3

我似乎有一个有趣的问题，尽管我可能做错了什么。

我的问题是我试图将 AAAABBBBCCCC 推入堆栈，然后通过标准输出打印它们。但是，在我的 x86_64 环境中，似乎是push 0x41414141pushes 4141414100000000。

所以下面的代码块：

    global _start
    section .text
    _start:
    push 0x43434343  ; CCCC
    push 0x42424242  ; BBBB
    push 0x41414141  ; AAAA
    xor rax,rax      ; Zero RAX
    mov byte al,0x1  ; 1 for sys_write
    mov rdi,rax      ; 1 for stdout
    mov rsi,rsp      ; RSP for source
    mov byte dl,0xC  ; 12
    syscall          

    xor rax,rax      ; Zero RAX
    mov al, 0x3C     ; 60 for sys_edxit
    cdq              ; 0 for clean exit.
    syscall

Outputs AAAABBBB，我认为只有 8 个字节，实际上是我要求的 12 个字节。当通过管道传输到输出文件并在 hexedit 中查看时，我注意到它正在显示414141410000000042424242.

我认为push指令推动了一个dword价值。到一个qword大小的堆栈上？我这样想对吗？

这可以通过考虑额外的字节，并将我的长度更改为 20 来避免。但这会导致诸如sys_open.

所以我的问题是，我做错了什么？

4

1 回答 1

11

对于 64 位代码，堆栈 (RSP) 始终在 8 字节边界上对齐。也没有“push qword imm64”指令（见注）。

我的建议是将字符串“AAAABBBBCCCC”存储在它所属的数据部分（或“.rodata”）中，而不是弄乱堆栈。或者在 shellcode 中，

push   'CCCC'                  ; push qword, including 4 bytes of zeros
mov    rax, 'AAAABBBB'         ; mov reg, imm64; pick any register
push   rax                     ; push qword

保留您的变态的替代方法可能是：

sub rsp,16
mov dword [rsp],'AAAA'
mov dword [rsp+4],'BBBB'
mov dword [rsp+8],'CCCC'
....
add rsp,16

注意：AMD 的手册说有一个“push imm64”指令。AMD 的手册是错误的——这条指令实际上是推动一个 32 位立即数（符号扩展为 64 位）。

英特尔的手册没有这个问题：https
://www.felixcloutier.com/x86/push 还相关：当我没有指定操作数大小时，push 指令将多少字节推入堆栈？- 你绝对不能在 64 位模式下进行双字推送。

于 2012-09-22T15:20:52.797 回答