200

我想计算包含范围内任何内容的单元格。任何包含文本、数字或其他内容的单元格都应该在我的结果单元格中加一。

我发现了这个功能，

countif(range; criteria)

但这对我不起作用，因为我不知道在标准中输入什么。我怎样才能做到这一点？

4

8 回答 8

296

您可以将"<>"（包括引号）作为参数传递给criteria. 这基本上是说，只要它不是空的/空白的，就数它。我相信这就是你想要的。

=COUNTIF(A1:A10, "<>")

否则，您可以CountA按照 Scott 的建议使用

于 2012-10-05T13:21:08.480 回答
34

COUNTIF 函数只会计算包含指定范围内的数字的单元格。

COUNTA(range) 将计算参数列表中的所有值。文本条目和数字会被计算在内，即使它们包含长度为 0 的空字符串。

示例：A7 中的函数 =COUNTA(A1:A6)

范围：

A1a

A2 b

A3香蕉

A4 42

A5

A6

A7 4 -> 结果

Google 电子表格函数列表包含所有可用函数的列表以供将来参考https://support.google.com/drive/table/25273?hl=en。

于 2013-12-25T18:56:29.950 回答
7

标准应该是"?*"而不是"<>"因为后者也会计算包含空结果的公式，例如“”

所以最简单的公式是

=COUNTIF(Range,"?*")
于 2019-02-04T12:14:44.153 回答
2

如果您有类似的单元格=""并且不想计算它们，则必须通过公式从单元格总数中减去空单元格的数量，例如

=row(G101)-row(G4)+1-countblank(G4:G101)

如果是二维数组，它将是

=(row(G101)-row(A4)+1)*(column(G101)-column(A4)+1)-countblank(A4:G101)

在谷歌文档测试。

于 2017-07-05T21:44:09.390 回答
2

示例文件

在此处输入图像描述

笔记：

  • 试图找到计算非空白单元格（=""是空白单元格）的公式，而不需要使用data两次。的解决方案：=ARRAYFORMULA(SUM(IFERROR(IF(data="",0,1),1)))。对于 ={SUM(IFERROR(IF(data="",0,1),1))}应该可以工作（在公式中按Ctrl+ Shift+ ）。Enter
于 2018-08-28T11:46:42.573 回答
1

COUNTIF函数可以计算特定条件的单元格，其中COUNTA将计算包含任何值的所有单元格

示例： 中的函数A7：=COUNTA(A1:A6)

范围：

A1| a

A2| b

A3| banana

A4| 42

A5|

A6|

A7| 4 (result)
于 2020-04-08T08:02:47.297 回答
1

这行得通。

=ArrayFormula(SUM(IF(ISTEXT(把你的文本范围与任何东西混合在这里),1,0),1))

  1. IsText(range) 查看您的数据并为每个文本单元格返回 True，为每个不是文本的单元格返回 false。我认为这些被返回到数据表/数组中。请参见步骤 4。
  2. If(IsText(range),1,0) 从步骤 1 中 IsText 返回的数组/表中获取 True/False 值，并将 True 转换为 1，将 False 转换为 0，作为真正的整数，而不是字符串。
  3. Sum(range) 然后合计 1（完全是文本的 Trues/Cells）并忽略 0（Falses/Cells 不完全是文本）。
  4. 出于某种原因，需要 ArrayFormula 将所有单元格的总和返回到一个单元格中，而不是将所有单元格的总和返回到一个相等大小的表中。同上。如果有知识的人可以补充一下，将不胜感激。

好的机会。

于 2021-09-25T00:39:14.437 回答
0

计算其中包含任何内容的任何单元格（包括任何文本或数字值，以及具有文本或数字或空白结果的公式），然后使用：

=COUNTIF(A1:A10, "<>")

或者

=COUNTA(A1:A10)

仅计算具有非空白值的单元格（包括文本或数值，或具有数字或文本值的公式，但不包括具有空白结果的公式），即：单元格值长于零个字符，然后使用：

=SUMPRODUCT(--(LEN(A1:A10)>0))

或者

=COUNTA(FILTER(A1:A10, A1:A10 <> ""))

只计算具有文本（字母数字）值的单元格，然后使用：

=COUNTIF(A1:A10,"?*")

只计算具有数值的单元格，然后使用：

=COUNT(A1:A10)

计算任何空白单元格（包括没有值的单元格，以及公式结果为空白的单元格），然后使用：

=COUNTBLANK(A1:A10)
于 2022-01-06T05:31:51.467 回答