21

我们在每台开发 PC 上都有大量 Qt 副本——每个项目在第三方目录中都有自己的 Qt 副本。这是因为每个项目都是用自己的 Qt 开发和测试的；通常情况下，我们需要为某个项目定制 Qt 构建。因此，由于上面提到的，我们有一个单独的 SVN 存储库，用于保存各种 Qt 构建和每个 Qt 项目中的外部，它指的是这些构建中的一个。

问题是，在使用 CMake 时，我们只能选择 Qt 的一个版本，而 Qt4 finder 自己决定使用什么 Qt。这不是正确的。我们需要重定向查找器以配置项目第三方目录中特定 Qt 副本的所有内容。

我试图指定这样的PATHS选项FIND_PACKAGE：FIND_PACKAGE( Qt4 REQUIRED PATHS "thirdparty/Qt" )但这没有帮助。我试图设置QT_QMAKE_EXECUTABLE变量，但没有奏效。我尝试在安装之前将所需的 QMake 路径（FindQt4.cmake 使用它来确定所有目录）添加到 PATH 变量中，但这也无济于事。

有没有办法使用 FIND_PACKAGE 提供的所有东西，但对于某个 Qt 副本？我真的不想实现所有 Qt 包装器，手动设置所有定义、包含、目录等。

这是我的 CMake 项目。也许这会有所帮助：

CMAKE_MINIMUM_REQUIRED( VERSION 2.8 )

#############################################################################

MACRO( ADD_FILES_TO_FILTER rootFilterName rootFilterPath files )
    FOREACH( curFile ${files} )
        FILE( RELATIVE_PATH curFilter "${CMAKE_CURRENT_SOURCE_DIR}/${rootFilterPath}" "${CMAKE_CURRENT_SOURCE_DIR}/${curFile}" )
        FILE( RELATIVE_PATH test "${CMAKE_CURRENT_SOURCE_DIR}" "${CMAKE_CURRENT_SOURCE_DIR}/${curFile}" )
        GET_FILENAME_COMPONENT( curFilter ${curFilter} PATH )
        SET( curFilter "${rootFilterName}/${curFilter}" )
        STRING( REPLACE "/" "\\\\" curFilter ${curFilter} )
        SOURCE_GROUP( ${curFilter} FILES ${curFile} )
    ENDFOREACH( curFile )
ENDMACRO( ADD_FILES_TO_FILTER rootFilterName rootFilterPath files )

MACRO( TO_RELATIVE_PATHS filePaths )
    SET( resPaths "" )
    FOREACH( curPath ${${filePaths}} )
        FILE( RELATIVE_PATH relPath ${CMAKE_CURRENT_SOURCE_DIR} ${curPath} )
        SET( resPaths ${resPaths} ${relPath} )
    ENDFOREACH( curPath )
    SET( ${filePaths} ${resPaths} )
ENDMACRO( TO_RELATIVE_PATHS filePaths )

######################################################################

# Define project settings
PROJECT( RealTimeCapture )
FIND_PACKAGE( Qt4 REQUIRED PATHS "thirdparty/Qt" )
SET( BOOST_ROOT "thirdparty/boost" )
FIND_PACKAGE( Boost REQUIRED )

# Collect all required files for build
FILE( GLOB_RECURSE headers RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "src/RTCF/include/*.h" )
FILE( GLOB_RECURSE sources RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "src/RTCF/src/*.cpp" )
FILE( GLOB_RECURSE resources RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "src/*.qrc" )
FILE( GLOB_RECURSE forms RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "src/*.ui" )

# Preprocess all Qt files
QT4_WRAP_CPP( header_mocs ${headers} )
QT4_WRAP_UI( form_headers ${forms} )
QT4_ADD_RESOURCES( resources_rcc ${resources} )

# Convert all generated files paths to relative ones
TO_RELATIVE_PATHS( header_mocs )
TO_RELATIVE_PATHS( form_headers )
TO_RELATIVE_PATHS( resources_rcc )

# Create executable
ADD_EXECUTABLE( RealTimeCapture ${headers} ${sources} ${header_mocs} ${form_headers} ${resources_rcc} )
SET_TARGET_PROPERTIES( RealTimeCapture PROPERTIES COMPILE_FLAGS "/Zc:wchar_t-" )

# Set filters for project according to its namespaces
FILE( RELATIVE_PATH buildDir ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR} )
ADD_FILES_TO_FILTER( "Headers" "src/RTCF/include" "${headers}" )
ADD_FILES_TO_FILTER( "Sources" "src/RTCF/src" "${sources}" )
ADD_FILES_TO_FILTER( "Generated" "${buildDir}/src/RTCF/include" "${header_mocs}" )
ADD_FILES_TO_FILTER( "Forms" "${buildDir}/src/RTCF/include" "${form_headers}" )
ADD_FILES_TO_FILTER( "Resources" "${buildDir}" "${resources_rcc}" )

# Set additional include directories
INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
INCLUDE_DIRECTORIES( "src" )
INCLUDE_DIRECTORIES( "src/RTCF/include" )
INCLUDE_DIRECTORIES( "thirdparty" )

# Configure Qt
SET( QT_USE_QTNETWORK TRUE )
SET( QT_USE_QTSQL TRUE )
SET( QT_USE_QTSCRIPT TRUE )
SET( QT_USE_QTXML TRUE )
SET( QT_USE_QTWEBKIT TRUE )
INCLUDE( ${QT_USE_FILE} )
ADD_DEFINITIONS( ${QT_DEFINITIONS} )
TARGET_LINK_LIBRARIES( RealTimeCapture ${QT_LIBRARIES} )

# Add boost support
INCLUDE_DIRECTORIES( ${Boost_INCLUDE_DIR} )
TARGET_LINK_LIBRARIES( RealTimeCapture ${Boost_LIBRARIES} )

# Add other libs include dirs
INCLUDE_DIRECTORIES( "thirdparty/SimpleCrypt" )
INCLUDE_DIRECTORIES( "thirdparty/id3lib/include" )
INCLUDE_DIRECTORIES( "thirdparty/libtwitcurl" )
INCLUDE_DIRECTORIES( "thirdparty/curl-7.24.0/curl/include" )
INCLUDE_DIRECTORIES( "thirdparty/log4qt/include" )
INCLUDE_DIRECTORIES( "thirdparty/fervor-auto" )

# Add defines
ADD_DEFINITIONS( RealTimeCapture -DQUAZIP_STATIC )
ADD_DEFINITIONS( RealTimeCapture -DBUILDING_LIBCURL )
ADD_DEFINITIONS( RealTimeCapture -DID3LIB_LINKOPTION=1 )
ADD_DEFINITIONS( -DUNICODE -D_UNICODE ) #enable unicode support

更新

正如对已接受答案的评论中提到的那样，我设法通过设置QT_QMAKE_EXECUTABLECMake 变量来设置自定义 qmake.exe （不同于添加到 OS PATH 变量中的那个）。但问题是，qmake 可执行文件具有所有 Qt 模块的硬编码路径。所以我通过提供一个自定义qt.conf文件来解决它（正如答案中提到的那样）。我在互联网上没有找到任何示例，所以在这里，也许它会帮助某人：

[Paths]
Prefix=..
Documentation=doc
Headers=include
Libraries=lib
Binaries=bin
Plugins=plugins
Imports=imports
Data=
Translations=
Settings=
Examples=
Demos=

我正是用这个。您可以考虑在前缀中指定 Qt 安装的绝对路径。我只是不想在 repo 中使用绝对路径，它可以克隆到任意位置。有关使用的详细信息，请参阅此链接qt.conf。

4

3 回答 3

10

你在正确的轨道上QT_QMAKE_EXECUTABLE。该变量是一个缓存变量，所以简单地设置它是行不通的......除非您通过 GUI 更改它，或者在第一次运行 cmake 之前，或者在 CMakeCache.txt 中，或者使用 CACHE 更改它，否则缓存的值将一直存在和 FORCE 选项SET。

这是我使用的惯用语，因为我有固定的逻辑来根据配置时已知的变量选择我的 QT 目录。在这里，我在运行 FIND_PACKAGE 之前设置了变量，因此没有缓存问题。

IF(WIN32 AND ${CMAKE_SIZEOF_VOID_P} MATCHES 8)
  # Hardcode a location for a QT toolkit compiled for Win64.  By overriding QT_QMAKE, all the rest is found
  # Choose any version of QT found in the 64-bit tools area
  FILE(GLOB QTROOTS c:/Tools_x64/Qt/*/bin)     # */
  FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake qmake4 qmake-qt4 qmake-mac PATHS ${QTROOTS})
ENDIF()

把它放在 FIND_PACKAGE(Qt4) 之前

根据评论中的新信息进行编辑：

哦，我现在和你在一起。你有多少损坏的 Qt 安装。FindQt 模块将始终使用 qmake 可执行文件来发现 Qt 树的设置。Qmake 将此信息存储在一组“持久属性”中，可以用 查询，用qmake -query设置qmake -set。因此，您可以通过运行它的 qmake 并设置 QT_INSTALL_PREFIX 属性来“修复”Qt 安装，如此处所述：http: //doc.qt.digia.com/4.7-snapshot/qmake-environment-reference.html

qmake -set "QT_INSTALL_PREFIX" /path/to/qt/

或者，在一个旧的 SO 问题qmake 和 QT_INSTALL_PREFIX 中。如何为 Qt 库选择新位置？，不接受的答案使用 qt.conf 覆盖 QT 前缀。

这两种解决方案都涉及修改 Qt 安装。我不确定有什么办法可以解决这个问题，但是这如何适合您的存储库和构建系统超出了这里的范围。

于 2012-09-20T14:42:00.683 回答
3

如果可以的话，我想完成/确认这里所说的一些信息并给出一个完整的例子。

像 Occulta 一样，我有一个定制的 Qt 环境，我必须将其用于我的项目。这些是我为使项目编译而复制的步骤：

  1. 我项目的 CMakeLists.txt 已经拥有所有 CMake 内容，只需包含一个“qt.cmake”文件

    include(qt)

  2. qt.cmake 文件包含 Peter 的解决方案，并装饰有其他内容。通过这个配置，我可以使用 moc、uic 和 rcc 来管理 UI 文件、资源文件等。这是我的文件和一些注释。如果它们不完全正确，请不要犹豫修复它们（CMake 的工作方式对我来说仍然是多云的）：

    # The path where Qt is.
SET(QT_ROOT_DIR "path/to/qt")

set(QT_QMAKE_EXECUTABLE ${QT_ROOT_DIR}/osx/bin/qmake)

# Loads CMake macros bound to Qt.
find_package(Qt4 REQUIRED)
# Includes used Qt headers.
include(${QT_USE_FILE})

  3. 我还在 qmake 可执行文件的同一级别添加了 Occulta 的 qt.conf 文件。

完成这三个步骤后，一切都很好。希望这个完整的例子对某人有所帮助。

谢谢你们，你们显然在这里帮助了我！

于 2013-06-06T10:58:15.187 回答
1

这对我有用：

set( QT_ROOT /opt/myqt/ )
set( ENV(CMAKE_PREFIX_PATH) ${QT_ROOT} )
FIND_PACKAGE( Qt4 COMPONENTS QtCore QtGui QtDBUS REQUIRED )

这将更改 PATH 环境变量，但我还没有找到另一种方法。其他答案对我不起作用。

于 2014-02-26T10:16:47.780 回答