4

给定x数量的数组，每个数组都有可能不同数量的元素，我如何遍历从每个数组中选择一个项目的所有组合？

例子：

[   ]   [   ]   [   ]
 foo     cat      1
 bar     dog      2
 baz              3
                  4

退货

[foo]   [cat]   [ 1 ]
[foo]   [cat]   [ 2 ]
  ...
[baz]   [dog]   [ 4 ]

顺便说一句，我在 Perl 中这样做。

4

5 回答 5

21

我的Set::CrossProduct模块完全符合您的要求。请注意，您并不是真的在寻找排列，它是集合中元素的顺序。您正在寻找叉积，它是来自不同集合的元素的组合。

我的模块为您提供了一个迭代器，因此您不必在内存中创建它。仅在需要时才创建新元组。

use Set::Crossproduct;

my $iterator = Set::CrossProduct->new(
    [
        [qw( foo bar baz )],
        [qw( cat dog     )],
        [qw( 1 2 3 4     )],
    ]
    );

while( my $tuple = $iterator->get ) {
    say join ' ', $tuple->@*;
    }
于 2009-08-10T18:08:23.343 回答
2

任意数量列表的简单递归解决方案：

sub permute {
  my ($first_list, @remain) = @_;

  unless (defined($first_list)) {
    return []; # only possibility is the null set
  }

  my @accum;
  for my $elem (@$first_list) {
    push @accum, (map { [$elem, @$_] } permute(@remain));
  }

  return @accum;
}

对于任意数量的列表，一个不那么简单的非递归解决方案：

sub make_generator {
  my @lists = reverse @_;

  my @state = map { 0 } @lists;

  return sub {
    my $i = 0;

    return undef unless defined $state[0];

    while ($i < @lists) {
      $state[$i]++;
      last if $state[$i] < scalar @{$lists[$i]};
      $state[$i] = 0;
      $i++;
    }

    if ($i >= @state) {
      ## Sabotage things so we don't produce any more values
      $state[0] = undef;
      return undef;
    }

    my @out;
    for (0..$#state) {
      push @out, $lists[$_][$state[$_]];
    }

    return [reverse @out];
  };
}

my $gen = make_generator([qw/foo bar baz/], [qw/cat dog/], [1..4]);
while ($_ = $gen->()) {
  print join(", ", @$_), "\n";
}
于 2009-08-10T17:11:49.857 回答
1

可以在http://www.perlmonks.org/?node_id=7366找到用于进行笛卡尔积的递归和更流畅的 Perl 示例（带有注释和文档）

例子：

sub cartesian {
    my @C = map { [ $_ ] } @{ shift @_ };

    foreach (@_) {
        my @A = @$_;

        @C = map { my $n = $_; map { [ $n, @$_ ] } @C } @A;
    }

    return @C;
}
于 2009-08-10T18:31:43.203 回答
0

您可以使用嵌套循环。

for my $e1 (qw( foo bar baz )) {
for my $e2 (qw( cat dog )) {
for my $e3 (qw( 1 2 3 4 )) {
   my @choice = ($e1, $e2, $e3); 
   ...
}}}

当您需要任意数量的嵌套循环时，可以使用Algorithm::Loops的NestedLoops。

use Algorithm::Loops qw( NestedLoops );

my @lists = (
   [qw( foo bar baz )],
   [qw( cat dog )],
   [qw( 1 2 3 4 )],
);

my $iter = NestedLoops(\@lists);
while ( my @choice = $iter->() ) {
   ...
}
于 2018-07-26T20:55:19.743 回答
-1

我首先想到的一种方法是使用一对 for 循环并且没有递归。

  1. 找到排列的总数
  2. 从 0 循环到 total_permutations-1
  3. 观察到，通过将循环索引模数取为数组中元素的数量，您可以获得每个排列

例子：

给定 A[3]、B[2]、C[3]，

for (index = 0..totalpermutations) {
    print A[index % 3];
    print B[(index / 3) % 2];
    print C[(index / 6) % 3];
}

当然，可以用 for 循环代替 [ABC ...] 循环，并且可以记住一小部分。当然，递归更简洁，但这对于递归受堆栈大小严重限制的语言可能很有用。

于 2009-08-10T17:58:58.077 回答