0

CreateOutputFile我正在尝试使用,WriteToFile和CloseFileIrvine32 过程将双字数组写入磁盘文件。这是我的代码。

INCLUDE Irvine32.inc

.data

     count = 45 
     BUFFER_SIZE = 188
     filename BYTE "Fibonacci.txt",0
     fileHandle DWORD ?
     array DWORD 47 DUP(?)
     num1 = 1
     num2 = 1
     temp1 DWORD ?
     temp2 DWORD ?
.code

     main PROC
     mov edx,OFFSET filename
     call CreateOutputFile

     mov fileHandle,eax
     mov esi,0
     mov array[esi],num1
     mov eax,array[esi]
     mov temp1,eax
     add esi,4 
     mov array[esi],num2
     mov eax,array[esi]
     mov temp2,eax
     add esi,4
     mov ecx, count

L1:

     mov eax,0
     mov ebx,0
     mov eax,temp1
     mov ebx,temp2
     add eax,ebx
     mov array[esi],eax
     mov temp1,ebx
     mov temp2,eax
     add esi,4
     loop L1

     mov eax,fileHandle
     mov edx,OFFSET array
     mov ecx,BUFFER_SIZE
     call WriteToFile

     mov eax,fileHandle
     call CloseFile
     exit
main ENDP

END main

我每次调试后，都成功创建了一个文本文件，但是却变成了文本文件中一些无法识别的代码。我认为它应该是以十六进制显示的数组。

我真的不知道我哪里出错了。请帮我！谢谢！

4

2 回答 2

1

“无法识别的代码”是 188 个字节，代表 CPU 内部格式中的 47 个值，称为“DWORD”。该文件是array DWORD 47 DUP(?). 对于人类可读的格式，例如十进制字符串，它们必须在斐波那契循环 (L1) 内或使用新循环（梯形图在下面显示为 L2）中一个接一个地进行转换。WinApi 包含一个可用作转换例程的函数：wsprintf. 由于 Irvine32 库声明了此函数，因此无需其他情况即可使用。

例子：

INCLUDE Irvine32.inc

.data

    count = 45
    BUFFER_SIZE = 188
    filename BYTE "Fibonacci.txt",0
    fileHandle DWORD ?
    array DWORD 47 DUP(?)
    num1 = 1
    num2 = 1
    temp1 DWORD ?
    temp2 DWORD ?

    decimalstring BYTE 16 DUP(0)    ; String for WriteFile
    fmt BYTE "%u",13,10,0           ; Format string for wsprintf ("%u\r\n")

.code

main PROC

    mov edx,OFFSET filename
    call CreateOutputFile

    mov fileHandle,eax
    mov esi,0
    mov array[esi],num1
    mov eax,array[esi]
    mov temp1,eax
    add esi,4
    mov array[esi],num2
    mov eax,array[esi]
    mov temp2,eax
    add esi,4
    mov ecx, count

L1:
    mov eax,0
    mov ebx,0
    mov eax,temp1
    mov ebx,temp2
    add eax,ebx
    mov array[esi],eax
    mov temp1,ebx
    mov temp2,eax
    add esi,4
    loop L1

    mov ecx, LENGTHOF array     ; Number of elements (DWORD's) in array
    mov esi, 0                  ; First index
L2:
    push ecx                    ; Preserve loop counter

    ;convert number to string
    push array[esi]             ; Argument for format string
    push OFFSET fmt             ; Pointer to format string ("%d")
    push OFFSET decimalstring   ; Pointer to buffer for output
    call wsprintf               ; Irvine32.inc / Smallwin.inc / User.lib / User.dll
    mov ecx, eax                ; Length of the stored string into ECX for WriteToFile
    add esp, (3*4)              ; CCALL calling function! Adjust the stack.

    mov eax, fileHandle
    mov edx, OFFSET decimalstring
    call WriteToFile

    pop ecx                     ; Restore loop counter
    add esi, 4                  ; Next DWORD
    loop L2

    mov eax,fileHandle
    call CloseFile
    exit
main ENDP

END main
于 2015-12-25T17:08:51.690 回答
0

这是一个老问题，但要查看您在文件上写入的数据，您需要使用 HEX 编辑器工具查看文件的 HEX 代码。我尝试调试你的代码并用十六进制编辑查看它，你的数组就在那里。您可以从此处下载 Hexedit：http ://www.hexedit.com/ 或使用任何其他允许您以十六进制模式查看文件的工具。

于 2015-04-04T22:09:13.220 回答