6

我有这个作业，我必须在 Prolog 中编写。要求是编写一段执行二进制加法的代码，例如：

?- add([1,0,1],[1,1],X).
X = [0,0,0,1]

所以，这是我想出的代码：

add([],[], _).
add([],Y, Z) :- append([], Y, Z).
add(X,[], Z) :- append(X,[],Z).
add([HX|TX],[HY|TY], Z) :-
    HX = 1,
    HY = 1,
    add(TX,TY, Z1),
    add([1],Z1, Z2),
    append([0],Z2,Z),!.
add([HX|TX],[HY,TY], Z) :-
    HX = 0,
    HY = 1,
    add(TX,TY,Z1),
    append([1],Z1, Z),!.
add([HX|TX],[HY|TY], Z) :-
    HX = 1,
    HY = 0,
    add(TX,TY,Z1),
    append([1],Z1, Z),!.
add([HX|TX],[HY,TY], Z) :-
    HX = 0,
    HY = 0,
    add(TX,TY,Z1),
    append([0],Z1, Z),!.

它似乎做了我需要的，但是，它有一些我无法理解的奇怪问题，所以如果有人能指导我做错了什么，我会很高兴。

结果：

?- add([1,1,1,1], [1,1],Z).
Z = [0, 1, 0, 0, 1]. % this is correct

?- add([1], [1],Z).
Z = [0, 1]. % this is correct

?- add([1,1,0,1], [1,1],Z).
Z = [0, 1, 1, 1]. % this is correct

?- add([1],[0],Y).
Y = [1|_G7100]. % there is an error here, but its not the big issue.

?- add([1,0,1], [1,1],Z).   
false. % no results are returned.

    104 ?- add([0], [1],Z).
    false. % no results returned either

问题：每当第一个二进制列表中似乎有 0 时，在某些情况下（仍在尝试找出它们），似乎没有返回任何结果。但我似乎无法找到我的错误。如果有人会很高兴可以告诉我我做错了什么。

4

2 回答 2

3

有3个错误：

  • 规则#1：应该add([],[],[]).代替add([],[], _).. 这对于等长列表失败。
  • 规则 #5 和 #7：应该add([HX|TX],[HY|TY], Z)代替add([HX|TX],[HY,TY], Z). 当第二个列表 ( Y) 包含的元素少于两个时，这将失败。

修复这些问题，您的代码应该运行良好：请参见此处。

于 2012-09-23T06:36:04.250 回答
0

我看到您使用 7 种不同的规则，因为您将二进制算术放在规则中。您可以使用 6 种不同的规则加上一个开始规则，如下所示：

add2(AL, BL, CL) :-
   add2(AL, BL, 0, CL).

add2([A | AL], [B | BL], Carry, [C | CL]) :-
   X is (A + B + Carry),
   C is X rem 2,
   NewCarry is X // 2,
   add2(AL, BL, NewCarry, CL).
add2([], BL, 0, BL) :- !.
add2(AL, [], 0, AL) :- !.
add2([], [B | BL], Carry, [C | CL]) :-
   X is B + Carry,
   NewCarry is X // 2,
   C is X rem 2,
   add2([], BL, NewCarry, CL).
add2([A | AL], [], Carry, [C | CL]) :-
   X is A + Carry,
   NewCarry is X // 2,
   C is X rem 2,
   add2([], AL, NewCarry, CL).
add2([], [], Carry, [Carry]).

以下是一些示例运行：

?- add2([1,1,1,1], [1,1],Z).
Z = [0,1,0,0,1]
?- add2([1], [1],Z).
Z = [0,1]
?- add2([1,1,0,1], [1,1],Z).
Z = [0,1,1,1]
?- add2([1],[0],Y).
Y = [1]
?- add2([1,0,1], [1,1],Z).
Z = [0,0,0,1]
?- add2([0], [1],Z).
Z = [1]

上述解决方案的主要优点是，对 add2/4 的调用较少，您可以替换 //2 和 rem 2，也可以在其他数字系统中进行加法。

PS：代码取自这里。

于 2012-09-24T16:22:40.100 回答