29

这个功能：

GOOGLEFINANCE(("CURRENCY:EURAUD"))

在 Google 表格中运行良好，我在网上上下搜索了一些关于此功能及其使用方式的文档，我得到的最接近的是这个

http://www.google.com/finance?q=EURAUD

有谁知道如何使用这个？或者在哪里可以找到有关此功能的文档？

4

8 回答 8

17

您正在寻找的具体说明在这里： https: //support.google.com/docs/answer/3093281

请记住，您的 Google 电子表格公式可能会使用分号 (;) 而不是逗号 (,)，具体取决于区域设置。

在某些示例上进行替换后，将如下所示：

=GoogleFinance("CURRENCY:USDEUR")
=INDEX(GoogleFinance("USDEUR","price",today()-30,TODAY()),2,2)
=SPARKLINE(GoogleFinance("USDEUR","price",today()-30,today()))
于 2014-12-06T02:23:16.297 回答
13

2016 年 1 月 1 日欧元对挪威克朗的汇率：

=INDEX(GOOGLEFINANCE("CURRENCY:EURNOK"; "close"; DATE(2016;1;1)); 2; 2)

使用该INDEX()函数是因为GOOGLEFINANCE()当您使用这些参数调用该函数时，函数实际上会在 4 个单独的单元格 (2x2) 中打印出来，结果只会是一个单元格。

于 2016-08-08T13:38:18.157 回答
8

干得好：

https://support.google.com/docs/answer/3093281

这是 Google 提供的所有文档。

于 2013-04-08T22:13:49.350 回答
3

请记住，该GoogleFinance()功能在新版 Google 表格中无法 100% 运行。例如，从转换USD为GBP使用公式在旧版本中GoogleFinance("CURRENCY:USDGBP")给出0.603974，但在新版本中只有 0.6。看起来有一个舍入错误。

于 2014-01-29T13:31:50.483 回答
3

某些货币对在某些日子没有历史数据。

比较=GOOGLEFINANCE("CURRENCY:EURNOK", "close", DATE(2016,1,1), DATE(2016,1,12)：

Date                Close
1/1/2016 23:58:00   9.6248922
1/2/2016 23:58:00   9.632922114
1/3/2016 23:58:00   9.579957264
1/4/2016 23:58:00   9.609146435
1/5/2016 23:58:00   9.573877808
1/6/2016 23:58:00   9.639368875
1/7/2016 23:58:00   9.707103569
1/8/2016 23:58:00   9.673324479
1/9/2016 23:58:00   9.702379872
1/10/2016 23:58:00  9.702721875
1/11/2016 23:58:00  9.705679083

和=GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1), DATE(2016,1,12)：

Date                Close
1/1/2016 23:58:00   79.44402768
1/4/2016 23:58:00   79.14048175
1/5/2016 23:58:00   80.0452446
1/6/2016 23:58:00   80.3761125
1/7/2016 23:58:00   81.70830185
1/8/2016 23:58:00   81.70680013
1/11/2016 23:58:00  82.50853122

所以，=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1)), 2, 2)给

79.44402768

但是=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2)), 2, 2)给

#N/A

因此，当使用周末/节假日没有汇率的货币对时，可以使用以下公式来获取下一个工作日的汇率：

=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2), 4), 2, 2)
于 2020-01-05T20:45:33.623 回答
2 
=INDEX(GoogleFinance("CURRENCY:" & "EUR" & "USD", "price", A2), 2, 2)

A2日期格式为日期的单元格在哪里。

将“EUR”和“USD”替换为您的货币对。

于 2017-04-26T08:31:23.210 回答
-1

语法是：

=GOOGLEFINANCE（股票代码，[属性]，[开始日期]，[天数|结束日期]，[间隔]）

示例用法：

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")
=GOOGLEFINANCE("GOOG","price",TODAY()-30,TODAY())
=GOOGLEFINANCE(A2,A3)
=117.80*Index(GOOGLEFINANCE("CURRENCY:EURGBP", "close", DATE(2014,1,1)), 2, 2)

例如，如果您想转换特定日期的汇率，这里有一些更高级的示例：

=IF($C2 = "GBP", "", Index(GoogleFinance(CONCATENATE("CURRENCY:", C2, "GBP"), "close", DATE(year($A2), month($A2), day($A2)), DATE(year($A2), month($A2), day($A2)+1), "DAILY"), 2))

$A2您的日期在哪里（例如01/01/2015），C2您的货币在哪里（例如EUR）。

在Google的文档编辑器帮助中查看更多示例。

于 2015-07-18T20:11:08.710 回答
-2

您必须在公式框中使用等号

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")
于 2016-08-07T02:04:32.470 回答