3

我有以下任务：
有一个包含长字符串的 xml 元素。我需要使用 xsl 将此元素转换为多个 html<input>标签。它的工作原理是这样的：如果字符串的长度超过了一个<input>字段在不滚动的情况下可以容纳的长度，我会递归地调用相同的模板来创建另一个带有剩余文本的输入字段。

问题是字符串经常在单词的中间被分割，这不是很好。

所以我需要找到最后一个space字符的位置，它不大于适合<input>标签的子字符串的大小，并且只打印它之前的子字符串。

所以我准备了一个最大长度的子字符串，它可以适合该字段，但我不知道如何获取其中最后一个的索引space并将其作为参数传递给函数的下一次调用。

UPD：这是我到目前为止所得到的

<xsl:template name="multilineInput">
    <xsl:param name="input" select="."/>
    <xsl:param name="maxFirst" select="."/>
    <xsl:param name="firstLineWidth" select="."/>



    <input>
        <xsl:attribute name="readonly">readonly</xsl:attribute>
        <xsl:attribute name="class">input_multiline</xsl:attribute>
        <xsl:attribute name="style">width = "<xsl:value-of select="$firstLineWidth"/>"</xsl:attribute>
        <xsl:attribute name="type">text</xsl:attribute>
        <xsl:attribute name="value"><xsl:value-of select="substring($input, 1, $maxFirst)"/></xsl:attribute>
    </input>

    <xsl:if test="$maxFirst &lt; string-length($input)">
        <xsl:call-template name="multilineInput">
            <xsl:with-param name="input" select="substring($input, $maxFirst+1, string-length($input)-$maxFirst)"/>
            <xsl:with-param name="maxFirst" select="110"/>
            <xsl:with-param name="firstLineWidth" select="'980'"/>
        </xsl:call-template>
    </xsl:if>

</xsl:template>
4

3 回答 3

6

以下递归模板可用于返回给定分隔符的最后索引：

<xsl:template name="last-index-of">
    <xsl:param name="txt"/>
    <xsl:param name="remainder" select="$txt"/>
    <xsl:param name="delimiter" select="' '"/>

    <xsl:choose>
        <xsl:when test="contains($remainder, $delimiter)">
            <xsl:call-template name="last-index-of">
                <xsl:with-param name="txt" select="$txt"/>
                <xsl:with-param name="remainder" select="substring-after($remainder, $delimiter)"/>
                <xsl:with-param name="delimiter" select="$delimiter"/>
            </xsl:call-template>      
        </xsl:when>
        <xsl:otherwise>
            <xsl:variable name="lastIndex" select="string-length(substring($txt, 1, string-length($txt)-string-length($remainder)))+1"/>
            <xsl:choose>
                <xsl:when test="string-length($remainder)=0">
                    <xsl:value-of select="string-length($txt)"/>
                </xsl:when>
                <xsl:when test="$lastIndex>0">
                    <xsl:value-of select="($lastIndex - string-length($delimiter))"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="0"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

可以像这样调用它：

<xsl:call-template name="last-index-of">
    <xsl:with-param name="txt" select="'The quick brown fox jumped over the lazy dog.'"/>
    <xsl:with-param name="delimiter" select="' '"></xsl:with-param>
 </xsl:call-template>

并返回：41

您可以将模板调用的结果分配给如下变量：

<xsl:variable name="last-index">
    <xsl:call-template name="last-index-of">
        <xsl:with-param name="txt" select="'The quick brown fox jumped over the lazy dog.'"/>
        <xsl:with-param name="delimiter" select="' '"></xsl:with-param>
     </xsl:call-template>
</xsl:variable>
于 2012-09-29T02:11:10.673 回答
4

这种转换实现了一个简单而有效的算法：字符串中的最后一个空格是反转字符串中的第一个空格：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
     <xsl:call-template name="lastCharIndex">
       <xsl:with-param name="pText" select=
         "'The quick brown fox jumped over the lazy dog.'"/>
     </xsl:call-template>
 </xsl:template>

 <xsl:template name="lastCharIndex">
  <xsl:param name="pText"/>
  <xsl:param name="pChar" select="' '"/>

  <xsl:variable name="vRev">
    <xsl:call-template name="reverse">
     <xsl:with-param name="pStr" select="$pText"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:value-of select=
  "string-length($pText) - string-length(substring-before($vRev, $pChar))"/>
 </xsl:template>

 <xsl:template name="reverse">
  <xsl:param name="pStr"/>

  <xsl:variable name="vLength" select="string-length($pStr)"/>
  <xsl:choose>
    <xsl:when test="$vLength = 1"><xsl:value-of select="$pStr"/></xsl:when>
    <xsl:otherwise>
      <xsl:variable name="vHalfLength" select="floor($vLength div 2)"/>
      <xsl:variable name="vrevHalf1">
        <xsl:call-template name="reverse">
         <xsl:with-param name="pStr" 
              select="substring($pStr, 1, $vHalfLength)"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:variable name="vrevHalf2">
        <xsl:call-template name="reverse">
         <xsl:with-param name="pStr" 
              select="substring($pStr, $vHalfLength+1)"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="concat($vrevHalf2, $vrevHalf1)"/>
    </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于任何 XML 文档（未使用）时，将产生所需的正确结果：

41
于 2012-09-29T05:19:22.167 回答
1

您可以使用 EXSLTsplit模板（描述；实现）或tokenize用空格分割字符串。然后您可以打印除最后一个以外的所有文本节点，和/或使用最后一个文本节点的长度来获取最后一个空格的索引。

另请参阅此模板，您可以根据自己的需要进行调整。

于 2012-09-28T15:05:17.527 回答