5

以下工作完美（Delphi 7）：

procedure TMainForm.SayIt(s:string); // s is the string to be spoken
var
voice: OLEVariant;
begin
  memo1.setfocus;
  voice := CreateOLEObject ('SAPI.SpVoice');
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFDefault);
end;

以上在“同步”模式下工作（SVSFDefault标志），但如果我将标志更改为SVSFlagsAsync以尝试在异步模式下播放声音，则不会产生声音。没有给出错误消息，但扬声器上没有播放任何内容。

问题可能是什么？我在 Delphi 的 Imports 文件夹中有 SpeechLib_TLB 单元。

编辑：这是在 Windows XP 中

谢谢，布鲁诺。

4

1 回答 1

7

当您使用SVSFlagsAsync标志时，语音流在内部缓冲区中排队等待语音服务执行，所以我认为您发出的问题与语音对象的生命周期有关，因为是一个局部变量，实例在执行声音之前被销毁。

作为解决方法，您可以等待声音，使用WaitUntilDone方法

  voice.Speak (s, SVSFlagsAsync);
  repeat  Sleep(100); until  voice.WaitUntilDone(10);

或voice在表单定义中声明变量。

  TMainForm = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
   voice: OLEVariant;
   procedure SayIt(const s:string);
  end;

var
  MainForm: TMainForm;

implementation

uses
   ComObj;

{$R *.dfm}
procedure TMainForm.SayIt(const s:string); // s is the string to be spoken
const
  SVSFDefault = 0;
  SVSFlagsAsync = 1;
  SVSFPurgeBeforeSpeak= 2;
begin
  memo1.setfocus;
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFlagsAsync {or SVSFPurgeBeforeSpeak});
end;


procedure TMainForm.Button1Click(Sender: TObject);
begin
  SayIt('Hello');
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  voice := CreateOLEObject('SAPI.SpVoice');
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  voice  := Unassigned;
end;

end.

另外请注意，由于您使用的是后期绑定，因此您不需要 SpeechLib_TLB 单元。

于 2012-08-25T17:52:41.227 回答