vb.net - 如何通过使用 LINQ TO SQL 将表名作为参数传递来获取表记录数

Question

我有一个名为 getTableRecordCount 的方法。

 Public Function getTableRecordCount(ByVal strTableName As String, ByVal iParam1 As Integer, iParam2 As Integer) As Boolean


        Try
            Dim detailReturned = (From paramTableName In dc.<need to pass the strTableName here>
                                  Where paramTableName.col1 = iParam1 And paramTableName.col2 = iParam2 
                                  Select paramTableName).Count

            If (detailReturned > 0) Then
                Return True
            Else
                Return False
            End If

        Catch ex As Exception
            .....
        End Try

  End Function

如果我可以传递表名并拥有 DataContext，我可以使用相同的方法来获取其他表的记录数。关于如何实现这一目标的任何意见？

Answer 1

You could create a method where you pass a data context and expression. Then from data context (based on Linq2Sql as you did not specify framework) you can get table by using

GetTable<T>() 

method on your data context.

Expression would be your parameters.

Hope it helps.

Answer 2

希望我的 VB 没问题；我在 C# 中更舒服。我不确定这是否适用于 LINQ to SQL，但底部附近的 GetTableRecordCount 测试确实通过了。我假设您在表中使用不同的数据类型，因此是通用方法。

Imports System.Text
Imports System.Linq.Expressions

Class Product
    Public Id As Integer
    Public Name As String
    Sub New(id As Integer, name As String)
        Me.Id = id
        Me.Name = name
    End Sub
End Class

Class Order
    Public Id As Integer
    Public NumberOfItems As Integer
    Sub New(id As Integer, numItems As String)
        Me.Id = id
        Me.NumberOfItems = numItems
    End Sub
End Class

Class DataContext
    Public Property Products As IEnumerable(Of Product)
    Public Property Orders As IEnumerable(Of Order)
    Sub New()
        Me.Products = New Product() {New Product(1, "Apple"), New Product(2, "Banana")}
        Me.Orders = New Order() {New Order(1, 20), New Order(2, 50)}
    End Sub
End Class

<TestClass()>
Public Class Main
    Dim MyDataContext As DataContext

    <TestMethod()>
    Public Sub GetTableRecordCount()
        Me.MyDataContext = New DataContext()
        Assert.IsTrue(Me.GetTableRecordCount(Of Product)("Products", Function(p) p.Id, 1, Function(p) p.Name.Length, 5))
        Assert.IsTrue(Me.GetTableRecordCount(Of Order)("Orders", Function(o) o.Id, 2, Function(o) o.NumberOfItems, 50))
    End Sub

    Private Function GetTableRecordCount(Of TRow)(tableName As String, getParam1 As Func(Of TRow, Integer), iParam1 As Integer, getParam2 As Func(Of TRow, Integer), iParam2 As Integer) As Boolean
        Try
            Dim propertyExpr = Expression.Property(Expression.Constant(Me.MyDataContext), tableName)
            Dim getTableData = Expression.Lambda(Of Func(Of IEnumerable(Of TRow)))(propertyExpr).Compile()

            Dim detailReturned =
             From row In getTableData()
             Where getParam1(row) = iParam1 And getParam2(row) = iParam2
             Select row

            Return detailReturned.Count() > 0

        Catch ex As Exception
            Return False
        End Try

    End Function
End Class