2

我正在尝试创建一个网站，其中包含供人们填写的表单，当用户按下提交按钮时，每个表单字段中的文本被连接成一个文本字符串，用于制作二维码。我怎么能做到这一点，什么语言最适合大多数浏览器兼容。

另外，我想让文本字段有一个新行（\n）与之关联，以使用户扫描二维码时格式更漂亮。

请让我知道..提前致谢..您能否提供一个具有三个要连接的文本区域的网站的示例代码？

4

1 回答 1

5

Imager::QRCode模块使这很容易。我刚刚在 5 分钟内完成了以下操作。

#!/Users/quentin/perl5/perlbrew/perls/perl-5.14.2/bin/perl

use v5.12;
use CGI; # This is a quick demo. I recommend Plack/PSGI for production.
use Imager::QRCode;

my $q = CGI->new;
my $text = $q->param('text');
if (defined $text) {
    my $qrcode = Imager::QRCode->new(
        size          => 5,
        margin        => 5,
        version       => 1,
        level         => 'M',
        casesensitive => 1,
        lightcolor    => Imager::Color->new(255, 255, 255),
        darkcolor     => Imager::Color->new(0, 0, 0),
    );
    my $img = $qrcode->plot($text);
    print $q->header('image/gif');
    $img->write(fh => \*STDOUT, type => 'gif')
        or die $img->errstr;
} else {
    print $q->header('text/html');
    print <<END_HTML;
<!DOCTYPE html>
<meta charset="utf-8">
<title>QR me</title>
<h1>QR me</h1>
<form>
    <div>
        <label>
            What text should be in the QR code?
            <textarea name="text"></textarea>
        </label>
        <input type="submit">
    </div>
</form>
END_HTML
}

我怎么能做到这一点，什么语言最适合大多数浏览器兼容。

如果它在服务器上运行，那么您只需要确保输出在浏览器之间兼容；所以使用 GIF 或 PNG。

您能否包含一个具有三个要连接的文本区域的网站的示例代码？

只需.在 Perl 中使用 a 来连接字符串变量。

my $img = $qrcode->plot($foo . $bar . $baz);
于 2012-08-20T16:24:37.550 回答