0

感谢您的建议。请原谅我不够清楚。让我尽我所能再描述一遍。

compns.f有两个模型 - A 和 B。模型 A 有一个由主程序调用的子程序（它不是模块的一部分） 。下面，compns.f代码：

compns.f：（模型 A）

 subroutine compns(deltim,fhout)      
 use var_repos, only: compns_var_dump

 open(unit=nlunit,file=gfs_namelist) ! reads a file for the variables deltim and fhout

 rewind (nlunit)

 read(nlunit,nam_mrf)

 print *, deltim,fhout               ! deltim = 360.0, fhout  = 6.0

 CALL compns_var_dump(deltim,fhout)  ! calls the subroutine and passes the variables

 end

另一个包含子程序 compns_var_dump（用于收集变量）的模块是 var_repos.f90：

MODULE var_repos

  IMPLICIT NONE

  PUBLIC :: compns_var_dump

  PUBLIC :: tstep_var_dump       !!! to dump variables from another place

  REAL, PUBLIC :: d_time    ! dummy variable

! declare the variables which will go public here:

  REAL,    PUBLIC :: deltim, fhout

CONTAINS

  SUBROUTINE compns_var_dump(deltim , fhout)

  REAL,    INTENT(inout) :: deltim , fhout

  d_time = deltim

  WRITE(*,*)'Inside var_repos: deltim = ',deltim,d_time

  END SUBROUTINE compns_var_dump

  SUBROUTINE tstep_var_dump

  ...

  END SUBROUTINE tstep_var_dump

END MODULE var_repos

现在，我需要模型 B 中的变量var_repos.f90。模型 B 中需要它们的模块如下：

mo_time_control.f90：（模型 B）

 MODULE time_control

 PUBLIC :: get_delta_time

CONTAINS

   REAL(dp) FUNCTION get_delta_time()

   USE var_repos,      ONLY: d_time

   IMPLICIT NONE

   REAL :: d_time

   REAL :: a_time            ! Testing

   get_delta_time = d_time

   a_time = d_time           ! Testing

   WRITE(*,*)'Inside function get_delta_time(): deltim= ',d_time,get_delta_time, a_time

   END FUNCTION get_delta_time

 END MODULE time_control

运行模型后的输出如下：

'Inside var_repos: deltim = ' 360.000 360.000

'Inside function get_delta_time(): deltim= ' 0.00000E+00 0.00000E+00 0.00000E+00

我希望我在这篇文章中很清楚。有没有更好的方法来完成上述任务？我的理念是通过不同的子程序调用将模型 A 所需的变量收集到一个模块中，从而将该模块用作存储库，让模型 B 将其用于所需的变量。这种方法对吗？

4

1 回答 1

1

试试这个例子：

MODULE var_repos

  IMPLICIT NONE

  PUBLIC :: compns_var_dump

  REAL,    PUBLIC :: deltim, var2

CONTAINS

  SUBROUTINE compns_var_dump(deltim , fhout)

  REAL,    INTENT(in) :: deltim , fhout

  WRITE(*,*)'Inside var_repos: args = ', deltim, fhout
  var2 = fhout

  END SUBROUTINE compns_var_dump

END MODULE var_repos


program test

use var_repos

call compns_var_dump ( 2.0, 3.0 )

write (*, *) "in main:", deltim, var2

end program test

输出是：

 Inside var_repos: args =    2.00000000       3.00000000    
 in main:   0.00000000       3.00000000

我相信答案是子程序的参数 deltim 和同名的模块变量是不同的变量。创建与模块变量同名的子例程虚拟参数会屏蔽模块模块，而不是自动将值复制到模块变量。所以在 main 模块变量 deltim 没有收到值 2 并且是未定义的。在编译器中，我使用了它所拥有的随机值为零；该值在不同的编译器上可能不同。另一方面，变量 fhout 和 var2 不同，虚拟参数 fhout 被主动复制到 var2。因此，模块 var2 的值被设置并可用于任何使用该模块的例程（这里是主程序）。

编辑：解决方案是我为参数 fhout 和模块变量 var2 显示的。调用虚拟参数 ARG_varX 和模块变量 GBL_varX。在子例程中使用赋值语句将每个 ARG_varX 复制到 GBL_varX。然后使用该模块的任何程序都可以访问变量 GBL_varX，这些变量将具有它们被发送到子程序中的值。这是否解决了你的问题。

编辑 2：这是您的新代码的一个版本。它似乎工作。如果我修复了错误，或者它在您显示的代码之外：

MODULE var_repos

   IMPLICIT NONE

   PUBLIC :: compns_var_dump

   ! declare the variables which will go public here:

   REAL,    PUBLIC :: GBL_deltim, GBL_fhout

CONTAINS

   SUBROUTINE compns_var_dump(ARG_deltim, ARG_fhout)

      REAL,    INTENT(in) :: ARG_deltim , ARG_fhout

      GBL_deltim = ARG_deltim
      GBL_fhout = ARG_fhout

      WRITE(*,*)'Inside compns_var_dump:', ARG_deltim, GBL_deltim, GBL_fhout

   END SUBROUTINE compns_var_dump

END MODULE var_repos

! ------------------------------------------------------------

module my_b

contains

   subroutine compns ()
      use var_repos, only: compns_var_dump

      real :: deltim, fhout

      deltim = 360.0
      fhout  = 6.0


      write (*, *) "compns:", deltim, fhout

      CALL compns_var_dump(deltim,fhout)  ! calls the subroutine and passes the variables

   end subroutine compns

end module my_b

! ------------------------------------------------------------

MODULE time_control

   PUBLIC :: get_delta_time

CONTAINS

   FUNCTION get_delta_time()

      USE var_repos,      ONLY: GBL_deltim

      IMPLICIT NONE

      real :: get_delta_time

      REAL :: a_time            ! Testing

      get_delta_time = GBL_deltim

      a_time = GBL_deltim           ! Testing

      WRITE(*,*)'Inside function get_delta_time(): deltim= ', GBL_deltim, get_delta_time, a_time

   END FUNCTION get_delta_time

END MODULE time_control

! ------------------------------------------------------------

program main

   use var_repos, only: GBL_deltim, GBL_fhout
   use my_b, only: compns
   use time_control, only: get_delta_time

   real :: local_var

   call compns ()

   local_var = get_delta_time ()

   write (*, *) "main:", local_var, GBL_deltim, GBL_fhout

end program main
于 2012-09-07T11:16:17.330 回答