1

我有一个如下所示的 xml。我需要您的帮助来转换以下 xml 以删除所有命名空间以及“返回”标签。感谢有人为我提供了正确的 xsl。

我厌倦了尝试几件事。

原始 XML：

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>         
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>

转换后的预期 XML： 

<Response>
      <person>
         <personName></personName>
         <personAge></personAge>
         <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
         </personAddress>
         <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
         </personAddress>         
      </person>
</Response>

这是 XSLT，我现在正在使用。但这并没有生成我需要的 xml。

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()" />
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
    </xsl:template>

    <xsl:template match="Response/return" />

</xsl:stylesheet>
4

2 回答 2

1

请记住，SOAP 不使用任何名称空间属性，因此您可以稍微简化一下。这个非常短的 XSLT 1.0 样式表可以解决问题。

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope"
    xmlns:ns="http://demo.test.classes.com"
    exclude-result-prefixes="xsl soapenv ns">
<xsl:output method="xml" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates select="@*|node()" />
 </xsl:element>
</xsl:template>

<xsl:template match="ns:return|soapenv:Envelope|soapenv:Body">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

由于这是一个 SOAP 文档，您不太可能对评论和 PI 感兴趣。但是，如果您真的希望它们重新进入，那么调整是一件小事。

于 2012-09-03T14:17:55.993 回答
0

代替

<xsl:template match="Response/return" />

你需要

<xsl:template xmlns:ns="http://demo.test.classes.com" match="ns:return">
  <xsl:apply-templates/>
</xsl:template>

这样，ns:return您编写的其他模板将处理 的子代和后代。

于 2012-09-03T14:01:21.553 回答