templates - XSLT 中 * 和 node() 的区别

Question

这两个模板有什么区别？

<xsl:template match="node()">

<xsl:template match="*">

Answer 1

<xsl:template match="node()">

是以下的缩写：

<xsl:template match="child::node()">

这匹配可以通过the child::axis选择的任何节点类型：

• 元素

• 文本节点

• 处理指令 (PI) 节点

• 评论节点。

另一方面：

<xsl:template match="*">

是以下的缩写：

<xsl:template match="child::*">

这匹配任何元素。

XPath 表达式： someAxis::* 匹配给定轴的主节点类型的任何节点。

对于child::轴，主要节点类型是element。

Answer 2

只是为了说明其中一个差异，即*不匹配text：

给定xml：

<A>
    Text1
    <B/>
    Text2
</A>

匹配上node()

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <!--Suppress unmatched text-->
    <xsl:template match="text()" />

    <xsl:template match="/">
        <root>
            <xsl:apply-templates />
        </root>
    </xsl:template>

    <xsl:template match="node()">
        <node>
            <xsl:copy />
        </node>
        <xsl:apply-templates />
    </xsl:template>
</xsl:stylesheet>

给出：

<root>
    <node>
        <A />
    </node>
    <node>
        Text1
    </node>
    <node>
        <B />
    </node>
    <node>
        Text2
    </node>
</root>

而匹配*：

<xsl:template match="*">
    <star>
        <xsl:copy />
    </star>
    <xsl:apply-templates />
</xsl:template>

与文本节点不匹​​配。

<root>
  <star>
    <A />
  </star>
  <star>
    <B />
  </star>
</root>

Answer 3

另请参阅XSL xsl:template match="/" 以了解其他匹配模式。