1

我有一个内部表itab，其中有一些行，其中一个组件matnr为空。我想检查palet内部表的列并从表matnr中获取，然后将内部表的列更改为新值。这是一个摘要；paletzlldetmatnrmatnr

itab桌子：

+-------+-------+-----------+
| palet | matnr | something |
+-------+-------+-----------+
|  1234 | null  | abc       |
|  1235 | null  | saa       |
|  1236 | null  | ssd       |
+-------+-------+-----------+

因此，我将检查表中的palet列zlldet并找到该matnr行的值。新itab值应为：

+-------+--------+-----------+
| palet | matnr  | something |
+-------+--------+-----------+
|  1234 | 543213 | abc       |
|  1235 | 988876 | saa       |
|  1236 | 344545 | ssd       |
+-------+--------+-----------+

我试过的：

LOOP AT itab.
  SELECT SINGLE matnr INTO itab-matnr
    FROM zlldet WHERE palet = itab-palet.
  ENDIF.
ENDLOOP.

我正在尝试更改第二行中的值。我知道这是错误的，我应该使用一些MODIFY声明，但我不确定如何。

编辑：

这是完整的代码：

REPORT zwps0510 MESSAGE-ID zc LINE-SIZE 255 NO STANDARD PAGE HEADING.
TABLES: zzllog, zzldet, marc, makt.
DATA: BEGIN OF itab OCCURS 0.
    INCLUDE STRUCTURE zzllog.
DATA: END OF itab.

DATA: adet TYPE p.
*/ paket numaraları
SELECT-OPTIONS: spalet FOR zzllog-palet.      "/paket no
SELECT-OPTIONS: spaleta FOR zzllog-paleta.    "/paketnoa
SELECT-OPTIONS: spaletb FOR zzllog-paletb.    "/paketnob
SELECTION-SCREEN SKIP 1.
*/ paketle ilgili bilgiler
SELECT-OPTIONS: sdispo FOR marc-dispo.
SELECT-OPTIONS: smatnr FOR zzllog-matnr.
SELECT-OPTIONS: sharkod FOR zzllog-harkod.    "/logtaki işlem kodu
*SELECT-OPTIONS: stelf1 FOR zzllog-telf1.
SELECT-OPTIONS: starih FOR zzllog-tarih.
SELECT-OPTIONS: susr FOR zzllog-usr.
SELECT-OPTIONS: saufnr FOR zzllog-aufnr.
SELECTION-SCREEN SKIP 1.
*/ depo adres bilgileri
SELECT-OPTIONS: sflgnum FOR zzllog-flgnum.    "/kaynak depo no
SELECT-OPTIONS: sflgtyp FOR zzllog-flgtyp.    "/kaynak depo tipi
SELECT-OPTIONS: sflgpla FOR zzllog-flgpla.    "/kaynak depo numarası
SELECT-OPTIONS: stlgnum FOR zzllog-tlgnum.    "/hedef depo no
SELECT-OPTIONS: stlgtyp FOR zzllog-tlgtyp.    "/hedef depo tipi
SELECT-OPTIONS: stlgpla FOR zzllog-tlgpla.    "/hedef depo numarası
SELECTION-SCREEN SKIP 1.
*/ Çıktıda gelecek kolonların seçimi
SELECTION-SCREEN BEGIN OF BLOCK uc WITH FRAME TITLE text-001.
PARAMETERS : tarih AS CHECKBOX DEFAULT 'X',
         saat AS CHECKBOX DEFAULT 'X',
         usr AS CHECKBOX DEFAULT 'X',
         palet AS CHECKBOX DEFAULT 'X',
         paleta AS CHECKBOX DEFAULT 'X',
         paletb AS CHECKBOX DEFAULT 'X',
         harkod AS CHECKBOX DEFAULT 'X',  "/ hareket kodu
         matnr AS CHECKBOX DEFAULT 'X',
         menge AS CHECKBOX DEFAULT 'X',
         sebep AS CHECKBOX DEFAULT 'X',  "/ sipariş/red
         aufnr AS CHECKBOX DEFAULT 'X',  "/sm.siparişi
         ref2 AS CHECKBOX DEFAULT 'X',
         paufnr AS CHECKBOX DEFAULT 'X', "/enj.siparişi
         flgnum AS CHECKBOX DEFAULT 'X', "/from depo...
         flgtyp AS CHECKBOX DEFAULT 'X',
         flgpla AS CHECKBOX DEFAULT 'X',
         tlgnum AS CHECKBOX DEFAULT 'X', "/ to depo...
         tlgtyp AS CHECKBOX DEFAULT 'X',
         tlgpla AS CHECKBOX DEFAULT 'X'.
SELECTION-SCREEN END OF BLOCK uc.
*
TOP-OF-PAGE.
   PERFORM baslik.
*
START-OF-SELECTION.
  PERFORM prepare_itab.
  PERFORM write_itab.
**
FORM prepare_itab.
*/ Paketle ilgili tüm geçmiş hareketler log tablosundan okunur
  SELECT * INTO CORRESPONDING FIELDS OF TABLE itab
      FROM zzllog WHERE palet IN spalet
                    AND paleta IN spaleta
                    AND paletb IN spaletb
                    AND matnr IN smatnr
                    AND harkod IN sharkod
                    AND tarih IN starih
                    AND flgnum IN sflgnum
                    AND flgtyp IN sflgtyp
                    AND flgpla IN sflgpla
                    AND tlgnum IN stlgnum
                    AND tlgtyp IN stlgtyp
                    AND tlgpla IN stlgpla
                    AND aufnr IN saufnr
                    AND usr IN susr.
  IF sdispo[] IS NOT INITIAL.
    LOOP AT itab.
      SELECT SINGLE dispo INTO marc-dispo
                FROM marc WHERE matnr = itab-matnr
                            AND werks = '3001'
                            AND dispo IN sdispo.
      IF sy-subrc <> 0.
        DELETE itab.
      ENDIF.
    ENDLOOP.
  ENDIF.




  DESCRIBE TABLE itab LINES adet.
*/ tüm hareketler tarih ve saate göre sıralanır
 SORT itab BY tarih saat.
 WRITE:/ 'ADET: ', adet.
 ULINE.
   ENDFORM.

所以，我想要做的正是：如果sharkod包含D,zzldet应该检查matnr.

4

3 回答 3

3

不要使用MODIFY，而是使用字段符号：

DATA: lt_materials TYPE TABLE OF zzllog.
FIELD-SYMBOLS: <ls_line> TYPE zzllog.

* other code with strange comments :-)

LOOP AT lt_materials ASSIGNING <ls_line> WHERE matnr IS INITIAL.
  SELECT SINGLE MATNR
    FROM zlldet
    INTO <ls_line>-matnr
    WHERE palet = <ls_line>-palet.
ENDLOOP.

这只是正确语法的示例。在实际程序中执行此操作不是一个好主意，因为您很有可能会使用数千个请求访问数据库，并且可能会降低性能。最好将PALET没有的数字预选MATNR到单独的表中，然后在单个查询中FOR ALL ENTRIES IN读取所有s。MATNR

编辑：添加类型名称。顺便说一句，您声明内部表的方式有些过时了......

于 2012-09-07T11:37:35.720 回答
2

当您想使用修改而不是字段符号来执行此操作时，这将是正确的解决方案：

LOOP AT itab.
  SELECT SINGLE matnr INTO itab-matnr
    FROM zlldet WHERE palet = itab-palet.
  MODIFY itab.
ENDLOOP.

您将 itab 声明为带有标题行的表（顺便说一句，已弃用）。这意味着您有一个表格 itab 和一个结构 itab。在哪种情况下使用哪个取决于上下文，并且某些命令（例如 LOOP AT 和 MODIFY）同时使用两者。这将是带有工作区而不是标题行的代码。它更具可读性。

DATA itab TYPE TABLE OF [something].
DATA wa TYPE [something].

LOOP AT itab INTO wa.  " copies each line into wa
  SELECT SINGLE matnr INTO wa-matnr
    FROM zlldet WHERE palet = itab-palet.
  MODIFY itab FROM wa.  " writes the changed line back to the table
ENDLOOP.

您还可以使用带有字段符号 vwegert 描述的解决方案。字段符号是指向表格行的指针。对字段符号的任何更改都将自动写回表中，因此在这种情况下您不需要 MODIFY。它也更快，尤其是对于非常宽的表，因为不需要复制数据。

于 2012-09-07T11:54:58.960 回答
1

您还可以避免每次在循环内使用 select 语句。相反，您可以尝试使用 Range 表并在循环之前只使用一次 select 语句，因为它可以提高性能。

定义用户定义的结构并声明变量

types: begin of ty_p_m,
         palet type zlldet-palet,
         matnr type zlldet-matnr,
       end of ty_p_m.

data: r_palet type range table of zlldet-palet,
      r_line_palet like line of r_palet,
      i_p_matnr type standard table of ty_p_m,
      wa_p_m type ty_p_m.


field-symbols: <fs> type wa_p_m.

填写下一步要在选择查询中使用的范围表。

r_line_palet-sign = 'I'.
r_line_palet-option = 'EQ'.

loop at itab into wa.
r_line_palet-low = wa-palet.
append  r_line_palet to r_palet.
endloop.

现在通过引用范围表来使用 select 语句并获取声明的内部表中的数据。

select palet matnr from zlldet into i_p_matnr
where palet in r_palet.

现在循环声明的内部表。在里面读取带有传入值的内部表，并使用字段符号而不是修改语句修改表本身。

loop at i_p_matnr into wa_p_matnr.
read table itab with key palet = wa_p_matnr-palet assigning <fs>.
if sy-subrc = 0.
<fs>-matnr = wa_p_matnr-matnr.
endif.
clear wa_p_matnr.
endloop.
于 2012-09-13T09:40:35.583 回答