1

我正在使用带有 MySQL 和 vaadin 的 hibernate、spring security 和 spring security acl 插件编写一个带有 grails 的基本 Web 应用程序，用于管理委员会、成员以及委员会和成员之间的成员资格。所有 CRUD 都适用于成员和委员会，但是当我创建一个 CommitteeMember 对象时，它无法引用该类的 Member 字段来获取有关成员资格所涉及的成员的信息。这是我的课程：

class Committee {
    String name
    String description
    String bylaws
    static hasMany = [members: CommitteeMember]
    static constraints = {
        name blank: false, nullable: false, matches: "[a-zA-Z0-9 ]*", unique: true
        description blank: false, nullable: false, matches: "[a-zA-Z0-9 ]*"
        bylaws blank: false, nullable: false, matches: "[a-zA-Z0-9 ]*"
   }
}

class Member {
    String firstName
    String middleName
    String lastName
    String address
    String phone

    static hasMany = [committees: CommitteeMember]
    static constraints = {
        firstName blank: false, nullable: false, matches: "[a-zA-Z]*"
        middleName blank: false, nullable: false, matches: "[a-zA-Z]*"
        lastName blank: false, nullable: false, matches: "[a-zA-Z]*"
        address blank: false, nullable: false, matches: "[0-9a-zA-Z ]*"
        phone blank: false, nullable: false, minSize: 10, maxSize: 10, matches: "[0-9]*"
    }
}

class CommitteeMember {

    Member member
    Committee committee
    Date startDate
    Date endDate
    String title
    Date created = new Date()
    Date updated = new Date()

    static constraints = {
        startDate blank: false, nullable: false, format: 'mm/dd/yyyy'
        endDate blank: false, nullable: false, format: 'mm/dd/yyyy'
        title blank: false, nullable: false, matches: "[a-zA-Z0-9 ]*"
        created blank: false, nullable: false, editable: false, display: false
        updated blank: false, nullable: false, editable: false, display: false
    }

}

以及添加这些类的服务层的方法：

@Transactional
def saveCommittee(name, desc, bylaws) {
    new Committee(name: name, description: desc, bylaws: bylaws).save(flush: true);
}

@Transactional
def saveMember(fname, mname, lname, address, phone) {
    new Member(firstName: fname, middleName: mname, lastName: lname,
                 address: address, phone: phone).save(flush: true);
}

@Transactional
def saveCommitteeMember(cname, lname, fname, title, start, end) {
    def cmem = new CommitteeMember(title: title, startDate: start, endDate: end);
    cmem.member = Member.findByLastNameAndFirstName(lname, fname);
    cmem.committee = Committee.findByName(cname);
    cmem.save(flush: true);
}

创建这些类是可行的，它们存储在数据库中。我的更新和删除方法对成员和委员会非常有用。但是，当我尝试类似

//this works
def cm = CommitteeMember.get(1);
def title = cm.title;

//this does not
def firstName = cm.member.firstName;

委员会成员引用的成员字段均不可访问。我在这里做错了什么？我做了很多研究，找不到任何与此完全一样的东西。帮助将不胜感激。在这件事上拉我的头发..

**更新

在服务层方法saveCommitteeMember()中，我添加了一行println(cmem.member.firstName);，并且在我的 grails 启动的终端中，它确实打印了我在调用该函数时添加到委员会的成员的名字。

4

1 回答 1

0

耶稣。我终于弄明白了。好的，这就是发生的事情。Hibernate 确实如此findByFirstNameAndLastName()，并且工作正常，但由于 grails 默认情况下是 LAZY，它只返回对该 Member 对象的 REFERENCE，而不是表中数据的对象表示。当函数返回时，该引用被销毁，且 CommitteeMember 对象的成员字段指向空。LazyInitializationException - no session exists这特别好，因为使用 Vaadin 插件，除非您明确尝试从 @Transaction 引用某些内容，否则您不会收到错误消息或任何错误消息，所以这样做def fname = cm.member.firstName没有抛出上述异常，因为 @Transaction 被认为是成功的，我只是试图读取一个空值，除了终止发生错误的函数之外，没有任何错误消息。谈论一些严肃的公牛#$&%！

无论如何，要解决这个荒谬的问题，请将其添加到您遇到空问题的对象中

class CommitteeMember {

    Member member
    Committee committee
    etc......

    static mapping = {
        member lazy: false
        committee lazy: false
    }

}

我真的希望其他有类似问题的人能找到这篇文章。这让我在如此荒谬的事情上花费了很多时间。在某些情况下，惰性评估非常好。数据库操作，IMO，不是那种情况。总之，加油。

于 2012-08-22T02:09:49.980 回答