5

我有两个 SAS 数据集。第一个相对较小，包含唯一的日期和相应的 ID：

date   dateID
1jan90     10
2jan90     15
3jan90     20
...

第二个数据集非常大，有两个日期变量：

dt1     dt2
1jan90  2jan90
3jan90  1jan90
...

我需要同时匹配dt1和dt2，dateID所以输出将是：

id1  id2
10   15
20   10

效率在这里非常重要。我知道如何使用哈希对象进行一次匹配，因此我可以执行一个数据步骤来进行匹配，dt1然后再执行另一步骤来匹配dt2，但我想在一个数据步骤中同时执行这两个步骤。如何才能做到这一点？

这是我将如何进行比赛的方式dt1：

data tbl3;
 if 0 then set tbl1 tbl2;

 if _n_=1 then do;
  declare hash dts(dataset:'work.tbl2');
  dts.DefineKey('date');
  dts.DefineData('dateid');
  dts.DefineDone();
 end;

 set tbl1;
 if dts.find(key:date)=0 then output;
 run;
4

3 回答 3

6

考虑到哈希表的大小，一种格式可能会同样有效地工作......

data fmt ;
retain fmtname 'DTID' type 'N' ;
set tbl1 ;
start = date ;
label = dateid ;
run ;
proc format cntlin=fmt ; run ;

data tbl3 ;
  set tbl2 ;
  id1 = put(dt1,DTID.) ;
  id2 = put(dt2,DTID.) ;
run ;

基于以下评论的编辑版本...

data fmt ;
retain fmtname 'DTID' type 'I' ;
set tbl1 end=eof ;
start = date ;
label = dateid ;
output ;
if eof then do ;
  hlo = 'O' ;
  label = . ;
  output ;
end ;
run ;
proc format cntlin=fmt ; run ;

data tbl3 ;
  set tbl2 ;
  id1 = input(dt1,DTID.) ;
  id2 = input(dt2,DTID.) ;
run ;
于 2012-09-13T07:50:22.887 回答
2

我现在没有 SAS 来测试它，但代码如下所示：

 data tbl3;
   if 0 then set tbl1 tbl2;

   if _n_=1 then do;
     declare hash dts(dataset:'work.tbl2');
     dts.DefineKey('date');
     dts.DefineData('dateid');
     dts.DefineDone();
   end;

   set tbl1;

   date = dt1;
   if dts.find()=0 then do;
     id1 = dateId;
   end;

   date = dt2;
   if dts.find()=0 then do;
     id2 = dateId;
   end;

   if dt1 or dt2 then do output; * KEEP ONLY RECORDS THAT MATCHED AT LEAST ONE;

   drop date dateId;
 run;
于 2012-09-13T05:58:31.670 回答
2

一方面，我同意格式解决方案，但如果你想做散列解决方案，就可以了。这里的基本内容是您将键定义为要匹配的变量，而不是散列本身。

data tbl2;
informat date DATE7.;
input date   dateID;
datalines;
01jan90     10
02jan90     15
03jan90     20
;;;;
run;

data tbl1;
informat dt1 dt2 DATE7.;
input dt1     dt2;
datalines;
01jan90  02jan90
03jan90  01jan90
;;;;
run;
data tbl3;
 if 0 then set tbl1 tbl2;

 if _n_=1 then do;
  declare hash dts(dataset:'work.tbl2');
  dts.DefineKey('date');
  dts.DefineData('dateid');
  dts.DefineDone();
 end;

 set tbl1;
 rc1 = dts.find(key:dt1);
 if rc1=0 then id1=dateID;
 rc2 = dts.find(key:dt2);
 if rc2=0 then id2=dateID;
 if rc1=0 and rc2=0 then output;
 run;
于 2012-09-13T12:33:54.547 回答