0

作为练习，我正在尝试实现一个小型的面向对象程序，有 2 个类：

point1d: 1 attribute (x), getter and setter
point2d: inherits from point1d, add a new attribute (y) and its getter and setter

我已经将每个类都实现为闭包。这是第一个的代码：

(define (point1d xx)
  (let ((x xx))
    (define (get-x)
      x)
    (define (set-x xx)
      (set! x xx))
    (lambda (f . args)
      (apply
       (case f
         ((get-x) get-x)
         ((set-x) set-x))
       args))))

第二个：

(define (point2d xx yy)
  (let ((p1d (point1d xx))
        (y yy))
    (define (get-y)
      y)
    (define (set-y yy)
      (set! y yy))
    (lambda (f . args)
      (case f
        ((get-y) (get-y))
        ((set-y) (apply set-y args))
        (else (p1d f args))))))

我对第二个定义有一些问题；在最后一行我尝试调用父母方法，但由于args是一个列表，它不起作用。

我能做些什么？

4

1 回答 1

1

在point2dlambda 中，您尝试point1d使用

(p1d f (list arg1 arg2 ... argN))

而point1d期望的论点是：

(p1d f arg1 arg2 ... argN)

为了解决这个问题，consf 到args，然后apply到p1d，就像我在这个固定的定义中所做的那样p1d

(define (point2d xx yy)
  (let ((p1d (point1d xx))
        (y yy))
    (define (get-y)
      y)
    (define (set-y yy)
      (set! y yy))
    (lambda (f . args)
      (case f
        ((get-y) (get-y))
        ((set-y) (apply set-y args))
        (else (apply p1d (cons f args)))))))
于 2012-08-18T14:38:13.467 回答