3

我的问题与这个问题非常相似，我从中学到了很多东西。但是，我正在处理多个数据块，如下所示：

1 2 3
4 5 6
7 8 0
4 3 0


4 5 7
2 3 0
4 5 0
5 6 7

我正在像这样绘制它们：

plot "file.txt" index 0 u 1:2 w points pt 1,\
     "file.txt" index 1 u 1:2 w points pt 2

它创建了 2 组不同的点，每组都有不同的颜色。现在，我的目标是修改此脚本，以便如果第 3 列数据为 0，则该点的颜色将变为黑色。我希望其他点保持它们当前的颜色（意味着彼此不同）。我已经这样做了：

set palette model RGB defined ( 0 'black', 1 'green' )
unset colorbox
plot file index 0 u 1:2:( $3 == 0 ? 0 : 1 ) w points pt 1 palette,\
     file index 1 u 1:2:( $3 == 0 ? 0 : 1 ) w points pt 2 palette

这正是我想要的，当然这两个集合现在都以绿色绘制。有什么方法可以根据需要绘制黑色，但也可以使每个索引都具有不同的颜色？

4

2 回答 2

3

这就是特殊的“可变”颜色的用途：

plot 'test.dat' i 0 u 1:2:($3 == 0? 0:1) w p pt 1 lc variable,\
     'test.dat' i 1 u 1:2:($3 == 0? 0:2) w p pt 2 lc variable

variable在这种情况下，使用第三列中给出的任何“样式索引”的颜色。我在第三列变量上设置过滤器，如果该列中的数据不为 0，它将第三列转换为常量（1 或 2）。

另一种不太直接的方法（由于您使用的是积分而有效）是：

plot 'test.dat' i 0 u 1:($3 == 0? 1/0: $2) w p pt 1 lc rgb "red",\
     'test.dat' i 0 u 1:($3 == 0? $2:1/0) w p pt 1 lc rgb "black,\
     'test.dat' i 1 u 1:($3 == 0? 1/0: $2) w p pt 1 lc rgb "green",\
     'test.dat' i 1 u 1:($3 == 0? $2:1/0) w p pt 1 lc rgb "black,\
于 2012-09-14T16:52:20.113 回答
2

它应该可以在调色板中定义一个额外的点：

set palette model RGB defined ( 0 'black', 1 'green', 2 'red')
unset colorbox
plot file index 0 u 1:2:( $3 == 0 ? 0 : 1 ) w points pt 1 palette,\
     file index 1 u 1:2:( $3 == 0 ? 0 : 2 ) w points pt 2 palette

在此处输入图像描述

于 2012-09-14T16:03:14.373 回答