10

关于 F# 中元素组合的最优雅和最简单实现的另一个问题。

它应该返回输入元素的所有组合（列表或序列）。第一个参数是组合中元素的数量。

例如：

comb 2 [1;2;2;3];;
[[1;2]; [1;2]; [1;3]; [2;2]; [2;3]; [2;3]]
4

8 回答 8

12

一种比 ssp 更简洁、更快速的解决方案：

let rec comb n l = 
    match n, l with
    | 0, _ -> [[]]
    | _, [] -> []
    | k, (x::xs) -> List.map ((@) [x]) (comb (k-1) xs) @ comb k xs
于 2009-08-05T07:42:01.170 回答
6 
let rec comb n l =
  match (n,l) with
  | (0,_) -> [[]]
  | (_,[]) -> []
  | (n,x::xs) ->
      let useX = List.map (fun l -> x::l) (comb (n-1) xs)
      let noX = comb n xs
      useX @ noX
于 2009-08-03T13:31:36.433 回答
1

KVB的答案有更简洁的版本：

let rec comb n l =
  match (n,l) with
    | (0,_) -> [[]]
    | (_,[]) -> []
    | (n,x::xs) ->
      List.flatten [(List.map (fun l -> x::l) (comb (n-1) xs)); (comb n xs)]
于 2009-08-04T16:10:03.010 回答
1

使用序列表达式的简单实现。就我个人而言，我经常觉得序列表达式比其他更密集的函数更容易理解。

let combinations (k : int) (xs : 'a list) : ('a list) seq =
    let rec loop (k : int) (xs : 'a list) : ('a list) seq = seq {
        match xs with
        | [] -> ()
        | xs when k = 1 -> for x in xs do yield [x]
        | x::xs ->
            let k' = k - 1
            for ys in loop k' xs do
                yield x :: ys
            yield! loop k xs }
    loop k xs
    |> Seq.filter (List.length >> (=)k)
于 2016-09-25T14:19:02.100 回答
1

如果您熟悉树递归，那么公认的答案是华丽且易于理解的。由于追求优雅，打开这条长长的休眠线程似乎有些不必要。

但是，需要一个更简单的解决方案。迭代算法有时对我来说似乎更简单。此外，性能被认为是质量的一个指标，迭代过程有时比递归过程更快。

以下代码是尾递归的，并生成一个迭代过程。从 24 个元素的列表中计算大小为 12 的组合需要三分之一的时间。

let combinations size aList = 
    let rec pairHeadAndTail acc bList = 
        match bList with
        | [] -> acc
        | x::xs -> pairHeadAndTail (List.Cons ((x,xs),acc)) xs
    let remainderAfter = aList |> pairHeadAndTail [] |> Map.ofList
    let rec comboIter n acc = 
        match n with
        | 0 -> acc
        | _ -> 
            acc
            |> List.fold (fun acc alreadyChosenElems ->
                match alreadyChosenElems with
                | [] -> aList //Nothing chosen yet, therefore everything remains.
                | lastChoice::_ -> remainderAfter.[lastChoice]
                |> List.fold (fun acc elem ->
                    List.Cons (List.Cons (elem,alreadyChosenElems),acc)
                ) acc
            ) []
            |> comboIter (n-1)
    comboIter size [[]]

允许迭代过程的想法是预先计算最后选择的元素到剩余可用元素列表的映射。此地图存储在remainderAfter.

代码不简洁，也不符合抒情韵律。

于 2016-06-01T17:51:08.970 回答
1

取自离散数学及其应用的方法。结果返回存储在数组中的有序组合列表。并且索引是从 1 开始的。

let permutationA (currentSeq: int []) (n:int) (r:int): Unit = 
    let mutable i = r
    while currentSeq.[i - 1] = n - r + i do
        i <- (i - 1)
    currentSeq.[i - 1] <- currentSeq.[i - 1] + 1
    for j = i + 1 to r do
        currentSeq.[j - 1] <- currentSeq.[i - 1] + j - i   
    ()
let permutationNum (n:int) (r:int): int [] list =
    if n >= r then
        let endSeq = [|(n-r+1) .. n|]
        let currentSeq: int [] = [|1 .. r|]
        let mutable resultSet: int [] list = [Array.copy currentSeq];
        while currentSeq <> endSeq do
            permutationA currentSeq n r
            resultSet <- (Array.copy currentSeq) :: resultSet
        resultSet
    else
        []

这个解决方案很简单，辅助函数会消耗恒定的内存。

于 2017-04-18T03:11:53.413 回答
0

Ok, just tail combinations little different approach (without using of library function)

let rec comb n lst =
    let rec findChoices = function
      | h::t -> (h,t) :: [ for (x,l) in findChoices t -> (x,l) ]
      | []   -> []
    [ if n=0 then yield [] else
            for (e,r) in findChoices lst do
                for o in comb (n-1) r do yield e::o  ]
于 2009-08-05T10:39:08.737 回答
0

我的解决方案不太简洁，不太有效（尽管如此，没有使用直接递归），但它确实返回了所有组合（目前只有对，需要扩展 filterOut 以便它可以返回两个列表的元组，稍后会做很少的事情）。 

let comb lst =
    let combHelper el lst =
        lst |> List.map (fun lstEl -> el::[lstEl])
    let filterOut el lst =
        lst |> List.filter (fun lstEl -> lstEl <> el)
    lst |> List.map (fun lstEl -> combHelper lstEl (filterOut lstEl lst)) |> List.concat

梳 [1;2;3;4] 将返回： [[1; 2]; [1; 3]; [1; 4]; [2; 1]; [2; 3]; [2; 4]; [3; 1]; [3; 2]; [3; 4]; [4; 1]; [4; 2]; [4; 3]]

于 2009-08-04T17:00:48.650 回答