95

Perl 中是否有一种简单的方法可以让我确定给定变量是否为数字？类似于以下内容：

if (is_number($x))
{ ... }

将是理想的。-w在使用开关时不会发出警告的技术当然是首选。

4

14 回答 14

143

Use Scalar::Util::looks_like_number()which 使用内部Perl C API 的looks_like_number() 函数，这可能是最有效的方法。请注意，字符串“inf”和“infinity”被视为数字。

例子：

#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

给出这个输出：

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number

也可以看看：

于 2008-08-26T16:53:34.377 回答
26

最初的问题是如何判断一个变量是否为数字，而不是它是否“具有数值”。

有一些运算符对数字和字符串操作数有不同的操作模式，其中“数字”表示最初是数字或曾经在数字上下文中使用的任何内容（例如$x = "123"; 0+$x，在加法之前，$x是字符串，之后是被认为是数字）。

一种说法是这样的：

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

如果启用了按位功能，即&仅生成数字运算符并添加单独的字符串&.运算符，则必须禁用它：

if ( length( do { no if $] >= 5.022, "feature", "bitwise"; no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

（按位在 perl 5.022 及更高版本中可用，如果您use 5.028;或更高版本默认启用。）

于 2010-09-27T17:16:12.517 回答
23

查看 CPAN 模块Regexp::Common。我认为它完全符合您的需要并处理所有边缘情况（例如实数、科学记数法等）。例如

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }
于 2008-08-15T21:01:16.790 回答
11

通常数字验证是​​使用正则表达式完成的。此代码将确定某些内容是否为数字，并检查未定义的变量以不引发警告：

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

这里有一些你应该看的阅读材料。

于 2008-08-15T19:58:52.907 回答
9

这个问题的一个简单（也许是简单化）的答案是$xnumeric的内容如下：

if ($x  eq  $x+0) { .... }

$x它对原始值与$x转换为数值的值进行文本比较。

于 2012-10-17T15:10:45.050 回答
5

我不相信有任何内置的东西可以做到这一点。有关该主题的更多信息，请参阅Perlmonks on Detecting Numeric

于 2008-08-15T20:44:02.673 回答
4

不完美，但您可以使用正则表达式：

sub isnumber 
{
    shift =~ /^-?\d+\.?\d*$/;
}
于 2008-08-15T19:49:44.563 回答
2

可以在Regexp::Common中找到更强大的正则表达式。

听起来您想知道 Perl 是否认为变量是数字的。这是一个捕获该警告的函数：

sub is_number{
  my $n = shift;
  my $ret = 1;
  $SIG{"__WARN__"} = sub {$ret = 0};
  eval { my $x = $n + 1 };
  return $ret
}

另一种选择是在本地关闭警告：

{
  no warnings "numeric"; # Ignore "isn't numeric" warning
  ...                    # Use a variable that might not be numeric
}

请注意，非数字变量将被静默转换为 0，这可能是您想要的。

于 2008-08-15T20:56:36.223 回答
2

rexep 不完美......这是：

use Try::Tiny;

sub is_numeric {
  my ($x) = @_;
  my $numeric = 1;
  try {
    use warnings FATAL => qw/numeric/;
    0 + $x;
  }
  catch {
    $numeric = 0;
  };
  return $numeric;
}
于 2010-12-10T18:58:12.393 回答
1

试试这个：

If (($x !~ /\D/) && ($x ne "")) { ... }
于 2013-05-31T16:01:54.270 回答
1

我发现这很有趣

if ( $value + 0 eq $value) {
    # A number
    push @args, $value;
} else {
    # A string
    push @args, "'$value'";
}
于 2015-10-01T14:15:28.637 回答
0

我个人认为要走的路是依靠 Perl 的内部上下文来使解决方案防弹。一个好的正则表达式可以匹配所有有效的数值，而不匹配任何非数值（反之亦然），但是由于有一种方法可以使用解释器正在使用的相同逻辑，因此直接依赖它应该更安全。

由于我倾向于使用 运行我的脚本-w，我不得不将“值加零”的结果与原始值进行比较的想法与no warnings@ysth 的基于方法相结合：

do { 
    no warnings "numeric";
    if ($x + 0 ne $x) { return "not numeric"; } else { return "numeric"; }
}
于 2015-12-31T13:47:24.677 回答
0

您可以使用正则表达式来确定 $foo 是否是一个数字（或不是）。

看看这里： 如何确定标量是否为数字

于 2016-02-26T16:55:43.127 回答
-1

if ( 定义 $x && $x !~ m/\D/ ) {} 或 $x = 0 if ! $x; 如果 ( $x !~ m/\D/) {}

这与 Veekay 的回答略有不同，但让我解释一下我做出这种改变的理由。

对未定义的值执行正则表达式将导致错误溢出，并导致代码在许多（如果不是大多数）环境中退出。在运行表达式之前测试该值是否已定义或像我在替代示例中所做的那样设置默认情况，至少会保存您的错误日志。

于 2013-09-21T16:14:58.190 回答