delphi - Delphi XE2中从右到左的组合框与样式

Question

当我在 Delphi XE2 中使用具有自定义样式（Emerald Light Slate）和此属性的 ComboBox 时遇到问题：

BiDiMode := bdRightToLeft;
Style := csDropDownList;

没有自定义样式的 ComboBox：

并带有自定义样式（翡翠灯石板）：

我该如何解决？

Answer 1

问题似乎位于TComboBoxStyleHook （ TComboBox 的vcl样式挂钩）的DrawItem方法中，您可以通过覆盖此方法来解决此问题。

试试这个示例代码（这个解决方案远非完美，但只是一个开始）

type
  TComboBoxStyleHookFix = class(TComboBoxStyleHook)
  protected
    procedure DrawItem(Canvas: TCanvas; Index: Integer;
      const R: TRect; Selected: Boolean); override;
  end;

{ TComboBoxStyleHookFix }

procedure TComboBoxStyleHookFix.DrawItem(Canvas: TCanvas; Index: Integer;
  const R: TRect; Selected: Boolean);
var
  DIS  : TDrawItemStruct;
  Text : string;
begin
  if Control.BiDiMode<>bdRightToLeft then
   inherited
  else
  begin
    FillChar(DIS, SizeOf(DIS), 0);
    DIS.CtlType := ODT_COMBOBOX;
    DIS.CtlID := GetDlgCtrlID(Handle);
    DIS.itemAction := ODA_DRAWENTIRE;
    DIS.hDC := Canvas.Handle;
    DIS.hwndItem := Handle;
    DIS.rcItem := R;
    Text:=TComboBox(Control).Items[Index];    
    DIS.rcItem.Left:=DIS.rcItem.Left+ (DIS.rcItem.Width-Canvas.TextWidth(Text)-5);    
    DIS.itemID := Index;
    DIS.itemData := SendMessage(ListHandle, LB_GETITEMDATA, 0, 0);
    if Selected then
      DIS.itemState := DIS.itemState {or ODS_FOCUS} or ODS_SELECTED;
    SendMessage(Handle, WM_DRAWITEM, Handle, LPARAM(@DIS));
  end;
end;

并以这种方式使用

 TStyleManager.Engine.RegisterStyleHook(TComboBox, TComboBoxStyleHookFix);

不要忘记在Embarcadero的QC页面中报告此错误。