9

如何使用 actionscript 3 随机化数组？

4

8 回答 8

21

有一个使用 Array.sort() 函数的简短版本：

var arr : Array = [0,1,2,3,4,5,6,7,8,9];

function randomize ( a : *, b : * ) : int {
    return ( Math.random() > .5 ) ? 1 : -1;
}

trace( arr.sort( randomize ) );

如果你没有得到“足够”的随机性，你可以排序两次 :)

编辑 - 逐行解释：

对于Array类方法sort()，您不仅可以传递诸如等Array.CASEINSENSITIVE, Array.DESCENDING之类的排序选项，还可以传递您自己的自定义比较函数引用（回调），该引用接受两个参数（要比较的数组中的两个元素）。来自 AS3 文档：

比较函数应该接受两个参数进行比较。给定元素 A 和 B，compareFunction 的结果可以是负值、0 或正值：

  • 负返回值指定 A 在排序序列中出现在 B 之前。
  • 返回值 0 指定 A 和 B 具有相同的排序顺序。
  • 正返回值指定 A 在排序序列中出现在 B 之后。

注意：可能会输入比较函数参数（如果输入了数组）并具有您想要的任何名称，例如：

function compareElements ( elementA : SomeClass, elementB : SomeClass ) : int;

当您需要按数组元素的特殊属性对数组元素进行排序时，此方法非常有用。在随机化情况下，compareFunction随机返回-1, 0或1使数组元素切换它们的位置（索引）。我发现更好的随机化（在我的主观和未经数学测试的观点中）是方法仅返回-1和1. 还要记住，带有自定义比较功能的排序功能不会按顺序比较元素，因此在某些特殊情况下，随机化结果可能与您的预期不同。

于 2012-08-16T07:45:17.270 回答
2

如果需要，还有一种更好的方法还可以让您在适当的位置随机化数组，并且它不会让您创建更多原始数组的单个副本。

package
{
    import flash.display.Sprite;

    public class RandomizeArrayExample extends Sprite
    {
        public function RandomizeArrayExample()
        {
            super();
            testDistribution();
        }

        private function testDistribution():void
        {
            var hash:Object = { };
            var tester:Array = [1, 2, 3, 4];
            var key:String;

            for (var i:int; i < 1e5; i++)
            {
                randomize(tester);
                key = tester.join("");
                if (key in hash) hash[key]++;
                else hash[key] = 1;
            }
            for (var p:String in hash) trace(p, "=>", hash[p]);
        }

        private function randomize(array:Array):Array
        {
            var temp:Object;
            var tempOffset:int;
            for (var i:int = array.length - 1; i >= 0; i--)
            {
                tempOffset = Math.random() * i;
                temp = array[i];
                array[i] = array[tempOffset];
                array[tempOffset] = temp;
            }
            return array;
        }
    }
}
于 2012-08-16T07:14:53.287 回答
1

我发现这很有帮助。我希望它也可以帮助你。

// Array to Randomize
var firstArray:Array = ["One","Two","Three","Four","Five","six","seven","eight","nine","ten"];
trace(firstArray); // Prints in order

var newArray:Array = new Array();
function randomizeArray(array:Array):Array
{
    var newArray:Array = new Array();

    while (array.length > 0)
    {
        newArray.push(array.splice(Math.floor(Math.random()*array.length), 1));
    }

    return newArray;
}

var randomArray:Array = randomizeArray(firstArray);
trace(randomArray); // Prints out randomized :)
于 2012-08-16T04:19:26.990 回答
1

我有一个替代要求，我想将大量源数组随机插入到目标数组中。像 Rytis 一样，我是数组上的 forEach、map 和 sort 函数的忠实粉丝。

var randomInsert:Function = function callback(item:*, index:int, array:Vector.<MyItem>):void
{
    var j:Number = Math.floor(Math.random() * targetArray.length);
    targetArray.splice(j,0,item);                   
}

targetArray = new Vector.<MyItem>();
sourceArray1.forEach(randomInsert, this);
sourceArray2.forEach(randomInsert, this);
于 2012-08-16T15:41:39.760 回答
1

这是一个更简单的功能。也适用于多维数组

function randomizeArray(array:Array):Array
{
    var newArray:Array = new Array();
    while (array.length > 0)
    {
        var mn=Math.floor(Math.random()*array.length)
        newArray[newArray.length]=array[mn]
        array.splice(mn,1)
    }
    return newArray;
}
于 2013-09-13T11:07:48.347 回答
0

如果您需要对数组进行洗牌（您的元素不能重复）。你可以使用这个功能：

/**
 * Shuffles array into new array with no repeating elements. Simple swap algorithm is used.
 */
public function shuffleArray(original:Array):Array
{
    // How many swaps we will do
    // Increase this number for better results (more shuffled array, but slower performance)
    const runs:int = original.length * 3;
    var shuffled:Array = new Array(original.length);

    var i:int;
    var a:int;
    var b:int;
    var temp:Object;

    // Copy original array to shuffled
    for(i=0; i<shuffled.length; i++){
        shuffled[i] = original[i];
    }

    // Run random swap cycle 'runs' times
    for(i=0; i<runs; i++){
        // There is a chance that array element will swap with itself,
        // and there is always small probability it will make your shuffle
        // results not that good, hence try to experiment with
        // different runs count as stated above
        a = Math.floor(Math.random() * original.length);
        b = Math.floor(Math.random() * original.length);

        // Swap messages
        temp = shuffled[a];
        shuffled[a] = shuffled[b];
        shuffled[b] = temp;
    }

    return shuffled;
}

用法：

var testArray:Array = ["Water", "Fire", "Air", "Earth"];
trace(shuffleArray(testArray).concat());
于 2014-09-06T17:16:59.670 回答
0

这就是我如何为记忆游戏随机化我的 36 张卡片数组

const QUANT_CARTAS: int = 36;

//get the 36 numbers into the array
for (var i: int = 0; i < QUANT_CARTAS; i++)
{
    cartas.push(i);
}

//shuffles them =)
for (var moeda: int = QUANT_CARTAS - 1; moeda > 0; moeda--)
{
    var pos: int = Math.floor(Math.random() * moeda);
    var carta: int = cartas[moeda];
    cartas[moeda] = cartas[pos];
    cartas[pos] = carta;
}
// and add them using the random order...

    for (i = 0; i < QUANT_CARTAS; i++)
{
    var novaCarta: Carta = new Carta();
    novaCarta.tipoCarta = cartas[i];
    etcetcetc.............
}
于 2014-12-15T14:34:19.083 回答
0

从数组中选择随机字符串

function keyGenerator(len:Number):String
{
    function randomRange(minNum:Number, maxNum:Number):Number
    {
        return (Math.floor(Math.random() * (maxNum - minNum + 1)) + minNum);
    }
    var hexArray = ['0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F'];
    var key = "";
    for (var i=0; i<len; i++)
    {
        key +=  hexArray[randomRange(0,hexArray.length-1)];
    }
    return key;
}

用法：

trace(keyGenerator(16));
于 2016-02-10T11:43:38.413 回答