0

我的用户对我们拥有的大型 Lotus Notes 应用程序（不是 Web）的糟糕性能感到非常沮丧。它目前是 10Gb，大约有 500.000 个文档，它包含 reader 字段。

我想做的是创建应用程序应用程序的迷你版，因为大多数用户只对过去几年的文档感兴趣。

目前无法存档或移动大型应用程序，因此我正在考虑提供一个新的迷你副本并进行选择性复制以仅包含今年的文档。

我遇到的问题是应用程序的完整版需要在所有服务器上，这意味着我将在具有相同副本 ID 的同一台服务器上获得完整版和迷你版，这看起来有点吓人。

有一个更好的方法吗？

4

2 回答 2

3

我见过很多不同的方法来解决这个问题，从简单到过度设计。可悲的是，我认为我已经设计了几种过度设计的方法。幸运的是，我学到了一些教训。以下是我认为技术含量最低的方法：

您首先要做的是制作数据库的仅设计副本。我将其命名为 productiondocs.ntf。我将原始文件称为 alldocs.nsf。

将两个代理添加到 productiondocs.ntf，并确保它们受到保护以防止设计刷新/替换。调用第一个代理“synch”，并将其设置为在新的或修改过的文档上运行，并编写代码以简单地将新/修改过的文档复制到 alldocs.nsf 中。确保选中 isValid 以防止在此代理的主循环中处理已删除的文档。调用第二个代理“清除”。编写代码来检查日期（创建、修改或文档中的数据字段，具体取决于您要强制执行的规则）并删除超过一年的文档。

现在，您可以使用选择性复制——但只能使用一次。制作 alldocs.nsf 的选择性副本，仅包含一年的文档，并将其命名为 yeardocs.nsf。然后制作 yeardocs.nsf 的非副本并将其命名为 production.nsf。最后，使用 production.ntf 替换 production.nsf 的设计。仔细检查代理是否存在以及它们是否受到保护以防止设计刷新/替换操作。（某些版本的设计器把这搞砸了！）安排同步运行尽可能频繁，并安排每天或每周运行清除。将 production.nsf 复制到所有服务器，并将您的用户转移到 production.nsf。

（注意：你可以反过来做，在清除现有数据库后将用户保留在现有数据库中；但老实说，我认为从一个全新的 NSF 开始，你会获得额外的性能提升，所以这就是我按照我的方式编写它的原因做过。）

于 2012-09-25T18:07:59.940 回答
0

我真的很喜欢 Richard 的解决方案，但我最近实现了我目前喜欢的那个的派生。基本上，将每个文档中的任何元数据放入作为您的“索引”的单独数据库中，当他们打开索引文档时，它会在 alldocs.nsf 中打开文档（并关闭索引文档）。

为此，请在 alldocs.nsf 中编写一个代理，以便在修改或保存文档时创建索引文档。它应该只复制您要用于索引的字段（元数据）。从我的Copy Incident 到 Main代理执行此操作的示例代码（没有它调用的子例程或函数） ：

Sub Initialize
Dim session As New NotesSession
Dim maindb As NotesDatabase ' Main SIR
Dim mainincidents As NotesView ' view in Main SIR
Dim maindoc As NotesDocument ' document in Main SIR
Dim projectdoc, nextprojectdoc As NotesDocument ' document in this database
Dim ndc As NotesDocumentCollection ' unprocessed documents in this database
Dim fieldItem As NotesItem
Dim reportnumber, value, formtype As Variant
Dim fieldsToCopy (10) As String 
Dim reason As String

On Error GoTo errorhandler 

Call StartAgentLogging ( session )

Set thisdb = session.Currentdatabase

' find all unstamped documents
Set ndc = thisdb.Unprocesseddocuments

If ndc.Count = 0 Then
    Call agentLog.LogAction ( "No incidents to process" )
    Exit Sub
End If

maindbfilepath = DetermineKeyword("MAINSIR")
Set maindb = session.Getdatabase("","")
Call maindb.Open("", maindbfilepath)

If Not maindb.Isopen Then
    reason = "Main Security database could not be found at " & maindbfilepath
    Call agentLog.LogAction ( reason )
    MessageBox reason, 16, "Error"
    Exit Sub
End If

Set mainincidents = maindb.Getview("(Incidents for Upload)")
Set projectdoc = ndc.Getfirstdocument()
fieldsToCopy (0) = "ReportType"
fieldsToCopy (1) = "ReportNumber"
fieldsToCopy (2) = "ReportDate"
fieldsToCopy (3) = "IncidentDate"
fieldsToCopy (4) = "ProjectName"
fieldsToCopy (5) = "ProjectCountry"
fieldsToCopy (6) = "ProjectLocation"
fieldsToCopy (7) = "ReporterName"
fieldsToCopy (8) = "ReporterPhone"
fieldsToCopy (9) = "ReporterEmail"
fieldsToCopy (10) = "Appointment"

While Not projectdoc Is Nothing
    formtype = projectdoc.GetItemValue ("Form")
    If formtype(0) = "Incident" Then
        ' check to see if that exists in the main SIR
        reportnumber = projectdoc.GetItemValue("ReportNumber")
        Call agentLog.LogAction ( "Checking " & reportnumber(0) )
        Set maindoc = mainincidents.GetDocumentByKey(reportnumber(0), True)
        Call agentLog.LogAction ( "Accessing " & reportnumber(0) )

        If maindoc Is Nothing Then
            Call agentLog.LogAction ( "Main does not contain " & reportnumber(0) & " creating new document." )
            ' if not, create new document
            Set maindoc = maindb.Createdocument()
            maindoc.Form = "Incident"

            ForAll fieldname In fieldsToCopy
                Call agentLog.LogAction ( "Field name: " & fieldname ) 
                Set fieldItem = projectdoc.Getfirstitem(fieldname)
                Call maindoc.Copyitem(fieldItem, fieldname)
            End ForAll

            Call maindoc.Save(True, False)
            Call CreateNotice ( maindoc )
        Else
            Call agentLog.LogAction ( "Main contains " & reportnumber(0) & " updating document." )
            ' if it does, update data
            ForAll fieldname In fieldsToCopy
                Call agentLog.LogAction ( "Field name: " & fieldname ) 
                value = projectdoc.GetItemValue(fieldname)
                Call maindoc.ReplaceItemValue(fieldname, value(0))
            End ForAll
        End If

        'Path and filename
        Call maindoc.Replaceitemvalue("Path", thisdb.Filepath)
        Call maindoc.Save(True, False)
        Call agentLog.LogAction ( "Saved " & reportnumber(0) )
    Else
        Call agentLog.LogAction ( "Project form is " & projectdoc.Form(0) )
    End If

    ' stamp document as processed
    Set nextprojectdoc = ndc.GetNextDocument(projectdoc)
    Call session.Updateprocesseddoc(projectdoc)
    Set projectdoc = nextprojectdoc
Wend 

exiting:
    Exit Sub
errorhandler:' report all errors in a messagebox
    reason = "Error #" & CStr (Err) & " (" & Error & ") when creating incident in Main database, on line " & CStr (Erl)
    Call agentLog.LogAction ( reason )
    MessageBox reason, 16, "Error" 
    Resume exiting
End Sub

然后，您需要在索引数据库中的索引表单的onLoad事件中添加代码。我把我的放在一个由 ToolsRunMacro 调用的代理中，但你可以直接把它放进去。这是我的Open Project Copy代理。

Sub Initialize
' this button opens the incident report in the project database
Dim ws As New NotesUIWorkspace
Dim session As New NotesSession
Dim reportdb As NotesDatabase
Dim view As NotesView
Dim uidoc As NotesUIDocument
Dim thisdoc, reportdoc As NotesDocument
Dim filepath, reportnumber As Variant
Dim baseurl, opener, unid As String

Call StartAgentLogging ( session )
Set thisdb = session.Currentdatabase

Set uidoc = ws.CurrentDocument
Set thisdoc = uidoc.Document
filepath = thisdoc.GetItemValue ( "Path" )
reportnumber = thisdoc.GetItemValue ( "ReportNumber" )

Set reportdb = session.GetDatabase (thisdb.Server, filepath (0), False )
If reportdb Is Nothing Then
    MessageBox ( "Could not find Project Security Incident Report database" & Chr$(10) & thisdb.Server & "\" & filepath(0) )
    Call agentLog.LogAction ( "Could not find Project Security Incident Report database" & Chr$(10) & thisdb.Server & "\" & filepath(0) )
    Exit Sub
End If
If Not reportdb.Isopen Then
    Call reportdb.Open(thisdb.Server, filepath (0)) 
End If
Set view = reportdb.GetView ( "Incidents" )
Set reportdoc = view.GetDocumentByKey ( reportnumber(0) )
If reportdoc Is Nothing Then
    MessageBox ( "Could not find Report #" & reportnumber(0) )
    Call agentLog.LogAction ( "Could not find Report #" & reportnumber(0) )
    Exit Sub
End If

Call uidoc.Close
unid = reportdoc.UniversalID
baseurl = reportdb.NotesURL
opener = Left$ ( baseurl, InStr ( baseurl, "?" ) -1 ) & "/Incidents/" & unid & "?OpenDocument"
Call ws.URLOpen ( opener )
Call agentLog.LogAction ( "Opened Report #" & reportnumber(0) )
End Sub

现在，您可以将索引数据库限制为仅包含最近一年的文档，或者查看当所有文档都在其中时它是如何工作的。很大程度上取决于您需要在视图中提供多少数据。

在我的情况下，索引数据库包含来自许多数据库的文档的索引文档，并充当“完整数据”数据库的中央访问点。它仍在测试中，所以我不确定它对我的效果如何，但我想我会为你提供它作为一种可能性。

于 2012-09-26T14:32:15.683 回答