delphi - 在 Delphi 中，当父控件接收和失去焦点时，如何通知控件？

Question

正如标题所说，我希望一个组件（比如 a ）在它的父级（比如 a ）接收和失去焦点label时得到通知。我在 Delphi 源代码中徘徊了一下，希望使用，但它仅用于通知子控件某些属性更改，例如字体和颜色。有什么建议么？panelTControl.Notify

Answer 1

每当应用程序中的活动控件发生更改时，CM_FOCUSCHANGED都会向所有控件广播一条消息。只需拦截它，并采取相应的行动。

此外，我假设当它的父级（例如，面板）接收和失去焦点时，您的意思是每当该父/面板上的（嵌套）子控件接收或失去焦点时。

type
  TLabel = class(StdCtrls.TLabel)
  private
    function HasCommonParent(AControl: TWinControl): Boolean;
    procedure CMFocusChanged(var Message: TCMFocusChanged);
      message CM_FOCUSCHANGED;
  end;

procedure TLabel.CMFocusChanged(var Message: TCMFocusChanged);
const
  FontStyles: array[Boolean] of TFontStyles = ([], [fsBold]);
begin
  inherited;
  Font.Style := FontStyles[HasCommonParent(Message.Sender)];
end;

function TLabel.HasCommonParent(AControl: TWinControl): Boolean;
begin
  Result := False;
  while AControl <> nil do
  begin
    if AControl = Parent then
    begin
      Result := True;
      Break;
    end;
    AControl := AControl.Parent;
  end;
end;

如果您不喜欢子类TJvGradientHeader化，那么可以使用以下方法进行通用设计Screen.OnActiveControlChange：

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FHeaders: TList;
    procedure ActiveControlChanged(Sender: TObject);
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FHeaders := TList.Create;
  FHeaders.Add(Label1);
  FHeaders.Add(Label2);
  Screen.OnActiveControlChange := ActiveControlChanged;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FHeaders.Free;
end;

function HasCommonParent(AControl: TWinControl; AMatch: TControl): Boolean;
begin
  Result := False;
  while AControl <> nil do
  begin
    if AControl = AMatch.Parent then
    begin
      Result := True;
      Break;
    end;
    AControl := AControl.Parent;
  end;
end;

procedure TForm1.ActiveControlChanged(Sender: TObject);
const
  FontStyles: array[Boolean] of TFontStyles = ([], [fsBold]);
var
  I: Integer;
begin
  for I := 0 to FHeaders.Count - 1 do
    TLabel(FHeaders[I]).Font.Style :=
      FontStyles[HasCommonParent(Screen.ActiveControl, TLabel(FHeaders[I]))];
end;

请注意，我选择TLabel为TControl衍生品演示这项工作。