4

我在 Delphi 4 中有这段代码。我创建了 10 个类型的对象T_Charge（见下文），我将它们添加到TList名为myList. 该T_Charge类型引用了三个类型的对象T_Platte（见下文）。

释放所有 10 个对象的所有内存的正确方法是什么？因此，对于每个我想释放P1、P2、等的内存的对象P3，F_Treated以及其myCharge自身的内存。我尝试了一切，但不断出错。

procedure Test;
var 
  myList: TList;
  myCharge: T_Charge;
begin
  myList := TList.Create;

  for i := 0 to 9 do
  begin;
    myCharge := T_Charge.Create(...);
    myList.Add(myCharge);
  end;
  ...
end;

type
  T_Platte = class(TObject)
  private
    F_Nummer : Integer;
    F_Los    : Integer;
    F_Dicke  : Real;
    F_Lange  : Real;
    F_Breite : Real;
    F_QuenchCode : Integer;
    F_Geschwindigkeit : Real;
    F_Menge  : Integer;
    F_MengeInLos : Integer;
    F_Treated : Boolean;
  public
    constructor Create(inNummer, inLos: Integer; inDicke, inLange, inBreite, inGeschwindigkeit : Real; inQuenchCode,inMenge: Integer; inTreated: Boolean); overload;
    constructor Create(inPlatte: T_Platte); overload;
    destructor Destroy; override;

    property Nummer: Integer read F_Nummer write F_Nummer;
    property Los: Integer read F_Los write F_Los;
    property Dicke: Real read F_Dicke write F_Dicke;
    property Lange: Real read F_Lange write F_Lange;
    property Breite: Real read F_Breite write F_Breite;
    property QuenchCode : Integer read F_QuenchCode write F_QuenchCode;
    property Geschwindigkeit: Real read F_Geschwindigkeit write F_Geschwindigkeit;
    property Menge: Integer read F_Menge write F_Menge;
    property MengeInLos: Integer read F_MengeInLos write F_MengeInLos;
    property Treated: Boolean read F_Treated write F_Treated;

    function getPlattenRecord: string;
  end; // class T_Platte  

  T_Charge = class(TObject)
  private
    F_P1 : T_Platte;
    F_P2 : T_Platte;
    F_P3 : T_Platte;
    F_Treated : Boolean;
    F_Vmin : Real;
    F_Qty : Integer;
    F_RelationNext : Boolean;
  public
    constructor Create(inP1, inP2, inP3 : T_Platte; inTreated: Boolean; inVmin: Real; inQty: Integer; inRelationNext: Boolean);  overload;
    constructor Create(inCharge : T_Charge); overload;
    destructor Destroy; override;

    property P1: T_Platte read F_P1 write F_P1;
    property P2: T_Platte read F_P2 write F_P2;
    property P3: T_Platte read F_P3 write F_P3;
    property Treated : Boolean read F_Treated write F_Treated;
    property Vmin : Real read F_Vmin write F_Vmin;
    property Qty : Integer read F_Qty write F_Qty;
    property RelationNext : Boolean read F_RelationNext write F_RelationNext;

    function getChargeRecord: string;
  end; // class T_Charge


constructor T_Platte.Create(inNummer, inLos: Integer; inDicke, inLange, inBreite, inGeschwindigkeit: Real; inQuenchCode,inMenge: Integer; inTreated: Boolean);
begin
  F_Nummer := inNummer;
  F_Los := inLos;
  F_Dicke := inDicke;
  F_Lange := inLange;
  F_Breite := inBreite;
  F_Geschwindigkeit := inGeschwindigkeit;
  F_QuenchCode := inQuenchCode;
  F_Menge := inMenge;
  F_MengeInLos := 0;
  F_Treated := inTreated;
end;

constructor T_Charge.Create(inP1, inP2, inP3 : T_Platte; inTreated: Boolean; inVmin:  Real; inQty: Integer; inRelatio nNext: Boolean);
begin
  F_P1 := T_Platte.Create(inP1);
  F_P2 := T_Platte.Create(inP2);
  F_P3 := T_Platte.Create(inP3);
  F_Treated := inTreated;
  F_Vmin := inVmin;
  F_Qty := inQty;
  F_RelationNext := inRelationNext;
end;
4

6 回答 6

8

要释放列表对象，请创建您的列表并覆盖 TList.Notify()。

procedure THotFixList.Notify(Ptr: Pointer; Action: TListNotification);
begin
  inherited;
  if Action = lnDeleted then
    Tobject(Ptr).Free;
end;

它将确保您在调用 TLIst.Delete、TList.Clear、TList.Free 时释放您的对象，而不必每次都自己迭代列表。

于 2012-09-06T08:01:56.910 回答
5

将以下内容添加到析构函数中T_Charge：

destructor T_Charge.Destroy;
begin
  F_P1.Free;
  F_P2.Free;
  F_P3.Free;
  // Other code as needed
  inherited;
end;

在释放列表之前，循环并删除每个T_Charge：

for i := 0 to myList.Count - 1 do
  TObject(myList[i]).Free;         // This will free the inner `T_Platt3` 
                                   // each `T_Charge` contains.
于 2012-09-05T18:32:26.953 回答
3

特别是当列表应该包含类实例时，我认为您应该将TObjectList其用于该目的（TObjectList）。调用 的构造函数TObjectList，Create(True)告诉列表在列表被销毁或从中删除项目后释放所有包含的类实例。尽管如此，正如 Ken White 的回答中提到的，您仍然需要在 T_Charge 析构函数中释放 F_P1 等。

于 2012-09-06T12:42:55.480 回答
3

不要忘记对项目进行类型转换，因为它们包含一个没有类型的指针！

for i := 0 to myList.Count - 1 do
begin
  T_Charge(myList[i]).Free;  // Type cast
end;
于 2012-09-05T19:00:55.470 回答
2

在销毁 myList 之前，您需要：

for i := 0 to myList.Count - 1 do  
begin;
  TObject(myList[i]).Free
end;

在 T_Charge 的析构函数中，您需要释放 F_P1、F_P2 和 F_P3。

于 2012-09-05T18:26:25.120 回答
2

类的小知识：TList vs TObjectList

TList 持有Pointers所以不知道如何释放任何TObject存储的

TObjectList hols TObjects，因此可以释放它们并自动执行

我最好的说法是：使用TObjectList而不是TList作为您的基类或类型声明。

样品：

Wrong: TMyListOfObjects=class(TList) ...
 Good: TMyListOfObjects=class(TObjectList) ...

Wrong: MyListOfObjects:TList;
 Good: MyListOfObjects:TObjectList;

注意：TList在 unit上声明classes并TObjectList在 上声明Contnrs，这使得很多人使用TList并且对此一无所知（前段时间TObjectList我在互联网上阅读之前也是如此）。TObjectList

于 2016-02-04T08:23:51.277 回答