3

我在一个目录中有许多 TSV 文件，我想在每一行附加文件名作为额外的列。例如，我的数据如下所示。

前

文件名： snapper_User_list.txt 

Username    group        
user1 admin  
user2 users

文件名： marlin_User_list.txt 

Username    group  
root admin  
sql admin

我的理想状态是拥有一个如下所示的文本文件。

后

文件名： 输出.txt 

user1 admin snapper  
user 2 users snapper  
root admin marlin  
sql admin marlin

现在我需要在 MS Windows 中完成这个。

我有下面的脚本工作，虽然它仍然在我的输出中显示完整的文件名。

Rem Rename the files by just using the name before the underscore.
for /f "tokens=1* delims=_" %%i in ( 'dir *.txt /b' ) do (
    rename %%i_%%j %%i.txt
    )

Rem Combine the files.
FOR %%I IN (*.txt) DO (
    FOR /f "tokens=*" %%a IN (%%I) DO (
        echo %%a%TAB%%%I>>combined.txt
        )
    )

这是非常丑陋的代码。

谢谢。（更新 - 更新我的代码）

4

1 回答 1

2

我将假设您指的是文件名中出现的下划线。

@echo off
setlocal

::The following defines a TAB character that is not preserved on StackOverflow
set "TAB=   "

for %%F in (*.txt) do call :processFile "%%F"
exit /b

:processFile
set "name=%~1"
set name=%name:_=&rem %
for /f "usebackq delims=" %%a in (%1) do echo %%a%TAB%%name%>>combined.txt

魔术命令是set name=%name:_=&rem %。它通过在语句中注入 REMark 命令来工作。假设当前名称是part1_part2.txt. 搜索和替换展开后，完整的语句变为set name=part1&rem part2.txt

编辑 - 改进的答案

查看您编辑的问题，我意识到有更好的方法。我应该考虑使用 FOR /F 解析名称 :-) 你在那里 90%！

@echo off
setlocal

::The following defines a TAB character that is not preserved on StackOverflow
set "TAB=   "

for %%F in (*.txt) do (
  for /f "delims=_" %%I in ("%%F") do (
    for /f "usebackq delims=" %%a in ("%%F") do echo %%a%TAB%%%I>>combined.txt
  )
)
于 2012-10-01T11:21:25.287 回答