6

这是来自 xml 的片段：

<sample>
        <test>
            <Cell1>John</Cell1>
            <Cell2>A</Cell2>
            <Cell4>xy</Cell4>
        </test>
        <test>
            <Cell1>Jack</Cell1>
            <Cell2>B</Cell2>
            <Cell3>Red</Cell3>
            <Cell6>10</Cell6>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A,Y</Cell2>
            <Cell4>1</Cell4>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A B,X</Cell2>
            <Cell3>Blue</Cell3>
        </test>
    </sample>

条件：

如果Cell2包含逗号拆分值并检查前面是否Cell2包含相同的值，同样如果Cell2包含空格拆分值并检查前面是否Cell2包含相同的值 -> 如果是则忽略它。

这就是我想要的输出：

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

这是我写的 xslt：（请查看评论）

<xsl:template match="sample">
        <xsl:for-each select="test">
                <xsl:choose>
                    <xsl:when test="contains(Cell2,',')">
                        <xsl:variable name="token1Cell2" select="tokenize(Cell2,',')"/>
                        <xsl:for-each select="$token1Cell2">
                            <xsl:choose>
                                <xsl:when test="contains(.,' ')">
                                    <xsl:variable name="token2Cell2" select="tokenize(.,' ')"/>
                                    <xsl:for-each select="$token2Cell2">
              <!-- I tried to check if the preceding sibling element test/Cell2 contains the text that is not equal to the current text. But I know what I am doing is wrong as I am inside for-each tokenize. How to get the preceding-sibling? -->
                                      <xsl:if test="preceding-sibling::test/
Cell2/text() != '.'">
                                        <Cell2>
                                            <xsl:value-of select="."/>
                                        </Cell2>
                                        </xsl:if>
                                    </xsl:for-each>
                                </xsl:when>
                                <xsl:otherwise>
                                <xsl:if test="preceding-sibling::test/Cell2/text() != '.'">
                                    <Cell2>
                                        <xsl:value-of select="."/>
                                    </Cell2>
                                </xsl:if>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:for-each>
                    </xsl:when>
                    <xsl:otherwise>
                        <Cell2>
                            <xsl:value-of select="Cell2"/>
                        </Cell2>
                    </xsl:otherwise>
                </xsl:choose>
        </xsl:for-each>
    </xsl:template>

我怎样才能实现输出？有任何想法吗？？

4

3 回答 3

6

只是这个简单的转换：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:for-each select="distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))">
      <Cell2><xsl:value-of select="."/></Cell2>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<sample>
    <test>
        <Cell1>John</Cell1>
        <Cell2>A</Cell2>
        <Cell4>xy</Cell4>
    </test>
    <test>
        <Cell1>Jack</Cell1>
        <Cell2>B</Cell2>
        <Cell3>Red</Cell3>
        <Cell6>10</Cell6>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A,Y</Cell2>
        <Cell4>1</Cell4>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A B,X</Cell2>
        <Cell3>Blue</Cell3>
    </test>
</sample>

产生想要的正确结果：

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

说明：

select属性中的XPath表达式xsl:for-each是理解的关键：

distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))

这会产生所有标记化（的字符串值）的序列的不同值/*/test/Cell2

于 2012-09-27T14:47:43.703 回答
4

首先，如果您在逗号或空格上进行标记，那么您可以将您的标记组合成一个表达式

<xsl:for-each select="tokenize(., ',|\s')">

你能做的，是首先匹配所有Cell2元素，使用模板标记内容，但将结果放入变量中

  <xsl:variable name="cells">
     <xsl:apply-templates select="test/Cell2"/>
  </xsl:variable>

然后你可以简单地使用xsl:for-each-group来迭代它们

  <xsl:for-each-group select="$cells/Cell2" group-by="text()">
     <xsl:copy-of select="."/>
  </xsl:for-each-group>

这是完整的 XSLT

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="sample">
      <xsl:variable name="cells">
         <xsl:apply-templates select="test/Cell2"/>
      </xsl:variable>
      <xsl:for-each-group select="$cells/Cell2" group-by="text()">
         <xsl:copy-of select="."/>
      </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="Cell2">
      <xsl:for-each select="tokenize(., ',|\s')">
         <Cell2>
            <xsl:value-of select="."/>
         </Cell2>
      </xsl:for-each>
   </xsl:template>
</xsl:stylesheet>

应用于您的示例 XML 时，将输出以下内容

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>
于 2012-09-27T10:56:57.277 回答
2

当您有深度嵌套的 xsl:for-each 指令时，上下文项在每个级别都会更改，因此您通常需要将一个变量绑定到每个级别的上下文项，以便您可以返回到它。但是，深度嵌套的 xsl:for-each 指令有时表明您应该将代码分解为更小的模板或函数。

于 2012-09-27T13:53:41.880 回答