5

我有一个 ANTLR3 AST，我需要使用后序深度优先遍历来遍历它，我已将其实现为大致以下 Clojure：

(defn walk-tree [^CommonTree node]
  (if (zero? (.getChildCount node))
    (read-string (.getText node))
    (execute-node
      (map-action node)
      (map walk-tree (.getChildren node)))))))

我想使用 loop...recur 将其转换为尾递归，但我无法弄清楚如何有效地使用显式堆栈来执行此操作，因为我需要后序遍历。

4

3 回答 3

8

您可以使用该函数生成深度优先遍历的惰性序列，tree-seq然后从遍历中的每个对象中获取文本，而不是生成遍历树并访问每个节点的尾递归解决方案。惰性序列永远不会破坏堆栈，因为它们将生成序列中的下一项所需的所有状态存储在堆中。它们经常被用来代替像这样的递归解决方案，loop而且recur更困难。

我不知道你的树是什么样子的，尽管典型的答案看起来像这样。您需要使用“有孩子”“孩子列表”功能

(map #(.getText %) ;; Has Children?      List of Children    Input Tree
     (tree-seq #(> (.getChildCount #) 0) #(.getChildren %) my-antlr-ast))

如果 tree-seq 不适合您的需要，还有其他方法可以从树中生成惰性序列。接下来看看拉链库。

于 2012-09-11T23:07:06.557 回答
5

正如您所提到的，使用尾递归实现这一点的唯一方法是切换到使用显式堆栈。一种可能的方法是将树结构转换为堆栈结构，该结构本质上是树的逆波兰符号表示（使用循环和中间堆栈来完成此操作）。然后，您将使用另一个循环来遍历堆栈并建立您的结果。

这是我为完成此任务而编写的示例程序，使用尾递归作为灵感，在 postorder 使用 Java 代码。

(def op-map {'+ +, '- -, '* *, '/ /})

;; Convert the tree to a linear, postfix notation stack
(defn build-traversal [tree]
  (loop [stack [tree] traversal []]
    (if (empty? stack)
      traversal
      (let [e (peek stack)
            s (pop stack)]
        (if (seq? e)
          (recur (into s (rest e)) 
                 (conj traversal {:op (first e) :count (count (rest e))}))
          (recur s (conj traversal {:arg e})))))))

;; Pop the last n items off the stack, returning a vector with the remaining
;; stack and a list of the last n items in the order they were added to
;; the stack
(defn pop-n [stack n]
  (loop [i n s stack t '()]
    (if (= i 0)
      [s t]
      (recur (dec i) (pop s) (conj t (peek s))))))

;; Evaluate the operations in a depth-first manner, using a temporary stack
;; to hold intermediate results.
(defn eval-traversal [traversal]
  (loop [op-stack traversal arg-stack []]
    (if (empty? op-stack)
      (peek arg-stack)
      (let [o (peek op-stack)
            s (pop op-stack)]
        (if-let [a (:arg o)]
          (recur s (conj arg-stack a))
          (let [[args op-args] (pop-n arg-stack (:count o))]
            (recur s (conj args (apply (op-map (:op o)) op-args)))))))))

(defn eval-tree [tree] (-> tree build-traversal eval-traversal))

你可以这样称呼它：

user> (def t '(* (+ 1 2) (- 4 1 2) (/ 6 3)))
#'user/t
user> (eval-tree t)
6

我将其作为练习留给读者，以将其转换为使用 Antlr AST 结构；）

于 2012-09-11T18:10:51.457 回答
1

我不擅长clojure，但我想我明白你在找什么。

这是一些伪代码。我的伪代码中的堆栈看起来像一个有状态的对象，但是使用不可变的对象来代替是很可行的。它使用像 O(depth of tree * max children per node) heap 之类的东西。

walk_tree(TreeNode node) {
    stack = new Stack<Pair<TreeNode, Boolean>>();
    push(Pair(node, True), stack)
    walk_tree_aux(stack);
}
walk_tree_aux(Stack<Pair<TreeNode, Boolean>> stack) { -- this should be tail-recursive
    if stack is empty, return;
    let (topnode, topflag) = pop(stack);
    if (topflag is true) {
        push Pair(topnode, False) onto stack);
        for each child of topnode, in reverse order:
            push(Pair(child, True)) onto stack
        walk_tree_aux(stack);
    } else { -- topflag is false
        process(topnode)
        walk_tree_aux(stack);
    }
}
于 2012-09-12T15:42:07.950 回答