oracle - 是否可以将对象作为参数传递给 PL SQL 包过程？

Question

让我们以 .NET MVC 中的示例为例，在该示例中，可以ActionResult使用自定义对象甚至此类对象的数组来定义参数：

方法：

public ActionResult Blah(Person[] people) {
  // ...
}

和相应的 HTML：

<input type="text" name="people[0].FirstName" value="George" />
<input type="text" name="people[0].LastName" value="Washington" />
<input type="text" name="people[1].FirstName" value="Abraham" />
<input type="text" name="people[1].LastName" value="Lincoln" />
<input type="text" name="people[3].FirstName" value="Thomas" />
<input type="text" name="people[3].LastName" value="Jefferson" />

取自此博客的示例

我想知道是否可以在 PL SQL 中执行类似的操作，例如：

PROCEDURE blah(param1 IN Person_type)
IS
BEGIN
  -- do whatever y like
END;

其中 person_type 定义对象、记录或类似的复杂结构。

Answer 1

CREATE OR REPLACE TYPE t_parsed_name as object (
name_prefix varchar2(50),
name_first varchar2(50),
name_middle varchar2(50),
name_last varchar2(100),
name_suffix varchar2(50)
);

CREATE OR REPLACE TYPE T_PARSED_NAME_ARY as table of t_parsed_name;

create or replace procedure test_parsed_names(i_parsed_name_ary in t_parsed_name_ary) as
    idx pls_integer;
begin
    idx := i_parsed_name_ary.first;
    loop
        exit when idx is null;
        dbms_output.put_line('First name: ' || i_parsed_name_ary(idx).name_first || ', Last name: ' || i_parsed_name_ary(idx).name_last);
        idx := i_parsed_name_ary.next(idx);
    end loop;
end;

----------------------------------------
-- example using above procedure
declare
    l_parsed_name t_parsed_name;
    l_parsed_name_ary t_parsed_name_ary;
begin
  l_parsed_name_ary := t_parsed_name_ary();
  l_parsed_name_ary.extend(3);

  -- create some parsed names and add to array
  l_parsed_name := t_parsed_name('Mr','Joe','T','Blow','Jr');
  l_parsed_name_ary(1) := l_parsed_name;
  l_parsed_name := t_parsed_name('Mrs','Jane','','Doe','');
  l_parsed_name_ary(2) := l_parsed_name;
  l_parsed_name := t_parsed_name('','Betty','','Boop','');
  l_parsed_name_ary(3) := l_parsed_name;

  -- test the array (call procedure with object type array parameter)
  test_parsed_names(l_parsed_name_ary);
end;

Answer 2

是的，您可以，但您需要使用 ODP 和 Oracle 的 UDT（用户定义类型）。不是 100% 确定如何将这些映射到 MVC 位，但您可以将对象类型传递到/从 .net 到 Oracle。

查看这些链接： 使用用户定义的类型参数调用函数 (Oracle ODP.NET) （特别注意此演练http://st-curriculum.oracle.com/obe/db/hol08/dotnet/udt/udt_otn。 .htm )

http://docs.oracle.com/html/E15167_01/featUDTs.htm

您可能需要进行一些微调才能使所有内容同步，但这是可能的。