actionscript-3 - AS3 圆形文本字段

Question

有谁知道如何在 AS3 中创建具有可见边框和圆角的动态文本字段？

我想我可能需要创建一个圆形影片剪辑，调整大小并将其放在文本后面。

我试过这个，但我没有看到任何变化。

var styleRound:StyleSheet = new StyleSheet();
styleRound.parseCSS("h4{cornerRadius:10;borderStyle: solid; borderThickness: 1;}");
tf.htmlText = "<h4>" + hotspotData.caption + "</h4>";
tf.styleSheet = styleRound;

Answer 1

下面是ActionScript 3 中 TextField 的可用 CSS 样式列表。抱歉，没有拐角半径。

您可以在 TextField 对象的边框属性上打开文本字段的边框。但是拐角处没有可用的财产。

我建议您创建一个新组件并自己将边框添加为 TextField 下方的 Sprite。就像是：

package
{

import flash.display.Graphics;
import flash.display.Sprite;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;

public class TextBorder extends Sprite
{
    private static const CORNER_RADIUS:int = 5;
    // display objects
    private var background:Sprite;
    private var field:TextField;

    // properties
    private var _text:String;

    public function TextBorder()
    {
        background = new Sprite;
        field = new TextField;
        field.autoSize = TextFieldAutoSize.LEFT;

        addChild(background);
        addChild(field);

        // TESTING:
        text = "Hello World";
    }

    public function set text(newText:String):void
    {
        _text = newText;
        display();
    }

    public function get text():String
    {
        return _text;
    }

    private function display():void
    {
        field.text = _text;

        var g:Graphics = background.graphics;
        g.clear();
        g.lineStyle(0, 0x0);
        g.beginFill(0xFFFFFF);
        g.drawRoundRect(0, 0, field.width, field.height, CORNER_RADIUS);
    }
}

}

Answer 2

我最终在 Flash 中创建了一个圆角矩形并将其导出为自己的类-hotspotBG。

var hotspotBackground:hotspotBG = new hotspotBG();
hotspotBackground.width = textField.width + 10;
caption.addChild(hotspotBackground);

Answer 3

您不能自行更改文本字段，自 2014 年起，flash 不允许这样做。

您可以做的是删除背景和边框，这将使文本字段完全透明，然后在文本字段的后面添加一个图像（矩形工具是最简单的方法），以便文本字段处于打开状态图像顶部（z 轴方向）

它可能不是你想的那样，但它确实有效！

//you are deleting the background and the borders //and replacing them with an image textbox.background=false; textbox.border=false;

Answer 4

你可以只使用 CSS 样式吗？就像是：

TextInput { 
  borderStyle: solid; 
  borderThickness: 1; 
  cornerRadius: 2; 
}

我没有测试过这个，但这应该给你一个圆角。