7

我正在尝试使用 Clojure 从一个大（> 1GB）文件中按行号获取 5 行。我快到了，但看到了一些奇怪的东西，我想了解发生了什么。

到目前为止，我有：

(defn multi-nth [values indices]
  (map (partial nth values) indices))

(defn read-lines [file indices]
  (with-open [rdr (clojure.java.io/reader file)]
    (let [lines (line-seq rdr)]
      (multi-nth lines indices))))

现在，(read-lines "my-file" [0])工作没有问题。但是，传入[0 1]给我以下堆栈跟踪：

java.lang.RuntimeException: java.io.IOException: Stream closed
        Util.java:165 clojure.lang.Util.runtimeException
      LazySeq.java:51 clojure.lang.LazySeq.sval
      LazySeq.java:60 clojure.lang.LazySeq.seq
         Cons.java:39 clojure.lang.Cons.next
          RT.java:769 clojure.lang.RT.nthFrom
          RT.java:742 clojure.lang.RT.nth
         core.clj:832 clojure.core/nth
         AFn.java:163 clojure.lang.AFn.applyToHelper
         AFn.java:151 clojure.lang.AFn.applyTo
         core.clj:602 clojure.core/apply
        core.clj:2341 clojure.core/partial[fn]
      RestFn.java:408 clojure.lang.RestFn.invoke
        core.clj:2430 clojure.core/map[fn]

在我从文件中读取第二行之前，流似乎已被关闭。有趣的是，如果我手动从文件中拉出一行，则(nth lines 200)该multi-nth调用适用于所有 <= 200 的值。

知道发生了什么吗？

4

2 回答 2

9

map（和 line-seq）返回惰性序列，因此在您调用 with-open 返回时，没有必要读取任何行，这会关闭文件。

基本上，您需要在 with-open 返回之前实现整个返回值，您可以使用 doall：

(defn multi-nth [values indices]
  (map (partial nth values) indices))

(defn read-lines [file indices]
  (with-open [rdr (clojure.java.io/reader file)]
    (let [lines (line-seq rdr)]
      (doall (multi-nth lines indices)))))

或类似的东西。请记住，在搜索指定行时，您的 multi-nth 会保留行 seq 的开头，这意味着它将保持所有行直到内存中的最后一个指定行 - 并且像这样使用 nth 意味着您'正在为每个索引重复遍历 line-seq - 你会想要解决这个问题。

更新：

像这样的东西会起作用。它比我喜欢的要丑一些，但它显示了原理，我认为：注意这里的索引需要是一个set。

(defn multi-nth [values indices]
 (keep 
   (fn [[number line]] 
     (if (contains? indices number) 
       line))
   (map-indexed vector values)))

(multi-nth '(a b c d e) #{2 3})
  => c d
于 2012-08-16T22:24:46.273 回答
5

with-file文件主体执行后关闭文件。因此，一旦multi-nth执行了文件，文件就会关闭，这意味着您最终会得到一个指向已关闭文件的惰性序列。

(read-lines "my-file" [0])之所以有效，是因为仅实现了惰性序列的第一个元素。

要解决此问题，您需要强制使用以下命令实现序列doall：

(defn multi-nth [values indices]
  (doall (map (partial nth values) indices)))

有关非常详细的说明，请参见https://stackoverflow.com/a/10462159/151650

于 2012-08-16T22:31:25.110 回答