1

我有以下内容：

#! /usr/bin/perl

use strict;

# Declare some meaningful named constants
use constant {FOO => 2,
              BAR => 3,
              BAM => 4};

# Define paths between the named entities
my %PATHS = (FOO => {BAR => "Foo->Bar",
                     BAM => "Foo->Bam"},
             BAR => {FOO => "Bar->Foo",
                     BAM => "Bar->Bam"},
             BAM => {FOO => "Bam->Foo",
                     BAR => "Bam->Bar"});

# Printing out PATHS map does more or less what I expect:
foreach my $src (sort keys %PATHS) {
  foreach my $dst (sort keys %{ $PATHS{$src} } ) {
    print "$src:$dst\t$PATHS{$src}{$dst}\n";
  }
}

# I can't use the constants as parameters
sub findPath($$) {
  my $src = shift;
  my $dst = shift;

  print "src:$src\ndst:$dst\n";
  my $path = $PATHS{$src}{$dst};
  print defined $path ? "path=$path\n" : "UNDEFINED\n";
}

findPath(FOO, BAR);

看来我的常量被视为裸词，并且在 HoH PATHS 的声明中添加了隐式引号。有没有一种简单的方法来定义这样一个映射，其中符号键可跨函数调用使用？

4

2 回答 2

2

操作员做了=>两件事：

  1. 引用左边的裸词
  2. 像逗号一样

如果您只想要#2，只需使用逗号。

于 2012-08-25T22:45:07.890 回答
0

Perl 常量实际上只是不带参数并返回固定值的子例程。

这意味着您可以添加&前缀以强制对它们进行插值：

my %PATHS = (&FOO => {&BAR => "Foo->Bar",
                      &BAM => "Foo->Bam"},
             &BAR => {&FOO => "Bar->Foo",
                      &BAM => "Bar->Bam"},
             &BAM => {&FOO => "Bam->Foo",
                      &BAR => "Bam->Bar"});

并保持=>显示键 => 值关系的良好语法。

您还可以使用@{[...]}始终有效的旧技巧：

print "The value of constant FOO is '@{[FOO]}'\n";

哪个比这更容易用你的眼睛解析：

print "The value of constant FOO is '" . FOO . "'\n";
于 2012-08-26T03:21:39.477 回答