9

嘿，我正在运行以下脚本：

using terms from application "Messages"
    on message received this_message from this_buddy for this_chat
        display dialog "test"
    end message received
end using terms from

但是每次收到消息时，我都会在消息中收到以下错误：

Event: Message Received in Active Chat
File: registerToReceiveMessages.applescript
Error: Error -1708

我在互联网上的任何地方都找不到该错误。它似乎适用于除活动聊天之外的每个聊天。有任何想法吗？

此外，我正在尝试为“收到的地址消息”添加事件，但每次我编译 applescript 时都会将其替换为“收到的远程屏幕共享邀请”

4

2 回答 2

7

每当您选择不处理指定事件的 AppleScript 时，您都会收到错误 -1708 。

例如，如果您的脚本只实现了on message sent，但您设置此脚本在每次收到消息时运行，您将收到错误 -1708。这是因为您的脚本只知道如何处理传出消息，而不知道如何处理传入消息，因此出现错误 -1708。

现在这里有一些有趣的事情......

如果您尝试对Mix Message Case.applescript事件Message Received、Message Received in Active Chat和使用默认脚本Message Sent。第一个和最后一个工作正常，但您会收到一个 -1708 错误活动聊天事件。我们可以推断这意味着脚本没有处理事件Message Received in Active Chat。因此，现在看来，即使是 Apple 也无法处理此事件。

OS X Mavericks 更新：

此更新修复了前面提到的错误。如果您选择 Apple 的示例脚本Speak Events.applescript，您会注意到它可以完美地处理接收到活动聊天室的消息。如果您检查代码，您会注意到它正在使用该on active chat message received方法。我们现在可以在我们的脚本中使用它。由于我不再安装旧版本，因此我无法测试相同的方法是否适用于以前的版本。

以下是 Speak Events.applescript 中的代码：

on active chat message received with eventDescription
    say eventDescription
end active chat message received

另请注意，您不再为特定事件指定要运行的单个脚本。相反，您为 Messages 事件指定单个脚本处理程序。这意味着您必须实现所有事件以避免获得 -1708 方法。请注意，在示例脚本中，Apple 甚至有注释# The following are unused but need to be defined to avoid an error。这是一个可以用作脚本起点的模板：

using terms from application "Messages"
    # The following are unused but need to be defined to avoid an error

    on message sent theMessage with eventDescription
    end message sent

    on message received theMessage with eventDescription
    end message received

    on chat room message received with eventDescription
    end chat room message received

    on active chat message received with eventDescription
    end active chat message received

    on addressed message received theMessage from theBuddy for theChat with eventDescription
    end addressed message received

    on received text invitation with eventDescription
    end received text invitation

    on received audio invitation theText from theBuddy for theChat with eventDescription
    end received audio invitation

    on received video invitation theText from theBuddy for theChat with eventDescription
    end received video invitation

    on received local screen sharing invitation from theBuddy for theChat with eventDescription
    end received local screen sharing invitation

    on buddy authorization requested with eventDescription
    end buddy authorization requested

    on addressed chat room message received with eventDescription
    end addressed chat room message received

    on received remote screen sharing invitation with eventDescription
    end received remote screen sharing invitation

    on login finished with eventDescription
    end login finished

    on logout finished with eventDescription
    end logout finished

    on buddy became available with eventDescription
    end buddy became available

    on buddy became unavailable with eventDescription
    end buddy became unavailable

    on received file transfer invitation theFileTransfer with eventDescription
    end received file transfer invitation

    on av chat started with eventDescription
    end av chat started

    on av chat ended with eventDescription
    end av chat ended

    on completed file transfer with eventDescription
    end completed file transfer

end using terms from

如果您从这个脚本开始并只实现您需要的方法（同时保持其余部分不变），那么您应该避免所有 -1708 错误。

于 2013-10-20T05:27:48.400 回答
0

在我看来，事件处理程序仅在Messagesmessage received中的感觉时才起作用。我有一个稍微不同的脚本同样的问题。在另一个网站上找到另一个示例后，将其复制粘贴到新的 AppleScript 编辑器窗口中，并将其保存在由 Messages 复制到的 AppleScript 文件中，它开始工作。~/Library/Scripts/Messages

您的脚本似乎没有问题。如果我用您的代码替换我当前的脚本并保存脚本，它会按预期工作，显示一个包含文本的对话框test。

None将脚本设置为运行并返回到您在“消息设置”中创建的脚本也可能就足够了。

于 2013-02-02T11:31:13.447 回答