0

我写了一些VBA：

For x = LBound(resProdID) To UBound(resProdID)
    CurrentDb.QueryDefs("qry_findID_vba").SQL = "" & _
    "SELECT tbl_products.ProdID " & _
    "FROM tbl_products " & _
    "WHERE (tbl_products.Size = " & resSize(x) & " " & _
    "AND tbl_products.SupplID = '" & Forms.frm_suppliers.SupplID & "')"

    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset

    Set dbs = CurrentDb()
    Set rst = dbs.OpenRecordset("qry_findID_vba")

    MsgBox rst.RecordCount

    If rst.RecordCount <> 0 Then
        rst.MoveLast
        rst.MoveFirst

        newProdID(x) = rst.Fields(0).Value
        MsgBox "This never fires"
     End If

    rst.Close
    Set rst = Nothing
    dbs.Close
    Set dbs = Nothing
Next x

当我运行它时，会弹出一个显示 0 的框。我单击“确定”，它会再重复一次。这是因为我的 resProdID 数组中有两个项目。

但是，如果我正常打开查询“qry_findID_vba”，它会显示一行，就像我预期的那样。

为什么 VBA 不返回这一行？我做错什么了吗？

4

2 回答 2

1

此代码消息框的计数是否正确？你可以用它来代替吗？（注意，我实际上并没有运行它，所以要注意轻微的语法错误。）

For x = LBound(resProdID) To UBound(resProdID) 
    Dim sql as String
    Dim rst As DAO.Recordset 
    sql = "Select tbl_products.ProdID FROM tbl_products " & _
          "WHERE (tbl_products.Size = " & resSize(x) & " " & _
          "AND tbl_products.SupplID = '" & Forms.frm_suppliers.SupplID & "')" 
    Set rst = dbs.OpenRecordset(sql)
    if not rst.eof then 
        MsgBox rst.fields("ProdID")    
    else
        Msgbox "None found!"
    end if
    rst.Close 
    Set rst = Nothing 
Next x

此外，尝试将所有内容复制到新表单，并压缩和修复数据库......

于 2012-10-01T14:05:08.460 回答
1

首先，您确实应该使用 QueryDef 参数。它们提供了许多好处：

  • 防止格式错误的输入和 SQL 注入的安全网。
  • 您无需在每次参数值更改时重新定义查询 SQL 文本。
  • 它们使您的 VBA 独立于查询文本。这是一个简单的查询，但如果您不必为了更改 SQL 而更改 VBA 代码，则更复杂的查询会受益。
  • 它们提供类型安全——您可以在 VBA 中使用类型化变量，并确保查询不会因数据类型错误而失败。
  • 它们可以重复使用——例如，参数化查询可以绑定到表单或直接执行。
  • 最后但同样重要的是，在 VBA 中使用时，它看起来更漂亮、更清晰。

您的情况正是参数化 QueryDefs 的用途。

qry_findID_vba将Access中的查询文本更改为：

PARAMETERS [ProductSize] Text (255), [SupplID] Number;
SELECT ProdID
FROM tbl_products
WHERE [tbl_products].[Size] = [ProductSize] AND [tbl_products].[SupplID] = [SupplID];

根据您在表中的实际数据类型替换参数数据类型。

接下来，当您处于循环中时，不要一次又一次地重新定义固定变量。dbs并且rst根本不需要在循环内定义。

最后一点，该RecordCount属性并不像您想象的那样工作。引用文档，强调我的：

使用该RecordCount属性可查明 Recordset 或 TableDef 对象中有多少条记录已被访问。在访问所有记录之前，RecordCount 属性不指示 动态集、快照或仅转发类型的Recordset 对象中包含多少记录。 [...] 要强制访问最后一条记录，请使用Recordset 对象上的方法。MoveLast

除了调用MoveLast，您还可以检查.EOF属性。如果为假，则至少有一条记录可用。

对于像这样的一次性查询结果，我建议使用快照类型 Recordset。您可以在调用QueryDef时定义要使用的类型。OpenRecordset

现在：

Dim qry_findID_vba As DAO.QueryDef 
Set qry_findID_vba = CurrentDb().QueryDefs("qry_findID_vba")

qry_findID_vba.Parameters("SupplID") = Forms.frm_suppliers.SupplID

For x = LBound(resProdID) To UBound(resProdID)
    qry_findID_vba.Parameters("ProductSize") = resSize(x)

    With qry_findID_vba.OpenRecordset(dbOpenSnapshot)
        If Not .EOF Then 
            newProdID(x) = .Fields("ProdID").Value 
        End If
    End With
Next x

请注意，我With用来保存维护辅助rst变量。

于 2012-10-01T14:56:38.923 回答