2

这个问题是指池上的这个评论：

[...] But if you're going to put an eval around every statement, just use RaiseError => 0. [...]

在这个线程中。

如果我在这种情况下设置RaiseError，我会得到什么？0

#!/usr/bin/env perl
use warnings;
use 5.10.1;
use DBI;

my $db = 'my_test_sqlite_db.sqlite';
open my $fh, '>', $db or die $!;
close $fh or die $!;

my ( $dbh, $sth );
eval {
    $dbh = DBI->connect( "DBI:SQLite:dbname=$db", "", "", {} );
};
if ( $@ ) { print $@ };

my $table = 'my_sqlite_table';

say   "RaiseError = 1";
say   "PrintError = 0";
$dbh->{RaiseError} = 1;
$dbh->{PrintError} = 0;
eval {
    $sth = $dbh->prepare( "SELECT * FROM $table" );
    $sth->execute();
};
if ( $@ ) { print "ERROR: $@" };

say "\nRaiseError = 0";
say   "PrintError = 1";
$dbh->{RaiseError} = 0;
$dbh->{PrintError} = 1;
eval {
    $sth = $dbh->prepare( "SELECT * FROM $table" );
    $sth->execute();
};
if ( $@ ) { print "ERROR: $@" };

say "\nRaiseError = 0";
say   "PrintError = 0";
$dbh->{RaiseError} = 0;
$dbh->{PrintError} = 0;
eval {
    $sth = $dbh->prepare( "SELECT * FROM $table" );
    $sth->execute();
};
if ( $@ ) { print "ERROR: $@" };

输出：

RaiseError = 1
PrintError = 0
ERROR: DBD::SQLite::db prepare failed: no such table: my_sqlite_table at ./perl2.pl line 23.

RaiseError = 0
PrintError = 1
DBD::SQLite::db prepare failed: no such table: my_sqlite_table at ./perl2.pl line 33.
ERROR: Can't call method "execute" on an undefined value at ./perl2.pl line 34.

RaiseError = 0
PrintError = 0
ERROR: Can't call method "execute" on an undefined value at ./perl2.pl line 44.
4

1 回答 1

3

如果由于某些原因失败，大多数 $dbh 方法将：

  • （如果RaiseError选项设置为 0）返回undef
  • （如果RaiseError选项设置为 1）立即退出脚本（'die'），错误原因作为退出消息给出。

这里的关键是如何处理错误取决于您。如果你愿意，你可以忽略它们，例如（以下显然只适用于RaiseError设置0）：

for my $db ( ... ) {
    my $dbh = get_database_handle( $db )
       or next;
    ...
}

在此代码段中（从您在问题中提到的@ikegami 的回答中复制）您循环浏览数据库连接的一些设置列表；如果某个连接给了您一个undef，那么您只需选择另一个连接，并且不会出错。

但是，通常情况下，当错误发生时，您必须做的不仅仅是“下一步”——但话又说回来，您有两个选择：或者检查每个 $dbh相关的语句，如下所示：

$sth = $dbh->prepare('some_params') 
  or process_db_error('In prepare');
...
$res = $sth->execute('another_set_of_params') 
  or process_db_error('In execute');
...
$res->doAnythingElse('something completely different') 
  or process_db_error('In something completely different');

（因为只有在布尔上下文中or对应的“左侧部分”评估为时才会执行部分false） 。

...或者只是将所有这些包装到 Perlish 'try-catch' 块中：

if (!eval {    
   $sth = $dbh->prepare('some_params');
   ...
   $res = $sth->execute('another_set_of_params');
   ...
   $res->doSomethingElse('something completely different') 
   ...
   1  # No exception
}) {
   process_db_error($@);
}

选择什么，由您决定：这是“返回语句中的错误”（除了要获取实际错误，您必须询问 $dbh 对象）和异常之间的常见决定。

但最重要的是你不能只写这个：

$sth = $dbh->do_something('that_can_result_in_error');
$sth->do_something('else');

...如果您确实设置RaiseError为0. 在这种情况下，脚本不会死，$sth将被分配一个undef，并且您会得到一个“衍生”错误（因为您不能在 上调用方法undef）。

这正是您原始问题的最后一部分代码中发生的事情。

于 2012-09-29T09:27:54.500 回答