15

我有一个由表列的一种行类型创建的关联数组。

举个例子，它是这样的（表名不同，但结构相同）：

这是表的 DDL

CREATE TABLE employees
  (
     id     NUMBER,
     name   VARCHAR2(240),
     salary NUMBER
  );

这是我的程序正在执行的操作：

DECLARE
    TYPE table_of_emp
      IS TABLE OF employees%ROWTYPE INDEX BY BINARY_INTEGER;
    emp TABLE_OF_EMP;
BEGIN
    IF emp IS NULL THEN
      dbms_output.Put_line('Null associative array');
    ELSE
      dbms_output.Put_line('Not null');
    END IF;
END;

我认为这应该导致打印“空关联数组”。但是，if条件失败，执行跳转到 else 部分。

现在，如果我输入一个for循环来打印集合值

DECLARE
    TYPE table_of_emp
      IS TABLE OF employees%ROWTYPE INDEX BY BINARY_INTEGER;
    emp TABLE_OF_EMP;
BEGIN
    IF emp IS NULL THEN
      dbms_output.Put_line('Null associative array');
    ELSE
      dbms_output.Put_line('Not null');

      FOR i IN emp.first..emp.last LOOP
          dbms_output.Put_line('Emp name: '
                               || Emp(i).name);
      END LOOP;
    END IF;
END;

然后程序单元引发异常，引用 for 循环行

ORA-06502: PL/SQL: 数字或值错误

我认为这是因为空关联数组。是否由于空关联数组而引发错误？

那么为什么第一次检查失败呢？我究竟做错了什么？

数据库服务器为 Oracle 11g EE（版本 11.2.0.3.0 64 位）

4

2 回答 2

14

我认为这应该导致打印“空关联数组”。这种假设对于关联数组是错误的。它们在声明时存在，但为空。这对于其他类型的 PL/SQL 集合是正确的：

在您初始化它之前，嵌套表或可变数组在原子上是空的；集合本身是空的，而不是它的元素。要初始化嵌套表或可变数组，请使用构造函数，即与集合类型同名的系统定义函数。此函数从传递给它的元素构造集合。

您必须为每个可变数组和嵌套表变量显式调用构造函数。关联数组，第三种集合，不使用构造函数。只要允许函数调用，就允许构造函数调用。初始化和引用集合

比较：

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4  begin
  5      test(1) := 'Hello';
  6      dbms_output.put_line(test(1));
  7  end;
  8  /
Hello

PL/SQL procedure successfully completed.

SQL> declare
  2      type varchar2_100_va is varray(100) of varchar2(100);
  3      test varchar2_100_va;
  4  begin
  5      test(1) := 'Hello';
  6      dbms_output.put_line(test(1));
  7  end;
  8  /
declare
*
ERROR at line 1:
ORA-06531: Reference to uninitialized collection
ORA-06512: at line 5

变量数组正确完成：

SQL> declare
  2      type varchar2_100_va is varray(10) of varchar2(100);
  3      test varchar2_100_va;
  4  begin
  5      test := varchar2_100_va(); -- not needed on associative array
  6      test.extend; -- not needed on associative array
  7      test(1) := 'Hello';
  8      dbms_output.put_line(test(1));
  9  end;
 10  /
Hello

PL/SQL procedure successfully completed.

因为关联数组为空first且last为空，这就是为什么您的第二个示例导致ORA-06502: PL/SQL: Numeric or value error：

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4  begin
  5      dbms_output.put_line(test.count);
  6      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
  7      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
  8      test(1) := 'Hello';
  9      dbms_output.new_line;
 10      dbms_output.put_line(test.count);
 11      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
 12      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
 13  end;
 14  /
0
NULL
NULL

1
1
1

PL/SQL procedure successfully completed.

编辑还请注意，关联数组可以是稀疏的。first循环和之间的数字last将为任何稀疏的集合引发异常。而是像这样使用first和next：（Last并prev循环另一个方向。）

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4      i binary_integer;
  5  begin
  6      test(1) := 'Hello';
  7      test(100) := 'Good bye';
  8      dbms_output.put_line(test.count);
  9      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
 10      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
 11      dbms_output.new_line;
 12  --
 13      i := test.first;
 14      while (i is not null) loop
 15          dbms_output.put_line(to_char(i, '999')  || ' - ' || test(i));
 16          i := test.next(i);
 17      end loop;
 18  end;
 19  /
2
1
100

   1 - Hello
 100 - Good bye

PL/SQL procedure successfully completed.
于 2012-09-13T19:04:21.970 回答
5

我不会回答为什么第一次检查失败。我从来没有想过做这样的事情，并且很惊讶它不会引发错误。

正如您所指出的，您在循环中引发异常的原因是索引emp.first不存在。

与其检查空值，不如检查该索引是否存在。您可以使用以下.exists(i)语法：

if not emp.exists(emp.first) then
   dbms_output.put_line('Nothing in here.');
end if;
于 2012-09-13T18:02:51.907 回答