regex - Perl 如何从文件中打印唯一的对

Question

我试图弄清楚如何使用 Perl 从文件中打印唯一的数据对。

例如，

Input: (check.pl)
A23072 A25058
A25058 A23072 
Output:
A23072 A25058

为了解决这个任务，我创建了文件 check.pl 的副本并遍历它以找到正则表达式。我编写了以下代码，但无法过滤数据。

#!/usr/bin/perl -w
use strict;
use warnings;
open FH, "<check.txt" || die "Error\n";
open FH1, "<checkcopy.txt" || die "Error\n";
chomp (my @array=<FH1>);
my %count=();

while (<FH>) 
{
my @values = split;
next if grep /\D/, @values or @values != 2;

my $re = qr/\A$values[0]\s+$values[1]\z|\A$values[1]\s+$values[0]\z/;

   foreach my $key (@array) 
   {
      if ((grep $_ =~ $re, $key) && (grep ++$count{$_} == 1, $key) )
      {
        print "$key\n";
      }
   }    
}
1;

任何帮助将不胜感激！谢谢。

Answer 1

您也可以将值存储在散列中，这使得查找它们变得更加容易。就像是：

my %duplicates;
while (<>) {
  my @values = split;
  next if @values != 2;

  my @sorted  = sort @values;
  $duplicates{ $sorted[0] } ||= {};
  next if $duplicates{ $sorted[0] }->{ $sorted[1] };

  $duplicates{ $sorted[0] }->{ $sorted[1] } = 1;
  print join(' ', @values), "\n";
}

Answer 2

这是我看到的一个类似问题的技术，使用sort.

#!/usr/bin/perl
use strict;
use warnings;

my %seen;
my @array;

while (<DATA>) {
    next unless 2 == (@array = split);
    my $key = join "", sort @array;
    print unless $seen{$key}++;
}

__DATA__
A23072 A25058
A25058 A23072