1

我在下面有 xml 文件和 xslt 转换：

    <?xml version="1.0" encoding="utf-8" ?>
    <?xml-stylesheet version="1.0" type="text/xml" href="pets.xsl" ?>
    <pets>
        <pet name="Jace" type="dog" />
        <pet name="Babson" type="" />
        <pet name="Oakley" type="cat" />
        <pet name="Tabby" type="dog" />
    </pets>

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:key name="pets-key" match="pet" use="type" />
    <xsl:template match="/" >
        <html>
            <head><title></title></head>
            <body>
                <xsl:for-each select="key('pets-key', '' )" >
                    <xsl:value-of select="@name" />
                </xsl:for-each>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

如何使用按键功能选择所有类型不为空的宠物？

4

1 回答 1

1

需要注意的两点：

  1. 您的密钥定义中有错误。您需要使用 use="@type"，而不是 use="type"

  2. 您需要设置差异来选择所有类型为非空的宠物，并且仍然使用 key() 函数。XPATH 1.0 中设置差异的一般方法是......

    $node-set1[count(. | $node-set2) != count($node-set2)]

总而言之，使用 key() 并列出所有非空类型的宠物的正确但低效的 XSLT 1.0 样式表是......

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="html" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:key name="kPets" match="pet" use="@type" />

<xsl:template match="/" >
  <html>
    <head><title>Pets with a type</title></head>
    <body>   
      <ul>
        <xsl:for-each select="*/pet[count(. | key('kPets', '' )) != count(key('kPets', '' ))]" >
          <li><xsl:value-of select="@name" /></li>
        </xsl:for-each>
      </ul>
    </body>
   </html>
</xsl:template>

</xsl:stylesheet>

这会产生输出......

<html>
  <head>
    <META http-equiv="Content-Type" content="text/html; charset=utf-8">
    <title>Pets with a type</title>
  </head>
  <body>
    <ul>
      <li>Jace</li>
      <li>Oakley</li>
      <li>Tabby</li>
    </ul>
  </body>
</html>

话虽如此，这个问题并不适合作为使用键的一个很好的练习。在现实生活中，如果您想实现这个结果，一个更好、更高效的 XSLT 1.0 解决方案将是......

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="html" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:key name="kPets" match="pet" use="@type" />

<xsl:template match="/*" >
  <html>
    <head><title>Pets with a type</title></head>
    <body>   
      <ul>
        <xsl:apply-templates />
      </ul>
    </body>
   </html>
</xsl:template>

<xsl:template match="pet[@type != .]">
  <li><xsl:value-of select="@name" /></li>
</xsl:template>  

</xsl:stylesheet>
于 2012-09-09T08:20:06.347 回答