5

在 Excel vba 中，我正在使用 vba 在 excel 中创建两个形状。一个箭头，我命名为“aro”+ i，和一个文本框，我命名为“text”+ i，其中 i 是表示照片编号的数字。

因此，假设照片 3 我将创建箭头“aro3”和文本框“text3”。

然后我想将它们分组并重命名该组“arotext”+ i，在这种情况下为“arotext3”。

到目前为止，我一直在像这样进行分组和重命名：

targetSheet.shapes.Range(Array(Arrow.Name, textBox.Name)).Select
Selection.group
Selection.Name = "AroTxt" & Number

它在一个子中工作得很好，但现在我想把它变成一个函数并返回命名组，所以我尝试了这样的事情：

Dim arrowBoxGroup as Object
set arrowBoxGroup = targetSheet.shapes.Range(Array(Arrow.Name, textBox.Name))
arrowBoxGroup.group
arrowBoxGroup.Name = "AroTxt" & Number

当我创建一个与已经创建的同名的新组时，我遇到了问题。因此，如果我创建第二个“aro3”和“text3”，然后尝试将它们分组并将组重命名为“arotext3”，我会收到错误消息，因为已经存在同名的组。

我不明白的是，当我使用引用选择的方法执行此操作时，如果我愿意，我可以用相同的名称重命名每个组并且不会出错。为什么在引用 Selection 对象时它可以工作，但在尝试使用分配的对象时却失败了？

更新：

由于有人问，我到目前为止的代码如下。箭头和文本框是指向用户使用表单任意定义的方向的箭头和文本框。

然后，这会在目标工作表上以正确的角度创建一个箭头，并在箭头的末尾放置一个带有指定数字（也通过表单）的文本框，以便它有效地形成一个标注。我知道有标注，但它们不符合我的要求，所以我必须自己制作。

我必须对文本框和箭头进行分组，因为 1）它们属于一起，2）我使用组的名称作为参考来跟踪已​​经放置了哪些标注，3）用户必须将标注放置在正确的位置上嵌入在工作表中的地图。

到目前为止，我已经设法通过将返回值设为 GroupObject 来将其变成一个函数。但这仍然依赖于 Sheet.Shapes.range().Select，在我看来这是一种非常糟糕的做法。我正在寻找一种不依赖于选择对象的方法。

而且我想了解为什么这在使用选择时有效，但在使用强类型变量来保存对象时失败。

    Public Function MakeArrow(ByVal No As Integer, ByVal angle As Double, ByVal size As ArrowSize, ByVal ArrowX As Double, ByVal ArrowY As Double, ByVal TargetInternalAngle As Double, ByRef targetSheet As Worksheet) As GroupObject

    Dim Number As String
    Dim fontSize As Integer
    Dim textboxwidth As Integer
    Dim textboxheight As Integer
    Dim arrowScale As Double
    Dim X1 As Double
    Dim Y1 As Double
    Dim X2 As Double
    Dim Y2 As Double
    Dim xBox As Double
    Dim yBox As Double
    Dim testRange As Range
    Dim arrow As Shape
    Dim textBox As Shape
'    Dim arrowTextbox As ShapeRange
'    Dim arrowTextboxGroup As Variant

    Select Case size
        Case ArrowSize.normal
            fontSize = fontSizeNormal
            arrowScale = arrowScaleNormal
        Case ArrowSize.small
            fontSize = fontSizeSmall
            arrowScale = arrowScaleSmall
        Case ArrowSize.smaller
            fontSize = fontSizeSmaller
            arrowScale = arrowScaleSmaller
    End Select
    arrowScale = baseArrowLength * arrowScale

    'Estimate required text box width
    Number = Trim(CStr(No))
    Set testRange = shtTextWidth.Range("A1")
    testRange.value = Number
    testRange.Font.Name = "ＭＳ Ｐ明朝"
    testRange.Font.size = fontSize
    shtTextWidth.Columns(testRange.Column).EntireColumn.AutoFit
    shtTextWidth.Columns(testRange.row).EntireRow.AutoFit
    textboxwidth = testRange.Width * 0.8
    textboxheight = testRange.Height * 0.9
    testRange.Clear

    'Make arrow
    X1 = ArrowX
    Y1 = ArrowY
    X2 = X1 + arrowScale * Cos(angle)
    Y2 = Y1 - arrowScale * Sin(angle)
    Set arrow = AddArrow(X1, Y1, X2, Y2, Number, targetSheet)

    'Make text box
    Set textBox = Addtextbox(angle, Number, fontSize, X2, Y2, textboxwidth, textboxheight, TargetInternalAngle, targetSheet)

    'Group arrow and test box
    targetSheet.shapes.Range(Array(arrow.Name, textBox.Name)).group.Select
    Selection.Name = "AroTxt" & Number

    Set MakeArrow = Selection

'    Set arrowTextbox = targetSheet.shapes.Range(Array(arrow.Name, textBox.Name))
'    Set arrowTextboxGroup = arrowTextbox.group
'    arrowTextboxGroup.Name = "AroTxt" & Number
'
'    Set MakeArrow = arrowTextboxGroup

End Function

Private Function AddArrow(ByVal StartX As Double, ByVal StartY As Double, ByVal EndX As Double, ByVal EndY As Double, ByVal Number As String, ByRef targetSheet As Worksheet) As Shape

    Set AddArrow = targetSheet.shapes.AddLine(StartX, StartY, EndX, EndY)
    With AddArrow
        .Name = "Aro" & Number
        With .Line
            .BeginArrowheadStyle = msoArrowheadTriangle
            .BeginArrowheadLength = msoArrowheadLengthMedium
            .BeginArrowheadWidth = msoArrowheadWidthMedium
            .ForeColor.RGB = RGB(0, 0, 255)
        End With
    End With

End Function

Private Function Addtextbox(ByVal angle As Double, ByVal Number As String, ByVal fontSize As Integer, ByVal arrowEndX As Double, ByVal arrowEndY As Double, ByVal Width As Integer, ByVal Height As Integer, ByVal LimitAngle As Double, ByRef targetSheet As Worksheet) As Shape

    Dim xBox, yBox As Integer
    Dim PI As Double
    Dim horizontalAlignment As eTextBoxHorizontalAlignment
    Dim verticalAlignment As eTextBoxVerticalAlignment

    PI = 4 * Atn(1)

    If LimitAngle = 0 Then
        LimitAngle = PI / 4
    End If

    Select Case angle
        'Right
        Case 0 To LimitAngle, 2 * PI - LimitAngle To 2 * PI
            xBox = arrowEndX
            yBox = arrowEndY - Height / 2
            horizontalAlignment = eTextBoxHorizontalAlignment.left
            verticalAlignment = eTextBoxVerticalAlignment.Center
        'Top
        Case LimitAngle To PI - LimitAngle
            xBox = arrowEndX - Width / 2
            yBox = arrowEndY - Height
            horizontalAlignment = eTextBoxHorizontalAlignment.Middle
            verticalAlignment = eTextBoxVerticalAlignment.Bottom
        'Left
        Case PI - LimitAngle To PI + LimitAngle
            xBox = arrowEndX - Width
            yBox = arrowEndY - Height / 2
            horizontalAlignment = eTextBoxHorizontalAlignment.Right
            verticalAlignment = eTextBoxVerticalAlignment.Center
        'Bottom
        Case PI + LimitAngle To 2 * PI - LimitAngle
            xBox = arrowEndX - Width / 2
            yBox = arrowEndY
            horizontalAlignment = eTextBoxHorizontalAlignment.Middle
            verticalAlignment = eTextBoxVerticalAlignment.top
    End Select

    Set Addtextbox = targetSheet.shapes.Addtextbox(msoTextOrientationHorizontal, xBox, yBox, Width, Height)
    With Addtextbox
        .Name = "Txt" & Number
        With .TextFrame
            .AutoMargins = False
            .AutoSize = False
            .MarginLeft = 0#
            .MarginRight = 0#
            .MarginTop = 0#
            .MarginBottom = 0#
            Select Case verticalAlignment
                Case eTextBoxVerticalAlignment.Bottom
                    .verticalAlignment = xlVAlignBottom
                Case eTextBoxVerticalAlignment.Center
                    .verticalAlignment = xlVAlignCenter
                Case eTextBoxVerticalAlignment.top
                    .verticalAlignment = xlVAlignTop
            End Select
            Select Case horizontalAlignment
                Case eTextBoxHorizontalAlignment.left
                    .horizontalAlignment = xlHAlignLeft
                Case eTextBoxHorizontalAlignment.Middle
                    .horizontalAlignment = xlHAlignCenter
                Case eTextBoxHorizontalAlignment.Right
                    .horizontalAlignment = xlHAlignRight
            End Select
            With .Characters
                .Text = Number
                With .Font
                    .Name = "ＭＳ Ｐ明朝"
                    .FontStyle = "標準"
                    .size = fontSize
                    .Strikethrough = False
                    .Superscript = False
                    .Subscript = False
                    .OutlineFont = False
                    .Shadow = False
                    .Underline = xlUnderlineStyleNone
                    .ColorIndex = xlAutomatic
                End With
            End With
        End With
        .Fill.Visible = msoFalse
        .Fill.Solid
        .Fill.Transparency = 1#
        With .Line
            .Weight = 0.75
            .DashStyle = msoLineSolid
            .style = msoLineSingle
            .Transparency = 0#
            .Visible = msoFalse
        End With
    End With


End Function
4

3 回答 3

7

Range.Group 返回一个值。你可以试试：

Set arrowBoxRange = targetSheet.shapes.Range(Array(Arrow.Name, textBox.Name))
Set arrowBoxGroup = arrowBoxRange.Group
arrowBoxGroup.Name = "AroTxt" & Number

我怀疑当前的选择会像您早期工作中的以下内容一样更新：

Set Selection = Selection.Group  'it's as if this is done for you when you create the group.

这导致了差异。

仅供参考，我使用的是 Excel 2010，无法复制基于 Selection 的原始代码片段（我在执行“Selection.Name =”时出错，这使得对象不支持属性。）

好的，我可以让它工作：

Selection.Group.Select
Selection.Name = "AroTxt"

当然，就像我建议的其他片段一样，这会重新分配组的返回值，以便 Selection.Group 和 Selection.Name 中的 Selection 引用不同的对象，我认为这就是你想要的。

于 2012-08-21T00:35:30.733 回答
0

这是因为您现在手动将新组存储为对象，所以出现了此错误。您可能无法对您创建的多个“AroTxt”和 Number实例执行任何操作。由于 excel 无法确定您指的是哪个组。

Excel 不应该允许这样做，但它并不总是警告这已经发生，但如果您尝试选择具有重复名称的组，则会出错。

即使不是这种情况，使用重复的变量名也不是一个好习惯。将额外的箭头和文本框添加到组中不是更好吗？

因此，要解决您的问题，您必须在保存之前检查该组是否已经存在。如果存在，则可能将其删除或添加到组中。

希望这可以帮助

于 2012-08-20T12:48:52.180 回答
0

编辑：正如它似乎总是发生的那样，在我单击提交后错误开始弹出。我会多做一些修改，但会回应@royka，想知道您是否真的需要为多个形状赋予相同的名称。

下面的代码似乎可以满足您的需求（创建形状，给它们命名然后分组）。在分组功能中，我将“AroText”编号保持不变，只是为了看看是否会发生错误（它没有发生）。看起来这两个形状具有相同的名称，但它们的区别在于它们的Shape.ID. 据我所知，如果您说ActiveSheet.Shapes("My Group").Select，它将选择具有最低 ID 的名称的元素（至于为什么它允许您将两个事物命名为相同的名称，不知道 :) ）。

这不是您“为什么”问题的答案（我无法复制错误），但这有望为您提供一种“如何”的方法。

Sub SOTest()

Dim Arrow As Shape
Dim TextBox As Shape
Dim i as Integer
Dim Grouper As Variant
Dim ws As Worksheet

Set ws = ActiveSheet

' Make two shapes and group, naming the group the same in both cases
For i = 1 To 2
  ' Create arrow with name "Aro" & i
  Set Arrow = ws.Shapes.AddShape(msoShapeRightArrow, 10, 50, 30, 30)
  Arrow.Name = "Aro" & i

  ' Create text box with name "Text" & i
  Set TextBox = ws.Shapes.AddTextbox(msoTextOrientationHorizontal, 50, 50, 40, 40)
  TextBox.Name = "Text" & i

  ' Use a group function to rename the shapes
  Set Grouper = CreateGroup(ws, Arrow, TextBox, i)

  ' See the identical names but differing IDs
  Debug.Print "Name: " & Grouper.Name & " | ID: " & Grouper.ID
Next

End Sub


Function CreateGroup(ws As Worksheet, Arrow As Shape, TextBox As Shape, Number As Integer) As Variant

Dim arrowBoxGroup As Variant

' Group the provided shapes and change the name
Set arrowBoxGroup = ws.Shapes.Range(Array(Arrow.Name, TextBox.Name)).Group
arrowBoxGroup.Name = "AroTxt" & Number

' Return the grouped object
Set CreateGroup = arrowBoxGroup

End Function
于 2012-08-20T14:21:41.163 回答