1

我有点坚持如何最好地使用以下 XML 示例：我所拥有的是以下内容：

<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (</local></Content>
<Content para="div"><local><refnr value="58236"/></local></Content>
<Content para="div"><local>) to something else (</local></Content>
<Content para="div"><local><refnr value="58237"/></local></Content>
<Content para="div"><local>), and make sure it's connected to this (</local></Content>
<Content para="div"><local><refnr value="58239"/></local></Content>
<Content para="div"><local>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (</local></Content>
<Content para="div"><local><refnr value="58238"/></local></Content>
<Content para="div"><local>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>

我想得到的输出如下：

<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (<refnr value="58236"/>) to something else (<refnr value="58237"/>), and make sure it's connected to this (<refnr value="58239"/>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (<refnr value="58238"/>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>

或者，要对其进行“编码”：任何以左括号结尾的 [Content para=div][local] 节点都需要与以下 [Content para=div][local] 节点合并，直到包含最后一个右括号的节点和句子的结尾（由结束点标识）。我能够做一些事情，但它变得过于复杂和缓慢，并且没有所有想要的结果。使用 xslt2 有什么建议吗？

4

2 回答 2

1

我认为您需要嵌套两种方法：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:output indent="yes"/>

<xsl:template match="Story">
  <xsl:copy>
    <xsl:for-each-group select="Content" group-adjacent="contains(., '(') or contains(., ')') or boolean(self::Content[local[refnr]])">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
            <Content para="div">
              <local>
                <xsl:copy-of select="current-group()/local/node()"/>
              </local>
            </Content>
          </xsl:for-each-group>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="current-group()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

使用该样式表和您的示例输入，我得到了您发布的结果。但是，我不确定我使用的条件对于实际输入是否过于简单，例如，报告是否可以存在包含refnr元素的“正常”文本。

[编辑] 使用matchesas

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:output indent="yes"/>

<xsl:template match="Story">
  <xsl:copy>
    <xsl:for-each-group select="Content" 
      group-adjacent="not(matches(., '\(.*\)')) 
                       or boolean(self::Content[local[refnr]])">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
            <Content para="div">
              <local>
                <xsl:copy-of select="current-group()/local/node()"/>
              </local>
            </Content>
          </xsl:for-each-group>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="current-group()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

我认为编辑后的输入样本会根据需要进行转换。当然，一旦你有例如<Content para="div"><local>Connect (foo) something (</local></Content>，这种方法也太简单了。

于 2012-09-01T17:21:03.610 回答
1

这个 XSLT 2.0 转换（可以很容易地转换为 XSLT 1.0）：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <Story>
   <xsl:apply-templates select="Content[1]/local"/>
  </Story>
 </xsl:template>

 <xsl:template match="Content/local[not(ends-with(., '('))]">
  <Content para="div"><local><xsl:apply-templates/></local></Content>
  <xsl:apply-templates select="../following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template match="Content/local[ends-with(., '(')]">
  <Content para="div"><local><xsl:apply-templates/>
   <xsl:apply-templates mode="inGroup" select="../following-sibling::Content[1]"/>
  </local></Content>

  <xsl:apply-templates select=
   "../following-sibling::Content
             [local[starts-with(.,')') and ends-with(.,'.')]][1]
               /following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template match="Content/local" mode="inGroup">
    <xsl:apply-templates/>
    <xsl:apply-templates mode="#current"
         select="../following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template mode="inGroup" match="Content/local[starts-with(.,')') and ends-with(.,'.')]">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="refnr"><xsl:copy-of select="."/></xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<Story>
 <Content para="div"><local>This is some (normal) text to start with.</local></Content>
 <Content para="div"><local>Connect something (</local></Content>
 <Content para="div"><local><refnr value="58236"/></local></Content>
 <Content para="div"><local>) to something else (</local></Content>
 <Content para="div"><local><refnr value="58237"/></local></Content>
 <Content para="div"><local>), and make sure it's connected to this (</local></Content>
 <Content para="div"><local><refnr value="58239"/></local></Content>
 <Content para="div"><local>).</local></Content>
 <Content para="div"><local>If that's ok do the same with this (</local></Content>
 <Content para="div"><local><refnr value="58238"/></local></Content>
 <Content para="div"><local>) also.</local></Content>
 <Content para="div"><local>This is some normal text.</local></Content>
 <Content para="div"><local>This also.</local></Content>
</Story>

产生想要的正确结果：

<Story>
   <Content para="div">
      <local>This is some (normal) text to start with.</local>
   </Content>
   <Content para="div">
      <local>Connect something (<refnr value="58236"/>) to something else (<refnr value="58237"/>), and make sure it's connected to this (<refnr value="58239"/>).</local>
   </Content>
   <Content para="div">
      <local>If that's ok do the same with this (<refnr value="58238"/>) also.</local>
   </Content>
   <Content para="div">
      <local>This is some normal text.</local>
   </Content>
   <Content para="div">
      <local>This also.</local>
   </Content>
</Story
于 2012-09-01T21:46:51.037 回答