2

我的 xsl 变量： 

<xsl:variable name="string">Satur - Sun - Mon - Tues - Wednes - Thurs - Fri</xsl:variable>

我需要从以下位置翻译或替换string变量数据： 

Satur - Sun - Mon - Tues - Wednes - Thurs - Fri

所以，输出应该是这样的： 

Saturday - Sunday - Monday - Tuesday - Wednesday - Thursday - Friday

...................................

@Mads Hansen
，我是新手，xsl我xml尝试了您的代码，但它不起作用
100%，这是错误的

我的 xsl 文件： 

    <xsl:variable name="string">Satur - Sun - Mon - Tues - Wednes - Thurs - Fri</xsl:variable>
    <xsl:template match="/">
        <html>
            <body>
                <h2>result: </h2>
                <xsl:value-of 
                    select="for $token in tokenize($string, '\s-\s') 
                            return(
                                document('')/*/config/replacement[find[.=$token]]/replace,             
                                $token
                            )[1]" 
                    separator=" - "
                />
            </body>
        </html>
    </xsl:template>

</xsl:stylesheet>

我的 xml 文件：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="index.xsl"?>
    <config>
       <replacement>
            <find>Satur</find>
            <replace>Saturday</replace>
        </replacement>
        <replacement>
            <find>Sun</find>
            <replace>Sunday</replace>
        </replacement>
        <replacement>
            <find>Mon</find>
            <replace>Monday</replace>
        </replacement>
        <replacement>
            <find>Tues</find>
            <replace>Tuesday</replace>
        </replacement>
        <replacement>
            <find>Wednes</find>
            <replace>Wednesday</replace>
        </replacement>
        <replacement>
            <find>Thurs</find>
            <replace>Thursday</replace>
        </replacement>
        <replacement>
            <find>Fri</find>
            <replace>Friday</replace>
        </replacement>
    </config>

我的代码有什么问题？

4

3 回答 3

3

一、XPath 2.0（XSLT 2.0）解决方案：

使用以下 XPath 2.0 one-liner：

concat(replace(.,'\s+-\s*', 'day - '), 'day')

基于 XSLT 的验证：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/*">
   <xsl:sequence select="concat(replace(.,'\s+-\s*', 'day - '), 'day')"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>Satur - Sun - Mon - Tues - Wednes - Thurs - Fri</t>

产生了想要的正确结果：

Saturday - Sunday - Monday - Tuesday - Wednesday - Thursday - Friday

二、XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

 <xsl:template match="/*">
      <xsl:call-template name="replace">
       <xsl:with-param name="pS" select=
       "concat(normalize-space(translate(., '-', ' ')), 'day')"/>
     </xsl:call-template>
 </xsl:template>

 <xsl:template name="replace">
  <xsl:param name="pS"/>
  <xsl:param name="pTarget" select="' '"/>
  <xsl:param name="pReplacement" select="'day - '"/>

  <xsl:if test="$pS">
   <xsl:value-of select="substring-before(concat($pS,$pTarget), $pTarget)"/>
   <xsl:if test="contains($pS, $pTarget)">
     <xsl:value-of select="$pReplacement"/>
   </xsl:if>
   <xsl:call-template name="replace">
     <xsl:with-param name="pS" select="substring-after($pS, $pTarget)"/>
     <xsl:with-param name="pTarget" select="$pTarget"/>
     <xsl:with-param name="pReplacement" select="$pReplacement"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于同一个 XML 文档（上图）时，会产生相同的所需、正确的结果：

Saturday - Sunday - Monday - Tuesday - Wednesday - Thursday - Friday
于 2012-09-20T03:16:29.277 回答
2

@Mads 答案的变体：

<xsl:template match="/">
  <xsl:value-of 
     select="for $token in tokenize($string, '\s-\s') 
        return concat($token, 'day')"
     separator=" - " />
</xsl:template>

然后你可以省略<my:config>.

于 2012-09-20T01:35:37.263 回答
2

XSLT 2.0 解决方案：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="2.0"
    xmlns:my="http://stackoverflow.com/questions/12502665/xsl-how-to-translate-or-replace-string">
    <xsl:output indent="yes"/>

    <xsl:variable name="string">Satur - Sun - Mon - Tues - Wednes - Thurs - Fri</xsl:variable>

    <my:config>
        <replacement>
            <find>Satur</find>
            <replace>Saturday</replace>
        </replacement>
        <replacement>
            <find>Sun</find>
            <replace>Sunday</replace>
        </replacement>
        <replacement>
            <find>Mon</find>
            <replace>Monday</replace>
        </replacement>
        <replacement>
            <find>Tues</find>
            <replace>Tuesday</replace>
        </replacement>
        <replacement>
            <find>Wednes</find>
            <replace>Wednesday</replace>
        </replacement>
        <replacement>
            <find>Thurs</find>
            <replace>Thursday</replace>
        </replacement>
        <replacement>
            <find>Fri</find>
            <replace>Friday</replace>
        </replacement>
    </my:config>

    <xsl:template match="/">
        <xsl:value-of 
              select="for $token in tokenize($string, '\s-\s') 
                        return
                         (
                          document('')/*/my:config/replacement[find[.=$token]]/replace,             
                          $token
                         )[1]" 
              separator=" - " />
    </xsl:template>

</xsl:stylesheet>
于 2012-09-20T00:44:20.693 回答