f# - 如何用索引做 Array.tryFind？

Question

我想做的一个简单的例子是

 Array.tryFind (fun elem index -> elem + index = 42) array1  //not valid

由于没有breakor continue，我发现即使在 for 循环中也很难手动完成

Answer 1

Similar with @gradbot's answer, you could define a module function along the line of mapi, iteri which works on arrays, lists and sequences.

module Seq =
    let tryFindi fn seq =
        seq |> Seq.mapi (fun i x -> i, x)
            |> Seq.tryFind (fun (i, x) -> fn i x)
            |> Option.map snd

// Usage
let res = [|1;1;40;4;2|] |> Seq.tryFindi (fun i el -> i + el = 42)

Answer 2

每当我发现内置函数中缺少一些我需要的东西时，我都会添加它！我总是有一个名为Helpers.fs我保存所有这些文件的文件。只要确保给它起一个好名字。

module Array =
    let tryFindWithIndex fn (array : _[]) =
        let rec find index =
            if index < array.Length then
                if fn array.[index] index then
                    Some(array.[index])
                else
                    find (index + 1)
            else
                None
        find 0

示例使用。

[|1;1;40;4;2|]
|> Array.tryFindWithIndex (fun elem index -> elem + index = 42)
|> printf "%A"

输出

Some 40

Answer 3

像这样的东西（免责声明：在浏览器中输入 - 可能包含错误）

array |> Seq.mapi (fun i el -> i + el) |> Seq.tryFind ((=)42)