2

我有以下正在使用的文本文件，并且必须能够在creationdatetime超过两天时仅解析对象名称值。

objectname ...........................: \Path\to\file\hpvss-LUN-22May12 22.24.11\hpVSS-LUN-29Aug12 22.39.15
creationdatetime .....................: 01-Sep-2012 02:17:43
objectname ...........................: \Path\to\file\hpVSS-LUN-22May12 22.24.11\hpVSS-LUN-28Aug12 22.16.19
creationdatetime .....................: 03-Sep-2012 10:18:09
objectname ...........................: \Path\to\file\hpVSS-LUN-22May-12 22.24.11\hpVSS-LUN-27Aug12 22.01.52
creationdatetime .....................: 03-Sep-2012 10:18:33

上述命令的输出将是：

\Path\to\file\hpvss-LUN-22May12 22.24.11\hpVSS-LUN-29Aug12 22.39.15

任何帮助将不胜感激。

普雷姆

4

2 回答 2

3

日期解析awk有点棘手，但可以使用mktime. 为了将月份名称转换为数字，定义了一个关联转换数组。

路径名称中有空格，因此字段分隔符的最佳选择可能是:（冒号后跟空格）。这是一个有效的 awk 脚本：

old_than_two_days.awk

BEGIN {
  months2num["Jan"] = 1;  months2num["Feb"] =  2; months2num["Mar"] =  3; months2num["Apr"] =  4;
  months2num["May"] = 5;  months2num["Jun"] =  6; months2num["Jul"] =  7; months2num["Aug"] =  8;
  months2num["Sep"] = 9;  months2num["Oct"] = 10; months2num["Nov"] = 11; months2num["Dec"] = 12;

  now = systime()
  two_days = 2 * 24 * 3600
  FS  = ": "
}

$1 ~ /objectname/ { 
  path = $2
}

$1 ~ /creationdatetime/ {
  split($2, ds, " ")
  split(ds[1], d, "-")
  split(ds[2], t, ":")
  date           = d[3] " " months2num[d[2]] " " d[1] " " t[1] " " t[2] " " t[3]
  age_in_seconds = mktime(date)

  if(now - age_in_seconds > two_days)
    print path
}

最后一个块中的所有拆分都是挑选出日期位并将它们转换为可以mktime接受的格式。

像这样运行它：

awk -f older_than_two_days.awk infile

输出：

\Path\to\file\hpvss-LUN-22May12 22.24.11\hpVSS-LUN-29Aug12 22.39.15
于 2012-09-03T13:24:33.647 回答
2

我会分两个阶段进行：

1）重新格式化你的输入文件

awk '/objectname/{$1=$2="";file=$0;getline;$1=$2="";print $0" |"file}' inputfile > inputfile2

这样你会处理

01-Sep-2012 02:17:43 |  \Path\to\file\hpvss-LUN-22May12 22.24.11\hpVSS-LUN-29Aug12 22.39.15
03-Sep-2012 10:18:09 |  \Path\to\file\hpVSS-LUN-22May12 22.24.11\hpVSS-LUN-28Aug12 22.16.19
03-Sep-2012 10:18:33 |  \Path\to\file\hpVSS-LUN-22May-12 22.24.11\hpVSS-LUN-27Aug12 22.01.52

2）过滤日期：

COMPARDATE=$(($(date +%s)-2*24*3600)) # 2 days off
IFS='|'
while read d f
do 
  [[ $(date -d "$d" +%s) < $COMPARDATE ]] && printf "%s\n" "$f"
done < inputfile2
于 2012-09-03T12:40:35.667 回答