3

我发现（并稍加修改）一个使用正则表达式（和 perl）编辑文件列表的命令。我将它放入一个名为 的脚本文件cred中，因此我可以将当​​前目录中所有文件中cred . england England所有出现的 替换为england。England

find $1 -type f -exec perl -e 's/'$2'/'$3'/g' -p -i {} \;

它非常强大，而且已经很有用——但是很危险，而且有缺陷。我希望它...

  1. 首先预览更改（或至少文件操作），要求确认
  2. 使用比单个单词更长的字符串。我试过cred . england 'the United Kingdom'但失败了

我也会对其他（简短且令人难忘，在 osx 和 ubuntu 上普遍安装/可安装）命令感兴趣以实现相同的目标。

编辑：

这就是我到目前为止所拥有的 - 对改进持开放态度......

# highlight the spots that will be modified (not specifying the file)
find $1 -type f -exec grep -E "$2" --color {} \;
# get confirmation
read -p "Are you sure? " -n 1 -r
if [[ $REPLY =~ ^[Yy]$ ]]
then
  # make changes, and highlight the spots that were changed
  find $1 -type f -exec perl -e "s/$2/$3/g" -p -i {} \;
  echo ""
  find $1 -type f -exec grep -E "$3" --color {} \;
else
  echo ""
  echo "Aborted!!"
fi
4

2 回答 2

3

要处理带空格的字符串，请编写如下命令：

perl -e "s/$2/$3/g"

如果使用双引号，变量将在引号内展开。

要执行诸如预览更改和请求确认之类的操作，您将需要一个更复杂的脚本。一件非常简单的事情是find $1 -type f首先运行以获取所有文件的列表，然后使用read命令获取一些输入并决定是否应该继续。

于 2012-09-26T21:48:01.890 回答
1

这是一个使用 File::Find 的纯 Perl 版本。它更长一些，但更容易调试和做更复杂的事情。它适用于每个文件，从而可以更轻松地进行验证。

use strict;
use warnings;

use autodie;
use File::Find;
use File::Temp;

my($Search, $Replace, $Dir) = @ARGV;

# Useful for testing
run($Dir);

sub run {
    my $dir = shift;
    find \&replace_with_verify, $dir;
}

sub replace_with_verify {
    my $file = $_;
    return unless -f $file;

    print "File: $file\n";

    if( verify($file, $Search) ) {
        replace($file, $Search, $Replace);
        print "\nReplaced: $file\n";
        highlight($file, $Replace);
    }
    else {
        print "Ignoring $file\n";
    }

    print "\n";
}

sub verify {
    my($file, $search) = @_;

    highlight($file, $search);

    print "Are you sure? [Yn] ";
    my $answer = <STDIN>;

    # default to yes
    return 0 if $answer =~ /^n/i;
    return 1;
}

sub replace {
    my($file, $search, $replace) = @_;

    open my $in, "<", $file;
    my $out = File::Temp->new;

    while(my $line = <$in>) {
        $line =~ s{$search}{$replace}g;
        print $out $line;
    }

    close $in;
    close $out;

    return rename $out->filename, $file;
}

sub highlight {
    my($file, $pattern) = @_;

    # Use PCRE grep.  Should probably just do it in Perl to ensure accuracy.
    system "grep", "-P", "--color", $pattern, $file;    # Should probably use a pager
}
于 2012-09-27T02:53:31.690 回答