2

我正在寻找一种能够在 Delphi 中在运行时检索我当前正在运行的计算机的 IP 子网掩码的方法。

代码中有没有办法让我检索子网掩码并存储它，以便我可以在其他操作中使用它？

谢谢

4

2 回答 2

5

您可以使用Win32_NetworkAdapterConfiguration WMI 类和IPSubnet属性。

试试这个示例代码

{$APPTYPE CONSOLE}


uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

function VarArrayToStr(const vArray: variant): string;

    function _VarToStr(const V: variant): string;
    var
    Vt: integer;
    begin
    Vt := VarType(V);
        case Vt of
          varSmallint,
          varInteger  : Result := IntToStr(integer(V));
          varSingle,
          varDouble,
          varCurrency : Result := FloatToStr(Double(V));
          varDate     : Result := VarToStr(V);
          varOleStr   : Result := WideString(V);
          varBoolean  : Result := VarToStr(V);
          varVariant  : Result := VarToStr(Variant(V));
          varByte     : Result := char(byte(V));
          varString   : Result := String(V);
          varArray    : Result := VarArrayToStr(Variant(V));
        end;
    end;

var
i : integer;
begin
    Result := '[';
     if (VarType(vArray) and VarArray)=0 then
       Result := _VarToStr(vArray)
    else
    for i := VarArrayLowBound(vArray, 1) to VarArrayHighBound(vArray, 1) do
     if i=VarArrayLowBound(vArray, 1)  then
      Result := Result+_VarToStr(vArray[i])
     else
      Result := Result+'|'+_VarToStr(vArray[i]);

    Result:=Result+']';
end;

procedure  GetWin32_NetworkAdapterConfigurationInfo;
const
  WbemUser            ='';
  WbemPassword        ='';
  WbemComputer        ='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapterConfiguration Where IpEnabled=True','WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    Writeln(Format('Caption       %s',[String(FWbemObject.Caption)]));// String
    if not VarIsNull(FWbemObject.DHCPServer) then
      Writeln(Format('DHCPServer    %s',[String(FWbemObject.DHCPServer)]));// String
    if not VarIsNull(FWbemObject.IPAddress) then
      Writeln(Format('IPAddress     %s',[VarArrayToStr(FWbemObject.IPAddress)]));// array String

    if not VarIsNull(FWbemObject.IPSubnet) then
      Writeln(Format('IPSubnet      %s',[VarArrayToStr(FWbemObject.IPSubnet)]));// array String

    if not VarIsNull(FWbemObject.MACAddress) then
      Writeln(Format('MACAddress     %s',[VarArrayToStr(FWbemObject.MACAddress)]));// array String

    Writeln;
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      GetWin32_NetworkAdapterConfigurationInfo;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.
于 2012-08-28T14:57:08.573 回答
0

1) 计算机可能属于不同的网络/子网。每个网络适配器通常都有一些。有时甚至不止一个。

2）即使物理上你只有一张网卡，你也有环回网络 - 127.xxx 子网。如果您安装了一些 VPN，例如 Hamachi 或 Comodo - 这将提供一个网络适配器。连接时与电话调制解调器相同。对于 XP 兼容模式等虚拟机也是如此。因此，无论如何您都必须根据某些标准对其进行过滤。

3) 你可以通过WMI的FindAdaptor功能来获取网卡：http://www.magsys.co.uk/delphi/magwmi.asp 然后你可以读取这些适配器的属性。还提到了设置IP的功能，可能还有读取它们的功能。

即使没有，如何读取属性也显示在 URL 的演示中。要读取哪些属性，您可以使用任何 WMI 资源管理器来确定。我个人以 ks-soft.net 的 WMI Explorer 和 Microsoft 的 WMI Tools 结束。您可以像使用 SQLite 一样调试 WMI 请求，然后将其传递给 WMI 包装器并读取结果。然而，回到前面提到的设置 IP 地址函数，它们的源可能已经包含属性名称，只是为了节省探索。

于 2012-08-28T12:01:49.857 回答