1

文件 1

A11;F1;BMW
A23;F2;BMW
B12;F3;BMW
H11;F4;JBW

文件 2

P01;A1;0;0--00  ;123;456;150
P01;A11;0;0--00  ;123;444;208
P01;B12;0;0--00  ;123;111;36
P01;V11;0;0--00  ;123;787;33.9

输出 

-;-;-;P01;A1;0;0--00  ;123;456;150
A11;F1;BMW;P01;A11;0;0--00  ;123;444;208
B12;F3;BMW;P01;B12;0;0--00  ;123;111;36
-;-;-;P01;V11;0;0--00  ;123;787;33.9

我试过了 

awk 'FNR==NR {a[$2] = $0; next }{ if($1 in a) {p=$1;$1="";print a[p],$0}}' File1 File2

但是没有用。

基本上我想从 FILE 1 中获取详细信息并与 FILE2 (master list) 进行比较。

例子 ：

FILE2 中的 A1 在 FILE1 中不可用，因此在输出文件中，第一个三个字段为“-”，其余为 FILE2 。现在，我们有了 A11，我们在 FILE1 中获得了详细信息。所以我们从文件 1 和 2 中写入 A11 的详细信息

4

5 回答 5

5

我个人会在 Perl 中执行此操作，但由于每个人和他们的母亲都在为您提供 Perl 解决方案，所以这里有一个替代方案：

假设每个文件中的记录具有一致的字段数，并且假设每个文件中的记录按字典顺序按“连接”字段排序，则可以使用join：

join -1 1 -2 2 -t ';' -e - -o '1.1 1.2 1.3 2.1 2.2 2.3 2.4 2.5 2.6 2.7' -a 2 File1 File2

选项说明：

  • -1 1并-2 2表示“加入”字段（A11、A23等）是 中的第一个字段File1和 中的第二个字段File2。
  • -t ';'表示字段由;
  • -e -表示应将空字段替换为-
  • -o '1.1 1.2 1.3 2.1 2.2 2.3 2.4 2.5 2.6 2.7'表示您希望每个输出行包含 的前三个字段File1，然后是 的前七个字段File2。（这就是为什么这种方法要求每个文件中的记录具有一致数量的字段。）
  • -a 2意味着您希望File2在输出中包含来自的每一行，即使没有来自File1. （否则它只会输出在两个文件中都匹配的行。）
于 2012-09-12T14:36:16.753 回答
3

通常的 Perl 方式：使用哈希来记住主列表：

#!/usr/bin/perl
use warnings;
use strict;

my %hash;

open my $MASTER, '<', 'File1' or die $!;
while (<$MASTER>) {
    chomp;
    my @columns = split /;/;
    $hash{$columns[0]} = [@columns[1 .. $#columns]];
}
close $MASTER;

open my $DETAIL, '<', 'File2' or die $!;
while (<$DETAIL>) {
    my @columns = split /;/;
    if (exists $hash{$columns[1]}) {
        print join ';', $columns[1], @{ $hash{$columns[1]} }, q();
    } else {
        print '-;-;-;';
    }
    print;
}
close $DETAIL;
于 2012-09-12T14:33:05.753 回答
2

使用 Perl：

use warnings;
use strict;
my %file1;
open (my $f1, "<", "file1") or die();
while (<$f1>) {
  chomp;
  my @v = (split(/;/))[0];
  $file1{$v[0]} = $_; 
}
close ($f1);
open (my $f2, "<", "file2") or die();
while (<$f2>) {
  chomp;
  my $v = (split(/;/))[1];
  if (defined $file1{$v}) {
    print "$file1{$v};$_\n";
  } else {
    print "-;-;-;$_\n";
  }
}
close ($f2);
于 2012-09-12T14:35:43.410 回答
1

perl 解决方案可能包括非常好的模块Text::CSV。如果是这样，您可以将值提取到散列中，然后使用该散列进行查找。查找值时，您将为-;-;-;查找哈希中的任何未定义值插入空白值。

use strict;
use warnings;
use Text::CSV;

my $lookup = "file1.csv";   # whatever file is used to look up fields 0-2
my $master = "file2.csv";   # the file controlling the printing

my $csv = Text::CSV->new({
        sep_char    => ";", 
        eol         => $/,  # to add newline to $csv->print()
        quote_space => 0,   # to avoid adding quotes 
    });

my %lookup;

open my $fh, "<", $lookup or die $!;

while (my $row = $csv->getline($fh)) {
    $lookup{$row->[0]} = $row;    # add entire row to specific key
}
open $fh, "<", $master or die $!; # new $fh needs no close

while (my $row = $csv->getline($fh)) {
    my $extra = $lookup{$row->[1]} // [ qw(- - -) ]; # blank row if undef
    unshift @$row, @$extra;       # add the new values
    $csv->print(*STDOUT, $row);   # then print them
}

输出：

-;-;-;P01;A1;0;0--00  ;123;456;150
A11;F1;BMW;P01;A11;0;0--00  ;123;444;208
B12;F3;BMW;P01;B12;0;0--00  ;123;111;36
-;-;-;P01;V11;0;0--00  ;123;787;33.9
于 2012-09-12T21:20:14.030 回答
1

这在单行程序中无法方便地完成，因为它涉及读取两个输入文件，但问题并不难

该程序从 中读取所有行file1，并使用第一个字段作为键将该行存储在哈希中

然后读取其中的所有行，file2并将第二个字段用作访问哈希的键。//defined-or 运算符用于打印任一元素的值（如果存在则打印），否则打印默认字符串（如果不存在）

file2最后打印当前行

use strict;
use warnings;

my %data;

open my $fh, '<', 'file1' or die $!;
while (<$fh>) {
  chomp;
  my $key = (split /;/)[0];
  $data{$key} = $_;
}

open $fh, '<', 'file2' or die $!;
while (<$fh>) {
  my $key = (split /;/)[1];
  print $data{$key} // '-;-;-;', $_;
}

输出

-;-;-;P01;A1;0;0--00  ;123;456;150
A11;F1;BMWP01;A11;0;0--00  ;123;444;208
B12;F3;BMWP01;B12;0;0--00  ;123;111;36
-;-;-;P01;V11;0;0--00  ;123;787;33.9
于 2012-09-12T15:23:45.013 回答