1

我正在开发一个在 Flash 中渲染 xps 内容的项目，并且在 Flash 中遇到了 twip（单位的 1/20）精度限制。twip 限制在 swf 文件格式中提及，但在 flash as3 文档中仅在 PrintJob.addPage 方法中提及。但是，在设置 DisplayObject x 和 y 属性时，任何小于 0.05 的精度都会被舍入。无论任何缩放。下面的代码演示了这个问题。


    package
    {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.GraphicsPathCommand;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.display.StageScaleMode;
    public class TWIPTest extends Sprite
    {
        // can change behaviour by switching between createPoint and drawPoint
        public function TWIPTest()
        {
            this.stage.scaleMode = StageScaleMode.NO_SCALE;
            // scale our unit square so we can see what is happening
            scaleX = 400; scaleY = 400;
            // draw grid
            var grid : Sprite = new Sprite();
            addChild(grid);
            grid.graphics.lineStyle(TWIP, 0x888888);
            drawGrid(1 / TWIP, 1 / TWIP, TWIP, TWIP, grid);
            // center of unit square
            var cx : Number = 0.5; 
            var cy : Number = 0.5;

            var shape : Shape;
            // GREEN in middle of unit square
            this.addChild(createPoint(cx, cy, 0x00FF00));
            //drawPoint(cx, cy, 0x00FF00, this.graphics);

            // BLUE one TWIP away from GREEN
            this.addChild(createPoint(cx + TWIP, cy + TWIP, 0x0000FF));
            //drawPoint(cx + TWIP, cy + TWIP, 0x0000FF, this.graphics);

            // RED half a TWIP away from GREEN (this does not work....) 
            this.addChild(createPoint(cx + (TWIP / 2), cy + (TWIP / 2), 0xFF0000, 0.5));
            //drawPoint(cx + (TWIP / 2), cy + (TWIP / 2), 0xFF0000, this.graphics, 0.5);

            // now insert new container to work around limit encontered with RED point
            var container : Sprite = new Sprite();
            this.addChild(container);
            container.scaleX = 0.5; container.scaleY = 0.5;
            container.addChild(createPoint(2 * cx + TWIP, 2 * cy + TWIP, 0xFF00FF, 1.0, 2 * TWIP));
            //drawPoint(cx + (TWIP / 2), cy + (TWIP / 2), 0xFF00FF, container.graphics);
        }
        static private function createPoint(x:Number, y:Number,color:uint,alpha:Number=1.0,radius:Number=0.05):Shape
        {
            var shape : Shape = new Shape();
            shape.x = x; shape.y = y;
            shape.graphics.beginFill(color,alpha);
            shape.graphics.drawCircle(0, 0, radius);
            shape.graphics.endFill();
            return shape;
        }
        static private function drawPoint(x:Number, y:Number,color:uint,target:Graphics,alpha:Number=1.0,radius:Number=0.05):void
        {
            target.beginFill(color,alpha);
            target.drawCircle(x, y, radius);
            target.endFill();
        }
        // drawGrid from @Feltope
        private function drawGrid(numColumns:Number, numRows:Number, cellHeight:Number, cellWidth:Number, grid:Sprite):void 
        {
            for (var col:Number = 0; col < numColumns + 1; col++)
            {
                for (var row:Number = 0; row < numRows + 1; row++)
                {
                    grid.graphics.moveTo(col * cellWidth, 0);
                    grid.graphics.lineTo(col * cellWidth, cellHeight * numRows);
                    grid.graphics.moveTo(0, row * cellHeight);
                    grid.graphics.lineTo(cellWidth * numColumns, row * cellHeight);
                }
            }
        }
        static private const TWIP : Number = 0.05;
    }
    }

这个帖子也提到了这个问题。

问题是，在解析 xps 文件时，这可能随时发生，而且发生很多次，例如


<Canvas RenderTransform="96.201126,0,0,-95.787476,713.62598,207.05859">
<Path Data="..." RenderTransform="0.010394889,0,0,-0.010439778,-7.4180626,2.1616458">

注意 Path 元素中的 dx，这看起来微不足道，但是父级 Canvas（以及上面的其他父级）将其放大，因此 dx 到 0 或 0.05 的舍入非常明显。

每当发生这种情况时，我都可以添加 Sprite 容器，就像上面的代码一样，但这会导致内存膨胀并减慢渲染速度。

我的问题（最后），有人处理过这个问题吗？有关处理此限制的更好方法的任何想法？解决方法？任何帮助表示赞赏。干杯

4

1 回答 1

0

这里最大的问题是什么？它在屏幕上的外观如何，或者在解析精度后丢失？您不能进行渲染，但您可以修改 DisplayObject 以存储例如位置，然后读取它将包含保持的精度。还是我错过了重点？:)

编辑： 以下是自定义显示对象（形状和精灵）的示例

import flash.display.Shape;
import flash.display.Sprite;
internal class MySprite extends Sprite
{
    protected var m_nX:Number;
    protected var m_nY:Number;


    override public function get x():Number 
    {
        return m_nX;
    }

    override public function set x(value:Number):void 
    {
        m_nX = value;
        super.x = m_nX;
    }
    override public function get y():Number 
    {
        return m_nY;
    }

    override public function set y(value:Number):void 
    {
        m_nY = value;
        super.y = m_nY;
    }
}
internal class MyShape extends Shape
{
    protected var m_nX:Number;
    protected var m_nY:Number;


    override public function get x():Number 
    {
        return m_nX;
    }

    override public function set x(value:Number):void 
    {
        m_nX = value;
        super.x = m_nX;
    }
    override public function get y():Number 
    {
        return m_nY;
    }

    override public function set y(value:Number):void 
    {
        m_nY = value;
        super.y = m_nY;
    }
}

将此添加到您的示例中并替换 Shape 的任何实例化并使用 MyShape，对于 Sprite 相同，将其替​​换为 MySprite。不会有视觉差异，但它们的 x 和 y 将返回精确值。

这是精度保持的示例测试：

addChild(createPoint(0.51000005, 0.510000049, 0x800000, 1, TWIP));
var disp :DisplayObject = getChildAt(numChildren - 1);
trace(disp.x, disp.y);

将跟踪 0.51000005、0.510000049 但在没有 MySprite 和 MyShape 自定义 DisplayObjects 的情况下添加到您的示例中的上述测试将返回 0.5 0.5。

于 2012-09-14T10:22:53.953 回答