3

我有一个包含三种治疗的散点图，并且想为每种治疗应用最佳拟合线。SPSS中是否有任何方法可以在一种处理中应用拟合线而不会在一个数字上影响其他处理。任何意见是极大的赞赏

4

2 回答 2

1

这是我在NABBLE SPSS 列表上发布的逐字记录 - 服务于同义问题：

这是我能想到的最佳解决方案。简而言之，它创建了两个分组变量，然后将一个组映射到一个 100% 透明的元素。然后它在 GPL 中只有两个元素调用（在此示例中，一个用于线性，一个用于二次）。

当然，最灵活的解决方案是实际拟合每个组的模型并将预测值作为新变量放入数据集中，但这并没有太糟糕（传说甚至没有那么糟糕） .

**********************************************.
set seed = 10.
input program.
loop #i = 1 to 100.
if #i <= 50 group = 0.
if #i > 50 group = 1.
end case.
end loop.
end file.
end input program.
dataset name sim.
execute.

compute x = RV.NORM(0,1).
if group = 0 outcome =  x + RV.NORM(0,0.1).
if group = 1 outcome =  x**2 + RV.NORM(0,0.1).

compute group_square = (group = 1).
compute group_linear = (group = 0).
formats all (F1.0).
exe.


DATASET ACTIVATE sim.
* Chart Builder.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=x outcome group_square group_linear group
    MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: x=col(source(s), name("x"))
  DATA: outcome=col(source(s), name("outcome"))
  DATA: group=col(source(s), name("group"), unit.category())
  DATA: group_square=col(source(s), name("group_square"), unit.category())
  DATA: group_linear=col(source(s), name("group_linear"), unit.category())
  GUIDE: axis(dim(1), label("x"))
  GUIDE: axis(dim(2), label("outcome"))
  GUIDE: legend(aesthetic(aesthetic.transparency), null())     
  SCALE: cat(aesthetic(aesthetic.transparency), map(("0", transparency."1.0"), ("1", transparency."0.0")))
  ELEMENT: point(position(x*outcome), color.exterior(group))
  ELEMENT: line(position(smooth.linear(x*outcome)), transparency.interior(group_linear), color.interior(group))
  ELEMENT: line(position(smooth.quadratic(x*outcome)), transparency.interior(group_square), color.interior(group))
END GPL.
**********************************************.

具有不同拟合线的曲线
（来源：nabble.com）

于 2012-09-28T14:59:26.337 回答
0

首先，当您创建散点图时，请确保您说“x with y by z”，其中 z 是定义组的变量，每个组将获得自己的拟合线。图形编辑器窗口中有一个按钮，用于应用多条拟合线。它就在单拟合线按钮旁边。您也可以使用菜单。我不知道用语法创建这些行的方法，除非在具有“交互式图形”功能的旧版本中。

获得拟合线后，您可以单击，稍等片刻，然后再次单击以仅选择一条，然后您可以使用属性对话框将其更改为二次、三次或黄土线。

于 2012-07-30T12:19:45.363 回答