2

我的 xml 看起来像这样：

<units>
    <unit>
        <unitnum></unitnum>
        <Year></Year>
        <Qty></Qty>
    </unit>
</units>

我创建了一把钥匙来捕捉所有可能的年份。像这样：

<xsl:key name="yr" match="//Year/text()" use="." />

然后我 for-each 循环遍历键以获得唯一的年份。我的最终目标是像这样总结数量：

<xsl:for-each select="//Year/text()[generate-id()=generate-id(key('yr',.)[1])]">
     <li>
        <xsl:variable name="varjobyear" select="."/>
        <xsl:value-of select="$varjobyear"/> - sum -
        <xsl:value-of select="sum(//unit[Year=$varjobyear]/Qty)"/>
     </li>
</xsl:for-each>

出于某种原因，我的输出如下所示：

2010 - sum - 0
2011 - sum - 0
2012 - sum - 0

但我想要的是那些 0 是每年数量的实际总和。

我最好的猜测是谓词 [Year=$varjobyear] 有问题，但我不知道它是什么。我也试过 [Year=string($varjobyear)] 和 [Year=number($varjobyear)]。

我究竟做错了什么？谢谢！

4

1 回答 1

1

你想要这样的东西：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kYearByVal" match="Year" use="."/>

 <xsl:template match="Year[generate-id()=generate-id(key('kYearByVal',.)[1])]">
  <li>
    <xsl:value-of select="concat(., ' - sum - ', sum(key('kYearByVal',.)/../Qty))"/>
  </li>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<units>
    <unit>
        <unitnum>12</unitnum>
        <Year>1922</Year>
        <Qty>3</Qty>
    </unit>
    <unit>
        <unitnum>13</unitnum>
        <Year>1922</Year>
        <Qty>8</Qty>
    </unit>
    <unit>
        <unitnum>14</unitnum>
        <Year>1999</Year>
        <Qty>5</Qty>
    </unit>
    <unit>
        <unitnum>15</unitnum>
        <Year>1999</Year>
        <Qty>7</Qty>
    </unit>
    <unit>
        <unitnum>16</unitnum>
        <Year>2003</Year>
        <Qty>3</Qty>
    </unit>
</units>

产生了想要的正确结果：

<li>1922 - sum - 11</li>
<li>1999 - sum - 12</li>
<li>2003 - sum - 3</li>
于 2012-09-11T13:10:49.400 回答